Структура из параметров формы

Возвращает структуру из параметров формы.

// Возвращает структуру из параметров формы.
// Источник: https://github.com/SeiOkami/CollectionMethodsOneS/issues/133
// 
// Параметры:
//  ПараметрыФормы - ДанныеФормыСтруктура
// 
// Возвращаемое значение:
//  Структура
Функция СтруктураИзПараметровФормы(Знач ПараметрыФормы) Экспорт
	
	Результат = Новый Структура;
	
	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку();
	СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ПараметрыФормы, НазначениеТипаXML.Явное);
	СтрокаXML = ЗаписьXML.Закрыть();
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(СтрокаXML);
	
	Пока ЧтениеXML.Прочитать() Цикл
		
		Если ЧтениеXML.Имя = "structure" 
			И ЧтениеXML.ПолучитьАтрибут("name") = "parameters" 
			И ЧтениеXML.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
			
			Прервать;
			             
		ИначеЕсли ЧтениеXML.Имя = "field" Тогда
			
			ТекущийКлюч	= ЧтениеXML.ПолучитьАтрибут("nameRu");
			ТекущийКлюч	= ?(ЗначениеЗаполнено(ТекущийКлюч), ТекущийКлюч, ЧтениеXML.ПолучитьАтрибут("name"));
			Если ЗначениеЗаполнено(ТекущийКлюч) Тогда
				Результат.Вставить(ТекущийКлюч);
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЦикла;
	
	ЧтениеXML.Закрыть();
	
	ЗаполнитьЗначенияСвойств(Результат, ПараметрыФормы);
	
	Возврат Результат;
	
КонецФункции

// Возвращает структуру из параметров формы.
// Источник: https://github.com/SeiOkami/CollectionMethodsOneS/issues/133
// 
// Параметры:
//  ПараметрыФормы - ДанныеФормыСтруктура
// 
// Возвращаемое значение:
//  Структура
Функция СтруктураИзПараметровФормы(Знач ПараметрыФормы) Экспорт
	
	Результат = Новый Структура;
	
	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку();
	СериализаторXDTO.ЗаписатьXML(ЗаписьXML, ПараметрыФормы, НазначениеТипаXML.Явное);
	СтрокаXML = ЗаписьXML.Закрыть();
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(СтрокаXML);
	
	Пока ЧтениеXML.Прочитать() Цикл
		
		Если ЧтениеXML.Имя = "structure" 
			И ЧтениеXML.ПолучитьАтрибут("name") = "parameters" 
			И ЧтениеXML.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда
			
			Прервать;
			             
		ИначеЕсли ЧтениеXML.Имя = "field" Тогда
			
			ТекущийКлюч	= ЧтениеXML.ПолучитьАтрибут("nameRu");
			ТекущийКлюч	= ?(ЗначениеЗаполнено(ТекущийКлюч), ТекущийКлюч, ЧтениеXML.ПолучитьАтрибут("name"));
			Если ЗначениеЗаполнено(ТекущийКлюч) Тогда
				Результат.Вставить(ТекущийКлюч);
			КонецЕсли;
			
		КонецЕсли;
		
	КонецЦикла;
	
	ЧтениеXML.Закрыть();
	
	ЗаполнитьЗначенияСвойств(Результат, ПараметрыФормы);
	
	Возврат Результат;
	
КонецФункции