СКД. Повторение шапки отчета на каждой странице

bolsun 311 5 4 8

Как вывести шапку отчёта на каждой странице средствами СКД? То есть не формируя отчёт программно. О программных решениях есть достаточно информации, но хочется знать как это сделать самим компоновщиком.

Отвечал на подобный вопрос на Инфостарте, настройки компоновщика это не позволяют.

В модуле отчета, процедура ПриКомпоновкеРезультата

Если известна высота шапки

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

// если высота шапки три строки
    ДокументРезультат.ПовторятьПриПечатиСтроки = ДокументРезультат.Область(1,, 3); 

КонецПроцедуры

Если высота шапки неизвестна, но шапка автоматически фиксируется при компоновке, то в этом случае можно использовать свойство ФиксацияСверху табличного документа.

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

    СтандартнаяОбработка = Ложь;

    НастройкиКомпоновки = КомпоновщикНастроек.ПолучитьНастройки();

    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, НастройкиКомпоновки, ДанныеРасшифровки);

    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,, ДанныеРасшифровки);

    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);

    Если ДокументРезультат.ФиксацияСверху Тогда
        ДокументРезультат.ПовторятьПриПечатиСтроки = ДокументРезультат.Область(1,, ДокументРезультат.ФиксацияСверху);
    КонецЕсли;

КонецПроцедуры

Автор ответа mickey.dev

0

Рекомендации

См. также

Разные параметры ориентации для разных страниц печатной формы в БСП

ВключитьПовторениеЗагрузкиСообщенияОбменаДаннымиПередЗапуском (БСП)

ОтключитьПовторениеЗагрузкиСообщенияОбменаДаннымиПередЗапуском (БСП)

СформироватьЭлементДанныхШапкиПисьма (БСП)

ДополнитьТелоПисьмаШапкойПечатнойФормы (БСП)

ИнформацияДляПоддержки (БСП)

КартинкаСтраницыПодписи (БСП)

URLСтраницыСервисаLogin (БСП)

URLСтраницыПорталаПоддержки (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз

Комментарии

Модератору