Краткое представление строки (в т.ч. многострочной) в виде первых N символов

Формирует из любой строки (включая многострочную) ее краткое однострочное представление, состоящее из первых N символов. Поддерживаемые контексты: клиент, сервер. Метод подходит для размещения в клиент-серверном общем модуле.

// Формирует из любой строки (в т.ч. многострочной) ее краткое однострочное представление, состоящее из первых N символов.
// Если исходная строка многострочная, то берется ее первая подстрока.
// 
// В варианте по умолчанию метод пропускает все пустые строки и незначащие символы слева перед тем,
// как начать подсчет первых N символов, но этим можно управлять через необязательные параметры.
// 
// Если длина исходной строки больше максимально допустимой (или если исходная строка многострочная),
// то в возвращаемый результат добавляется многоточие, иначе - не добавляется.
//
// Параметры:
//  ИсходнаяСтрока - Строка - Строка, которую нужно обрезать.
//  МаксимальнаяДлина - Число - Сколько символов оставлять в возвращаемом результате.
//  УдалятьПустыеСтроки - Булево - Исходная многострочная строка может начинаться с одной или нескольких пустых строк.
//                                 Если их не удалять, то возвращаемый результат будет состоять из первой такой пустой строки.
//  УдалятьПробелыСлева - Булево - Удалять или не удалять незначащие символы (пробелы, табуляции и т.д.) из начала возвращаемой строки.
// 
// Возвращаемое значение:
//  Строка - Результат усечения исходной строки до N символов.
//
Функция КраткоеПредставлениеСтроки(Знач ИсходнаяСтрока, Знач МаксимальнаяДлина, Знач УдалятьПустыеСтроки = Истина, Знач УдалятьПробелыСлева = Истина) Экспорт
	
	Результат = "";
	Подстроки = СтрРазделить(ИсходнаяСтрока, Символы.ПС, НЕ УдалятьПустыеСтроки);
	Если Подстроки.Количество() > 0 Тогда
		Результат = Подстроки[0];
	КонецЕсли;
	
	Если УдалятьПробелыСлева Тогда
		Результат = СокрЛ(Результат);
	КонецЕсли;
	
	Если СтрЧислоСтрок(ИсходнаяСтрока) > 1 ИЛИ СтрДлина(Результат) > МаксимальнаяДлина Тогда
		Результат = Лев(Результат, МаксимальнаяДлина) + "...";
	КонецЕсли;
	
	Возврат Результат;

КонецФункции

// Формирует из любой строки (в т.ч. многострочной) ее краткое однострочное представление, состоящее из первых N символов.
// Если исходная строка многострочная, то берется ее первая подстрока.
// 
// В варианте по умолчанию метод пропускает все пустые строки и незначащие символы слева перед тем,
// как начать подсчет первых N символов, но этим можно управлять через необязательные параметры.
// 
// Если длина исходной строки больше максимально допустимой (или если исходная строка многострочная),
// то в возвращаемый результат добавляется многоточие, иначе - не добавляется.
//
// Параметры:
//  ИсходнаяСтрока - Строка - Строка, которую нужно обрезать.
//  МаксимальнаяДлина - Число - Сколько символов оставлять в возвращаемом результате.
//  УдалятьПустыеСтроки - Булево - Исходная многострочная строка может начинаться с одной или нескольких пустых строк.
//                                 Если их не удалять, то возвращаемый результат будет состоять из первой такой пустой строки.
//  УдалятьПробелыСлева - Булево - Удалять или не удалять незначащие символы (пробелы, табуляции и т.д.) из начала возвращаемой строки.
// 
// Возвращаемое значение:
//  Строка - Результат усечения исходной строки до N символов.
//
Функция КраткоеПредставлениеСтроки(Знач ИсходнаяСтрока, Знач МаксимальнаяДлина, Знач УдалятьПустыеСтроки = Истина, Знач УдалятьПробелыСлева = Истина) Экспорт
	
	Результат = "";
	Подстроки = СтрРазделить(ИсходнаяСтрока, Символы.ПС, НЕ УдалятьПустыеСтроки);
	Если Подстроки.Количество() > 0 Тогда
		Результат = Подстроки[0];
	КонецЕсли;
	
	Если УдалятьПробелыСлева Тогда
		Результат = СокрЛ(Результат);
	КонецЕсли;
	
	Если СтрЧислоСтрок(ИсходнаяСтрока) > 1 ИЛИ СтрДлина(Результат) > МаксимальнаяДлина Тогда
		Результат = Лев(Результат, МаксимальнаяДлина) + "...";
	КонецЕсли;
	
	Возврат Результат;

КонецФункции