Отобразить заголовки периодов на форме отчета БСП

SeiOkami 434 5 9 9

В некоторых версиях БСП форма отчета скрывает заголовки ряда параметров. В том числе с типом "Стандартный период". Данную функцию нужно вставить в модуль отчета и вызывать в обработчике ПослеЗаполненияПанелиБыстрыхНастроек(). Подключить обработчик можно в событии ОпределитьНастройкиФормы

Источник: https://t.me/JuniorOneS

Процедура ОпределитьНастройкиФормы(Параметр, КлючВарианта, НастройкиОтчета) Экспорт
	
	НастройкиОтчета.События.ПослеЗаполненияПанелиБыстрыхНастроек = Истина;
		
КонецПроцедуры

Процедура ПослеЗаполненияПанелиБыстрыхНастроек(ФормаОтчета, ПараметрыОбновления) Экспорт
	
	ПочинитьЗаголовкиПериодов(ФормаОтчета);
		
КонецПроцедуры

Процедура ПочинитьЗаголовкиПериодов(ФормаОтчета)
	
	ЗаголовкиЭлементов = Новый Массив;
	Для Каждого ПараметрСКД Из СхемаКомпоновкиДанных.Параметры Цикл
		ЗначениеТипа = ПараметрСКД.ТипЗначения.ПривестиЗначение(Неопределено);
		Если ТипЗнч(ЗначениеТипа) = Тип("СтандартныйПериод") Тогда
			ЗаголовкиЭлементов.Добавить(ПараметрСКД.Заголовок + ":");
		КонецЕсли;
	КонецЦикла;
	
	Для Каждого ЭлементФормы Из ФормаОтчета.Элементы Цикл
		
		СвойстваЭлемента = Новый Структура("ПоложениеЗаголовка,Заголовок,ПутьКДанным");
		ЗаполнитьЗначенияСвойств(СвойстваЭлемента, ЭлементФормы);
		
		Если СвойстваЭлемента.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет
			И ЗаголовкиЭлементов.Найти(СвойстваЭлемента.Заголовок) <> Неопределено Тогда
			ЭлементФормы.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Авто;
		КонецЕсли;
		
	КонецЦикла;
		
КонецПроцедуры
0

См. также

ТекстФорматированногоЗаголовка (БСП)

УстановитьОтображениеЗаголовковГрупп (БСП)

НовыйПараметрыФормыОтобразитьРезультат (БСП)

ОбработкаОповещенияИзмененияФлажкаИспользоватьПоиск (БСП)

ОбработкаОповещенияИзмененияФлажкаУдалятьПоРасписанию (БСП)

ПриНажатииКнопкиВыбораПериода (БСП)

ПодключитьТестовыйПериод (БСП)

ЗаголовокСозданияРезервнойКопии (БСП)

Открытие формы выбора с отбором

Модератору