Заготовка на внешнюю обработку (минимум)

СергейТ 101 4 9

Просто вставить в текст модуля объекта внешней обработки... доработанная версия Теперь после вставки из шаблона нужно просто в соответствующих функциях указать соответствующие данные обработки. Вмешательства больше никуда не потребуется. Только при доработках менять версию в функции ВерсияОбработки и добавлять строки описаний версии в функции ОписаниеВерсии. Функцию ОписаниеВерсии можно использовать для вывода информации о версиях, например в подсказку надписи версии ```Элементы.ВерсияОбработки.Подсказка = ТекстПодсказки;```

#Область ДанныеОтчетаОбработки

Функция ВерсияОбработки(Строкой = Ложь) Экспорт
	
	ВерсияОбработки = "1.01.001";
	
	Если НЕ Строкой Тогда
		
		ИнформацияОВерсии = "v." + ВерсияОбработки + ":" + Символы.ПС
							+ НСтр("ru = 'Текст описания внешней обработки или просто наименование'");
		
		ЗаголовокВерсияОбработки = ?(ПустаяСтрока(ВерсияОбработки), "", "[v." + ВерсияОбработки + "]");
		
		Результат = Новый Структура;
		Результат.Вставить("Версия",		ВерсияОбработки);
		Результат.Вставить("Заголовок",		ЗаголовокВерсияОбработки);
		Результат.Вставить("Информация",	ИнформацияОВерсии);
		Результат.Вставить("ЧтоНового",		ОписаниеВерсии());
		
		Возврат Результат;
		
	КонецЕсли;
	
	Возврат ВерсияОбработки;
	
КонецФункции

Функция ОписаниеВерсии()
	
	ТекстыОписания = Новый Массив;
	
	ТекстыОписания.Добавить("1.01.003 - Исправлено..., доработано..., добавлено...");
	ТекстыОписания.Добавить("1.01.002 - Исправлено..., доработано..., добавлено...");
	
	Возврат СтрСоединить(ТекстыОписания, Символы.ПС)
	
КонецФункции

#Область Инициализация
// Необходимо заполнить один раз при создании обработки

Функция НаименованиеОбработки() Экспорт
	
	Возврат "Наименование обработки в списке Доболнительных отчетов и обработок";
	
КонецФункции

Функция КомандыОбработки(ТаблицаКоманд)
	
	ДобавитьКоманду(ТаблицаКоманд,
					НСтр("ru = 'Открыть'"),
					"",
					"ОткрытиеФормы",
					Истина);
	
	Возврат ТаблицаКоманд;
	
КонецФункции

Функция Назначения()
	
	МассивНазначений = Новый Массив;
	МассивНазначений.Добавить("");
	
	Возврат МассивНазначений;
	
КонецФункции

Функция ИспользоватьБезопасныйРежим()
	
	Возврат Ложь;
	
КонецФункции

Функция ВидОтчетаОбработки()
	
	Возврат ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет();
	
КонецФункции

Функция ВерсияБСП(Строкой = Истина)
	
	ВерсияБСП = "2.3.6.121";
	
	Если НЕ Строкой Тогда
		
		Результат = Новый Структура;
		Результат.Вставить("Версия",	ВерсияБСП);
		
		Возврат Результат;
		
	КонецЕсли;
	
	Возврат ВерсияБСП;
	
КонецФункции

#КонецОбласти

#КонецОбласти

#Область СлужебныйПрограммныйИнтерфейс

Функция СведенияОВнешнейОбработке() Экспорт
	
	ВерсияОбработки = ВерсияОбработки();
	
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(ВерсияБСП());
	
	ПараметрыРегистрации.Вид = ВидОтчетаОбработки();
	ПараметрыРегистрации.Версия = ВерсияОбработки.Версия;
	ПараметрыРегистрации.Назначение = Назначения();
	ПараметрыРегистрации.Наименование = НаименованиеОбработки();
	ПараметрыРегистрации.БезопасныйРежим = ИспользоватьБезопасныйРежим();
	ПараметрыРегистрации.Информация = ВерсияОбработки.Информация;
	
	КомандыОбработки(ПараметрыРегистрации.Команды);
	
	Возврат ПараметрыРегистрации;
	
КонецФункции

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
	НоваяКоманда = ТаблицаКоманд.Добавить();
	НоваяКоманда.Представление = Представление;
	НоваяКоманда.Идентификатор = Идентификатор;
	НоваяКоманда.Использование = Использование;
	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
	НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

#КонецОбласти

0

См. также

Отладить внешнюю обработку

ОбъектВнешнейОбработки (БСП)

ПриПодключенииВнешнейОбработки (БСП)

ПриСозданииВнешнейОбработки (БСП)

ПодключитьВнешнююОбработку (БСП)

Модератору