ПроверитьПараметрыАдминистрирования (БСП)

Автор: 1С
ОбщийМодуль.АдминистрированиеКластераCOM
БСП

Проверить параметры администрирования. Проверяет корректность параметров администрирования.

// Проверяет корректность параметров администрирования.
//
// Параметры:
//   ПараметрыАдминистрированияКластера - Структура - структура, описывающая параметры подключения к кластеру серверов,
//                  описание см. АдминистрированиеКластера.ПараметрыАдминистрированияКластера().
//   ПараметрыАдминистрированияИБ - Структура - структура, описывающая параметры подключения к информационной базе,
//                  описание см. АдминистрированиеКластера.ПараметрыАдминистрированияИнформационнойБазыКластера().
//   ПроверятьПараметрыАдминистрированияКластера - Булево -  флаг необходимости проверки параметров администрирования 
//                  кластера.
//  ПроверятьПараметрыАдминистрированияИнформационнойБазы - Булево - флаг необходимости проверки параметров
//                  администрирования кластера.
//
Процедура ПроверитьПараметрыАдминистрирования(Знач ПараметрыАдминистрированияКластера, Знач ПараметрыАдминистрированияИБ = Неопределено,
	ПроверятьПараметрыАдминистрированияИнформационнойБазы = Истина,
	ПроверятьПараметрыАдминистрированияКластера = Истина) Экспорт
	
	Если ПроверятьПараметрыАдминистрированияКластера ИЛИ ПроверятьПараметрыАдминистрированияИнформационнойБазы Тогда
		
		Попытка
			COMСоединитель = COMСоединитель();
			
			СоединениеСАгентомСервера = СоединениеСАгентомСервера(
				COMСоединитель,
				ПараметрыАдминистрированияКластера.АдресАгентаСервера,
				ПараметрыАдминистрированияКластера.ПортАгентаСервера);
			
			Кластер = ПолучитьКластер(
				СоединениеСАгентомСервера,
				ПараметрыАдминистрированияКластера.ПортКластера,
				ПараметрыАдминистрированияКластера.ИмяАдминистратораКластера,
				ПараметрыАдминистрированияКластера.ПарольАдминистратораКластера);
		Исключение
			Если ОбщегоНазначения.ЭтоWindowsСервер() Тогда 
				ТекстИсключения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
					НСтр("ru = '%1
					           |
					           |Если компонента ""comcntr"" не зарегистрирована или ее версия не совпадает с требуемой,
					           |следует зарегистрировать ее на компьютере %2 выполнив команду cmd с повышением привилегий UAC
					           |для учетной записи ОС Windows, от имени которой выполняется 1С:Предприятие.
					           |
					           |Например:
					           |regsvr32.exe ""%3""'"),
					КраткоеПредставлениеОшибки(ИнформацияОбОшибке()),
					ИмяКомпьютера(),
					КаталогПрограммы() + "comcntr.dll");
			Иначе 
				ТекстИсключения = КраткоеПредставлениеОшибки(ИнформацияОбОшибке());
			КонецЕсли;
			
			ВызватьИсключение ТекстИсключения
			
		КонецПопытки;
		
	КонецЕсли;
	
	Если ПроверятьПараметрыАдминистрированияИнформационнойБазы Тогда
		
		СоединениеСРабочимПроцессом = СоединениеСРабочимПроцессом(COMСоединитель, СоединениеСАгентомСервера, Кластер);
		
		ПолучитьИБ(СоединениеСРабочимПроцессом,
			Кластер,
			ПараметрыАдминистрированияИБ.ИмяВКластере,
			ПараметрыАдминистрированияИБ.ИмяАдминистратораИнформационнойБазы,
			ПараметрыАдминистрированияИБ.ПарольАдминистратораИнформационнойБазы);
		
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

СохраненныеПараметрыАдминистрирования (БСП)

СохранитьПараметрыАдминистрирования (БСП)

ПроверитьВозможностьАдминистрированияОбменов (БСП)

ПараметрыАдминистрирования (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз