ПроверитьДатыЗапретаЗагрузкиДанных (БСП)

Автор: 1С
ОбщийМодуль.ДатыЗапретаИзменения
БСП

Проверить даты запрета загрузки данных. Проверяет наличие запрета загрузки элемента данных или набор записей Данные.

// Проверяет наличие запрета загрузки элемента данных или набор записей Данные.
// При этом выполняется проверка старой и новой версии данных. 
// Для корректной работы требуется предварительная настройка
// процедуры ДанныеДляПроверкиЗапретаИзменения модуля ДатыЗапретаИзмененияПереопределяемый.
//
// Параметры:
//  Данные              - СправочникОбъект, 
//                        ДокументОбъект, 
//                        ПланВидовХарактеристикОбъект,
//                        ПланСчетовОбъект, 
//                        ПланВидовРасчетаОбъект, 
//                        БизнесПроцессОбъект,
//                        ЗадачаОбъект, 
//                        ПланОбменаОбъект, 
//                        УдалениеОбъекта,
//                        РегистрСведенийНаборЗаписей,
//                        РегистрНакопленияНаборЗаписей,
//                        РегистрБухгалтерииНаборЗаписей,
//                        РегистрРасчетаНаборЗаписей - элемент данных или набор записей.
//
//  УзелПроверкиЗапретаЗагрузки  - ПланОбменаСсылка - узел, для которого требуется проверка.
//
//  Отказ               - Булево - возвращаемый параметр: Истина, если загрузка запрещена.
//
//  ОписаниеОшибки      - Null      - (значение по умолчанию) - сведения о запретах не требуются.
//                      - Строка    - (возвращаемое значение) - вернуть текстовое описание найденных запретов.
//                      - Структура - (возвращаемое значение) - вернуть структурное описание найденных запретов,
//                                    подробнее см. функцию ДатыЗапретаИзменения.НайденЗапретИзмененияДанных.
//
Процедура ПроверитьДатыЗапретаЗагрузкиДанных(Данные, УзелПроверкиЗапретаЗагрузки, Отказ, ОписаниеОшибки = Null) Экспорт
	
	Если ТипЗнч(Данные) = Тип("УдалениеОбъекта") Тогда
		ОбъектМетаданных = Данные.Ссылка.Метаданные();
	Иначе
		ОбъектМетаданных = Данные.Метаданные();
	КонецЕсли;
	
	ИсточникиДанных = ДатыЗапретаИзмененияСлужебный.ИсточникиДанныхДляПроверкиЗапретаИзменения();
	Если ИсточникиДанных.Получить(ОбъектМетаданных.ПолноеИмя()) = Неопределено Тогда
		Возврат; // Для текущего типа объекта не определены запреты по датам.
	КонецЕсли;
	
	ДополнительныеПараметры = Новый Структура;
	ДополнительныеПараметры.Вставить("ПроверкаЗапретаИзменения",    Ложь);
	ДополнительныеПараметры.Вставить("УзелПроверкиЗапретаЗагрузки", УзелПроверкиЗапретаЗагрузки);
	ДополнительныеПараметры.Вставить("ОписаниеОшибки",              ОписаниеОшибки);
	ДополнительныеПараметры.Вставить("СообщитьОЗапрете",            Ложь);
	
	ЭтоРегистр = ОбщегоНазначения.ЭтоРегистр(ОбъектМетаданных);
	
	ДатыЗапретаИзмененияСлужебный.ПроверитьДатыЗапретаИзмененияЗагрузкиДанных(Данные,
		Отказ, ЭтоРегистр, ЭтоРегистр, ТипЗнч(Данные) = Тип("УдалениеОбъекта"), ДополнительныеПараметры);
	
	ОписаниеОшибки = ДополнительныеПараметры.ОписаниеОшибки;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ПроверитьДатыЗапретаИзмененияЗагрузкиДанных (БСП)

ОткрытьДатыЗапретаЗагрузкиДанных (БСП)

ПропуститьПроверкуДатЗапрета (БСП)

ОбновитьВерсиюДатЗапретаИзмененияПриЗагрузкеДанных (БСП)

ОбновлениеВерсииДатЗапретаИзмененияПослеЗагрузкиДанныхПриЗаписи (БСП)

Проверка даты запрета изменения данных

ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента (БСП)

ПроверитьДатуЗапретаИзмененияПередУдалением (БСП)

ТекстОшибкиДатыЗапретаЗагрузкиНеВнедрены (БСП)

TurboConf - расширение Конфигуратора 1С