Таблица значений по полному имени метаданных

Возвращает описание таблицы значений по полному имени таблицы базы данных Например "Справочник.Валюты" или "РегистрСведений.КурсыВалют"

// Возвращает описание таблицы значений по полному имени таблицы базы данных
// Например "Справочник.Валюты" или "РегистрСведений.КурсыВалют"
// Источник: https://github.com/SeiOkami/CollectionMethodsOneS/issues/21
//
// Параметры:
//  ПолноеИмя  - Строка - Полное имя таблицы базы данных
//
// Возвращаемое значение:
//   ТаблицаЗначений
//
Функция СтруктураТаблицыБазы(Знач ПолноеИмя) Экспорт
	
	ТекстЗапроса = СтрШаблон("ВЫБРАТЬ ПЕРВЫЕ 0 * ИЗ %1", ПолноеИмя);
	СхемаЗапроса = Новый СхемаЗапроса();
	СхемаЗапроса.УстановитьТекстЗапроса(ТекстЗапроса);
	
	Результат = Новый ТаблицаЗначений();
	Для Каждого Колонка Из СхемаЗапроса.ПакетЗапросов.Получить(0).Колонки Цикл
		
		ВременнаяСтруктура = Новый Структура("Колонки", Неопределено);
		ЗаполнитьЗначенияСвойств(ВременнаяСтруктура, Колонка);
		Если ЗначениеЗаполнено(ВременнаяСтруктура.Колонки) Тогда
			ТипЗначения = Новый ОписаниеТипов("ТаблицаЗначений");
		Иначе
			ТипЗначения = Колонка.ТипЗначения;
		КонецЕсли;
		
		Результат.Колонки.Добавить(Колонка.Псевдоним, ТипЗначения);
		
	КонецЦикла;
	
	Возврат Результат;
	
КонецФункции

// Возвращает описание таблицы значений по полному имени таблицы базы данных
// Например "Справочник.Валюты" или "РегистрСведений.КурсыВалют"
// Источник: https://github.com/SeiOkami/CollectionMethodsOneS/issues/21
//
// Параметры:
//  ПолноеИмя  - Строка - Полное имя таблицы базы данных
//
// Возвращаемое значение:
//   ТаблицаЗначений
//
Функция СтруктураТаблицыБазы(Знач ПолноеИмя) Экспорт
	
	ТекстЗапроса = СтрШаблон("ВЫБРАТЬ ПЕРВЫЕ 0 * ИЗ %1", ПолноеИмя);
	СхемаЗапроса = Новый СхемаЗапроса();
	СхемаЗапроса.УстановитьТекстЗапроса(ТекстЗапроса);
	
	Результат = Новый ТаблицаЗначений();
	Для Каждого Колонка Из СхемаЗапроса.ПакетЗапросов.Получить(0).Колонки Цикл
		
		ВременнаяСтруктура = Новый Структура("Колонки", Неопределено);
		ЗаполнитьЗначенияСвойств(ВременнаяСтруктура, Колонка);
		Если ЗначениеЗаполнено(ВременнаяСтруктура.Колонки) Тогда
			ТипЗначения = Новый ОписаниеТипов("ТаблицаЗначений");
		Иначе
			ТипЗначения = Колонка.ТипЗначения;
		КонецЕсли;
		
		Результат.Колонки.Добавить(Колонка.Псевдоним, ТипЗначения);
		
	КонецЦикла;
	
	Возврат Результат;
	
КонецФункции