ПриНачалеВыполненияРегламентногоЗадания (БСП)

Автор: 1С
ОбщийМодуль.БлокировкаРаботыСВнешнимиРесурсами
БСП

При начале выполнения регламентного задания.

Процедура ПриНачалеВыполненияРегламентногоЗадания(РегламентноеЗадание) Экспорт
	
	Если Не ОбщегоНазначения.ДоступноИспользованиеРазделенныхДанных() Тогда
		Возврат;
	КонецЕсли;
	
	ЗапускЗаданияРазрешен = ОбщегоНазначения.ХранилищеСистемныхНастроекЗагрузить(
		"РегламентныеЗадания", 
		РегламентноеЗадание.ИмяМетода);
	
	Если ЗапускЗаданияРазрешен = Истина Тогда
		Возврат;
	КонецЕсли;
	
	Если Не РегламентноеЗаданиеРаботаетСВнешнимиРесурсами(РегламентноеЗадание) Тогда
		Возврат;
	КонецЕсли;
	
	Если Не РаботаСВнешнимиРесурсамиЗаблокирована() Тогда
		Возврат;
	КонецЕсли;
	
	НачатьТранзакцию();
	Попытка
		ЗаблокироватьДанныеПараметровБлокировки();
		
		ПараметрыБлокировки = СохраненныеПараметрыБлокировки();
		ОтключитьРегламентноеЗадание(ПараметрыБлокировки, РегламентноеЗадание);
		СохранитьПараметрыБлокировки(ПараметрыБлокировки);
		
		ЗафиксироватьТранзакцию();
	Исключение
		ОтменитьТранзакцию();
		ВызватьИсключение;
	КонецПопытки;
	
	Если ОбщегоНазначения.РазделениеВключено() Тогда
		ТекстИсключения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Приложение было перемещено.
			           |Регламентное задание ""%1"", работающее с внешними ресурсами, отключено.'"), 
			РегламентноеЗадание.Синоним);
	Иначе 
		ТекстИсключения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Изменилась строка соединения информационной базы.
			           |Возможно информационная база была перемещена.
			           |Регламентное задание ""%1"" отключено.'"), 
			РегламентноеЗадание.Синоним);
	КонецЕсли;
	
	ВызватьИсключение ТекстИсключения;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ВыполнитьРегламентноеЗаданиеВручную (БСП)

ВыполнитьОбменДаннымиПоРегламентномуЗаданию (БСП)

ЗаданиеВыгрузка (БСП)

ЗаданиеЗагрузка (БСП)

РегламентноеЗаданиеИспользуется (БСП)

РасписаниеРегламентногоЗадания (БСП)

УстановитьИспользованиеРегламентногоЗадания (БСП)

УстановитьРасписаниеРегламентногоЗадания (БСП)

1С Менеджер конфигураций