ПередОбновлениемЗадания (БСП)

Автор: 1С
ОбщийМодуль.ДополнительныеОтчетыИОбработкиВМоделиСервиса
БСП

Перед обновлением задания. Вызывается перед записью изменений регламентного задания дополнительных отчетов и обработок в модели сервиса.

// Вызывается перед записью изменений регламентного задания дополнительных отчетов и обработок в модели сервиса.
//
// Параметры:
//   Объект - СправочникОбъект.ДополнительныеОтчетыИОбработки - Объект дополнительного отчета или обработки.
//   Команда - СправочникТабличнаяЧастьСтрока.ДополнительныеОтчетыИОбработки.Команды - Описание команды.
//   Задание - РегламентноеЗадание, СтрокаТаблицыЗначений - Описание регламентного задания.
//       См. РегламентныеЗаданияСервер.Задание.
//   Изменения - Структура - Значения реквизитов задания, которые необходимо изменить.
//       См. описание 2-го параметра процедуры РегламентныеЗаданияСервер.ИзменитьЗадание.
//       Если установить Неопределено, то регламентное задание не будет изменено.
//
Процедура ПередОбновлениемЗадания(Объект, Команда, Задание, Изменения) Экспорт
	
	Если Не ОбщегоНазначения.РазделениеВключено() Тогда
		Возврат;
	КонецЕсли;
	
	Если Не Константы.РазрешитьВыполнениеДОИОРегламентнымиЗаданиямиВМоделиСервиса.Получить() Тогда
		ВызватьИсключение НСтр("ru = 'Периодическое выполнение команд дополнительных обработок в качестве заданий запрещено администратором сервиса.'");
	КонецЕсли;
	
	МинимальныйИнтервал = Константы.МинимальныйИнтервалРегламентныхЗаданийДОИОВМоделиСервиса.Получить();
	ИсходнаяДата = ТекущаяДатаСеанса();
	ПроверяемаяДата = ИсходнаяДата + МинимальныйИнтервал - 1;
	
	Если Задание.Расписание.ТребуетсяВыполнение(ПроверяемаяДата, ИсходнаяДата) Тогда
		ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Расписание, задаваемое для выполнения команд дополнительного отчета или обработки в качестве заданий, должно быть не чаще, чем 1 раз в %1 секунд.'"), 
			МинимальныйИнтервал);
	КонецЕсли;
		
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ПередОбновлениемЗадания (БСП)

ПередОбновлениемИнформационнойБазы (БСП)

РезультатЗаданияПроверкиНаличияОбновлений (БСП)

ЗаданияОбновлениеКлассификаторов (БСП)

ОбновлениеАгрегатовОбработчикЗадания (БСП)

ОчередьЗаданийПередУдалением (БСП)

ПриВключенииОтложенногоОбновления (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз