СоединениеССерверомИнтернета (БСП)

Соединение сервером интернета. Устанавливает соединение с сервером Интернета по протоколу http(s).

// Устанавливает соединение с сервером Интернета по протоколу http(s).
//
// Параметры:
//  ПараметрыСоединения - Структура - дополнительные параметры для "тонкой" настройки.
//    * Схема - Строка константы "http"
//    * Хост - Строка
//    * Порт - Число
//    * Логин - Строка
//    * Пароль - Строка
//    * Таймаут - Число - определяет время ожидания осуществляемого соединения и операций, в секундах.
//
Функция СоединениеССерверомИнтернета(ПараметрыСоединения) Экспорт

	Прокси = ПолучениеФайловИзИнтернетаКлиентСервер.ПолучитьПрокси(ПараметрыСоединения.Схема);
	
	Таймаут = 30;
	Если ПараметрыСоединения.Свойство("Таймаут") Тогда
		Таймаут = ПараметрыСоединения.Таймаут;
	КонецЕсли;
	
	Попытка
		СертификатыУЦ = Новый СертификатыУдостоверяющихЦентровОС;
		
		Соединение = Новый HTTPСоединение(
			ПараметрыСоединения.Хост,
			ПараметрыСоединения.Порт,
			ПараметрыСоединения.Логин,
			ПараметрыСоединения.Пароль, 
			Прокси,
			Таймаут,
			?(НРег(ПараметрыСоединения.Схема) = "http", Неопределено, Новый ЗащищенноеСоединениеOpenSSL(, СертификатыУЦ)));
	Исключение
		ИнформацияОбОшибке = ИнформацияОбОшибке();	
		ЗаписьЖурналаРегистрации(
			НСтр("ru = 'Электронная подпись в модели сервиса.Соединение с сервером интернета'", ОбщегоНазначенияКлиентСервер.КодОсновногоЯзыка()),
			УровеньЖурналаРегистрации.Ошибка,,,
			ПодробноеПредставлениеОшибки(ИнформацияОбОшибке));
		ВызватьИсключение;
	КонецПопытки;
	
	Возврат Соединение;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Устанавливает соединение с сервером Интернета по протоколу http(s).
//
// Параметры:
//  ПараметрыСоединения - Структура - дополнительные параметры для "тонкой" настройки.
//    * Схема - Строка константы "http"
//    * Хост - Строка
//    * Порт - Число
//    * Логин - Строка
//    * Пароль - Строка
//    * Таймаут - Число - определяет время ожидания осуществляемого соединения и операций, в секундах.
//
Функция СоединениеССерверомИнтернета(ПараметрыСоединения) Экспорт

	Прокси = ПолучениеФайловИзИнтернетаКлиентСервер.ПолучитьПрокси(ПараметрыСоединения.Схема);
	
	Таймаут = 30;
	Если ПараметрыСоединения.Свойство("Таймаут") Тогда
		Таймаут = ПараметрыСоединения.Таймаут;
	КонецЕсли;
	
	Попытка
		СертификатыУЦ = Новый СертификатыУдостоверяющихЦентровОС;
		
		Соединение = Новый HTTPСоединение(
			ПараметрыСоединения.Хост,
			ПараметрыСоединения.Порт,
			ПараметрыСоединения.Логин,
			ПараметрыСоединения.Пароль, 
			Прокси,
			Таймаут,
			?(НРег(ПараметрыСоединения.Схема) = "http", Неопределено, Новый ЗащищенноеСоединениеOpenSSL(, СертификатыУЦ)));
	Исключение
		ИнформацияОбОшибке = ИнформацияОбОшибке();	
		ЗаписьЖурналаРегистрации(
			НСтр("ru = 'Электронная подпись в модели сервиса.Соединение с сервером интернета'", ОбщегоНазначенияКлиентСервер.КодОсновногоЯзыка()),
			УровеньЖурналаРегистрации.Ошибка,,,
			ПодробноеПредставлениеОшибки(ИнформацияОбОшибке));
		ВызватьИсключение;
	КонецПопытки;
	
	Возврат Соединение;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////