Получить данные физического лица

Получить данные физического лица (данные паспорта, прописки, адреса проживания, ФИО в полном и сокращенном формате)

ДанныеФизическогоЛица = КадровыйУчет.КадровыеДанныеФизическихЛиц(
		Истина, ОбщегоНазначенияКлиентСервер.ЗначениеВМассиве(ДокументДляПечати.ФизическоеЛицо), 
		"ФИОПолные, ФамилияИО, АдресПоПрописке, ДокументВид, ДокументСерия, ДокументНомер", ДокументДляПечати.Дата);
{3} Переменной ДанныеФизическогоЛица присвоено значение, но оно нигде не используется
Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз

Комментарии

FOX
#1, 08 апреля 2020 11:22

//==============================================================================
// Получение данных ЗУП
        
// Возвращает структуру заполненную данными сотрудников, перечисленными в 
// параметре СписокНеобходимыхДанных.
//
// Параметры:
//  Сотрудник - Ссылка на элемент справочника сотрудники или
//						  СправочникСсылка.Сотрудники.
//  КадровыеДанные - 	Строка - список полей данных, перечисленных через запятую 
//						или Массив строк с полями данных, которые необходимо получить. 
//						Если не указывать, будут возвращенны поля из функции КадровыеДанныеПоУмолчанию().
//	ДатаПолученияДанных	- дата на которую необходимо получить данные сотрудников, 
//						применимо к данным, носящим периодический характер.
//						Если дату не указывать, будут получены самые последние данные.
//
//
//  ПоляОтбораПериодическихДанных - Структура, в качестве ключа указывается имя таблицы, содержащей
//									периодические данные (например ФИОФизическихЛиц, ГражданствоФизическихЛиц).
//									В качестве значений коллекция условий отбора, 
//									соединяемых по "И" и применяемых к регистру сведений.
//									Коллекция строки которой имеют поля.
//										* ЛевоеЗначение - строка, имя поля регистра сведений.
//										* ВидСравнения - строка, вид сравнения, допустимый в языке запросов.
//										* ПравоеЗначение - значение для сравнения с полем ЛевоеЗначение.
//
//	Список полей, допустимых в параметре КадровыеДанные см. КадровыйУчетВнутренний.ЗапросВТКадровыеДанныеСотрудников
//		и КадровыйУчетВнутренний.ЗапросВТКадровыеДанныеФизическихЛиц
//
// Возвращаемое значение:
//   Структура   - Структура, содержащая запрошенные данные.
//
Функция ПолучитьКадровыеДанныеСотрудника(Сотрудник
										, КадровыеДанные				= ""
										, ДатаПолученияДанных			= '00010101'
										, ПоляОтбораПериодическихДанных	= Неопределено
										, ФормироватьСПериодичностьДень	= Истина)
	МассивСотрудников	= Новый Массив;
	МассивСотрудников.Добавить(Сотрудник);
	ТЗ					= ПолучитьКадровыеДанныеСотрудников(Сотрудник
														, КадровыеДанные
														, ДатаПолученияДанных
														, ПоляОтбораПериодическихДанных
														, ФормироватьСПериодичностьДень);
	ДанныеСотрудника	= Новый Структура;
	Для Каждого Колонка Из ТЗ.Колонки Цикл
		ДанныеСотрудника.Вставить(Колонка.Имя);	
	КонецЦикла;
	Если ТЗ.Количество() = 1 Тогда
		ЗаполнитьЗначенияСвойств(ДанныеСотрудника, ТЗ[0]);	
	КонецЕсли;
	Возврат ДанныеСотрудника;	
КонецФункции // ПолучитьКадровыеДанныеСотрудника()
//******************************************************************************
// Возвращает таблицу значений заполненную данными сотрудников, перечисленными в 
// параметре СписокНеобходимыхДанных.
//
// Параметры:
//  МассивСотрудников - Массив ссылок на элементы справочника сотрудники или
//						  СправочникСсылка.Сотрудники.
//  КадровыеДанные - 	Строка - список полей данных, перечисленных через запятую 
//						или Массив строк с полями данных, которые необходимо получить. 
//						Если не указывать, будут возвращенны поля из функции КадровыеДанныеПоУмолчанию().
//	ДатаПолученияДанных	- дата на которую необходимо получить данные сотрудников, 
//						применимо к данным, носящим периодический характер.
//						Если дату не указывать, будут получены самые последние данные.
//
//
//  ПоляОтбораПериодическихДанных - Структура, в качестве ключа указывается имя таблицы, содержащей
//									периодические данные (например ФИОФизическихЛиц, ГражданствоФизическихЛиц).
//									В качестве значений коллекция условий отбора, 
//									соединяемых по "И" и применяемых к регистру сведений.
//									Коллекция строки которой имеют поля.
//										* ЛевоеЗначение - строка, имя поля регистра сведений.
//										* ВидСравнения - строка, вид сравнения, допустимый в языке запросов.
//										* ПравоеЗначение - значение для сравнения с полем ЛевоеЗначение.
//
//	Список полей, допустимых в параметре КадровыеДанные см. КадровыйУчетВнутренний.ЗапросВТКадровыеДанныеСотрудников
//		и КадровыйУчетВнутренний.ЗапросВТКадровыеДанныеФизическихЛиц
//
// Возвращаемое значение:
//   ТаблицаЗначений   - Таблица значений, содержащая запрошенные данные.
//
Функция ПолучитьКадровыеДанныеСотрудников(МассивСотрудников
										, КадровыеДанные				= ""
										, ДатаПолученияДанных			= '00010101'
										, ПоляОтбораПериодическихДанных	= Неопределено
										, ФормироватьСПериодичностьДень	= Истина)
	Возврат КадровыйУчет.КадровыеДанныеСотрудников(Истина
			, МассивСотрудников
			, ?(ПустаяСтрока(КадровыеДанные), КадровыеДанныеПоУмолчанию(), КадровыеДанные)
			, ДатаПолученияДанных
			, ПоляОтбораПериодическихДанных
			, ФормироватьСПериодичностьДень);    	
КонецФункции // ПолучитьКадровыеДанныеСотрудников()
//******************************************************************************
Функция КадровыеДанныеПоУмолчанию()
	// Список доступных полей см. КадровыйУчетВнутренний.ЗапросВТКадровыеДанныеСотрудников
	// и КадровыйУчетВнутренний.ЗапросВТКадровыеДанныеФизическихЛиц
	Возврат СтрЗаменить("
			|Период,
			|ФизическоеЛицо,
			|Фамилия,
			|Имя,
			|Отчество,
			|ФИОПолные,
			|ФамилияИО,
			|ИОФамилия,
            |Пол,
            |Код,
			|Страна,
			|Организация,
			|Подразделение,
			|Должность,
			|ДолжностьПоШтатномуРасписанию,
            |РабочееМестоПериодРегистрации,
			|ТарифнаяСтавка,
			|ФОТ,
			|ОсновноеНачисление,
			|Аванс,
			|ДокументПериодРегистрации,	
			|ДокументВид, 				
			|ДокументКодМВД, 			
			|ДокументСерия, 			
			|ДокументНомер, 			
			|ДокументДатаВыдачи, 		
			|ДокументСрокДействия, 		
			|ДокументКемВыдан, 			
			|ДокументКодПодразделения, 	
			|ДокументПредставление,
			|АдресПоПрописке,
			|АдресПоПропискеПредставление,
            |АдресДляИнформирования,
            |АдресДляИнформированияПредставление,
            |АдресМестаПроживания,
            |АдресМестаПроживанияПредставление,
            |ДатаРождения,
            |МестоРождения,
			|ИННВСтранеГражданства,
            |ИНН,
			|СтраховойНомерПФР,
			|ТелефонМобильный,
			|ТелефонМобильныйПредставление,
			|ТелефонДомашний,
			|ТелефонДомашнийПредставление,
			|ТелефонРабочий,
			|ТелефонРабочийПредставление,
			|EMail,
			|EMailПредставление,
            |ТабельныйНомер,
            |ДатаПриема,
            |ДатаУвольнения,
            |ДатаЗавершенияРаботы,
            |ТекущаяОрганизация,
            |ТекущееПодразделение,
            |ТекущаяДолжность,
            |ТекущийВидЗанятости,
            |ОсновноеРабочееМестоВОрганизации,
            |ОформленПоТрудовомуДоговору,
            |ТекущаяДолжностьПоШтатномуРасписанию,
            |ТекущийВидДоговора,
            |ТекущаяТерритория,
            |ТекущаяТарифнаяСтавка,
            |ТекущийФОТ,
            |ТекущаяНадбавка,
            |ТекущийСпособРасчетаАванса,
            |ТекущийАванс,
            |ДатаНачалаУчета,
            |ТрудовойДоговорНомер,
            |ТрудовойДоговорДата,
            //|ЗарплатныйПроект,
            //|НомерЛицевогоСчета,
            //|ЗарплатныйПроектДатаОткрытияЛицевогоСчета,
            //|ЗарплатныйПроектРегистратор
            |Сотрудник", Символы.ПС, "");	
КонецФункции // КадровыеДанныеПоУмолчанию()

// Возвращает сведения об ответственных лицах организации.
//
// Параметры:
//		Организация - ссылка на организацию.
//		Сведения - строка с идентификаторами, разделенными запятыми.
//		ДатаСведений - дата получения сведений.
//
// Возвращаемое значение:
//		СтруктураДанных - структура со свойствами, совпадающими с параметром «Сведения».
//			Допустимые идентификаторы запрашиваемых значений:
//				Руководитель						- руководитель организации.
//				ДолжностьРуководителя				- должность руководителя.
//				ДолжностьРуководителяСтрокой		- представление должности руководителя.
//
//				ГлавныйБухгалтер					- главный бухгалтер организации.
//
//				Кассир								- кассир организации.
//				ДолжностьКассира					- должность кассира.
//				ДолжностьКассираСтрокой				- представление должности кассира.
//
//				РуководительКадровойСлужбы					- Руководитель кадровой службы организации.
//				ДолжностьРуководителяКадровойСлужбы			- должность руководителя кадровой службы организации.
//				ДолжностьРуководителяКадровойСлужбыСтрокой	- представление должности руководителя кадровой службы организации.
//
//				ОтветственныйЗаВУР 					- ответственный за военно-учетную работу.
//				ДолжностьОтветственногоЗаВУР 		- должность ответственного за военно-учетную работу.
//				ДолжностьОтветственногоЗаВУРСтрокой - представление должности ответственного за военно-учетную работу.
//
Функция ПолучитьДанныеОтветсвенныхЛиц(Организация, Сведения = "", ДатаСведений = Неопределено)
	Сведения = ?(Не ПустаяСтрока(Сведения), Сведения, "Руководитель,ДолжностьРуководителя,ДолжностьРуководителяСтрокой,ГлавныйБухгалтер");
	Возврат СведенияОбОтветственныхЛицах.СведенияОбОтветственныхЛицах(Организация, Сведения, ДатаСведений);
КонецФункции // ПолучитьДанныеОтветсвенныхЛиц() 

// Функция возвращает сведения об организации.
//
// Параметры:
//   Организация       - СправочникСсылка.Организации - ссылка на элемент справочника "Организации".
//   ДатаЗначения      - Дата - дата, на которую нужно получить сведения.
//   СписокПоказателей - СписокЗначений - список показателей, значения которых нужно вернуть.
//  
// Возвращаемое значение:
//   Структура - структура с ключами из списка показателей и возвращаемыми значениями.
//
// Пример:
//	 ОргСведения = Новый Структура;
//   Для Каждого Показатель Из СписокПоказателей Цикл
//  	 ИмяПоказателя = Показатель.Представление;
//       Если Имяпоказателя = "КодНО" Тогда
//      	 Значение = Организация.КодНалоговогоОргана;
//       ИначеЕсли ИмяПоказателя = "ОГРН" Тогда
//      	 Значение = Организация.ОГРН;
//       Иначе
//      	 Значение = "";
//       КонецЕсли;
//       ОргСведения.Вставить(ИмяПоказателя, Значение);
//   КонецЦикла;
//   Возврат ОргСведения;
//
Функция ПолучитьСведенияОбОрганизации(Организация, Сведения = Неопределено, ДатаСведений = Неопределено)
    Если Сведения = Неопределено Тогда
        // Описания реквизитов в ЗарплатаКадрыБазовый.ПолучитьСведенияОбОрганизации()
        Сведения = "НаимЮЛСокр,НаимЮЛПол,ТелОрганизации,ИННЮЛ,КППЮЛ,ОГРН,АдрПочт_XML,АдрФакт_XML,АдрЮР_XML,АдресЭлектроннойПочтыОрганизации,ПолныйАдрЮР,ОргГород";
    КонецЕсли;
	Возврат РегламентированнаяОтчетностьВызовСервера.ПолучитьСведенияОбОрганизации(Организация, ДатаСведений, Сведения);
КонецФункции // ПолучитьСведенияОбОрганизации()
//******************************************************************************
Функция АдресаОрганизации(Организация)
    АдресаОрганизаций = УправлениеКонтактнойИнформациейЗарплатаКадры.АдресаОрганизаций(Организация);
    ОписаниеЮридическогоАдреса = УправлениеКонтактнойИнформациейЗарплатаКадры.АдресОрганизации(
        АдресаОрганизаций,
        Организация,
        Справочники.ВидыКонтактнойИнформации.ЮрАдресОрганизации);				
    ОписаниеФактическогоАдреса = УправлениеКонтактнойИнформациейЗарплатаКадры.АдресОрганизации(
        АдресаОрганизаций,
        Организация,
        Справочники.ВидыКонтактнойИнформации.ФактАдресОрганизации);
    ОрганизацияГород = ОписаниеФактическогоАдреса.Город;
    Если НЕ ЗначениеЗаполнено(ОрганизацияГород) Тогда
        ОрганизацияГород = ОписаниеЮридическогоАдреса.Город;
    КонецЕсли;
    Возврат Новый Структура("ОписаниеЮридическогоАдреса,ОписаниеФактическогоАдреса,ОрганизацияГород"
            , ОписаниеЮридическогоАдреса
            , ОписаниеФактическогоАдреса
            , ОрганизацияГород);     
КонецФункции // АдресаОрганизации()


Похожие публикации

Паспортные данные физического лица

Основной сотрудник физ. лица

Кадровые данные физических лиц

Модератору