ВыполнитьПроверку (БСП)

Выполнить проверку. Выполняет указанную проверку ведения учета с заданными параметрами.

// Выполняет указанную проверку ведения учета с заданными параметрами.
//
// Параметры:
//   Проверка                    - СправочникСсылка.ПравилаПроверкиУчета, Строка - правило проверки,
//                                 которая будет выполняться либо строковый идентификатор указанного правила.
//   ПараметрыВыполненияПроверки - Структура, Массив - произвольные дополнительные параметры проверки,
//                                 которые уточняют, что и как именно проверять. 
//                                 См. КонтрольВеденияУчета.ПараметрыВыполненияПроверки.
//     - Структура - один параметр проверки:
//       * Свойство1 - ЛюбаяСсылка, Булево, Число, Строка, Дата - первое значение параметра.
//       * Свойство2 - ЛюбаяСсылка, Булево, Число, Строка, Дата - второе значение параметра.
//       * Свойство3 - ЛюбаяСсылка, Булево, Число, Строка, Дата - третье значение параметра.
//       ...                                              
//     - Массив - несколько параметров проверки (элементы массива типа Структура, как описано выше). 
//
// Пример:
//   1. Проверка = КонтрольВеденияУчета.ПроверкаПоИдентификатору("ПроверитьСсылочнуюЦелостность");
//      КонтрольВеденияУчета.ВыполнитьПроверку(Проверка);
//   2. ПараметрыВыполненияПроверки = Новый Массив;
//      Параметр1 = КонтрольВеденияУчета.ПараметрыВыполненияПроверки("ЗакрытиеМесяца", Организация1, ЗакрываемыйМесяц);
//      ПараметрыВыполненияПроверки.Добавить(Параметр1);
//      Параметр2 = КонтрольВеденияУчета.ПараметрыВыполненияПроверки("ЗакрытиеМесяца", Организация2, ЗакрываемыйМесяц);
//      ПараметрыВыполненияПроверки.Добавить(Параметр2);
//      ВыполнитьПроверку("ПроверитьПроведениеДокументов", ПараметрыВыполненияПроверки);
//
Процедура ВыполнитьПроверку(Знач Проверка, Знач ПараметрыВыполненияПроверки = Неопределено) Экспорт
	
	Если ТипЗнч(Проверка) = Тип("Строка") Тогда
		ВыполняемаяПроверка = ПроверкаПоИдентификатору(Проверка);
		Если ВыполняемаяПроверка.Пустая() Тогда
			ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
				НСтр("ru = 'Проверка ведения учета с идентификатором ""%1"" не существует (см. КонтрольВеденияУчетаПереопределяемый.ПриОпределенииПроверок)'"),
				Проверка);
		КонецЕсли;
	Иначе
		ОбщегоНазначенияКлиентСервер.ПроверитьПараметр("КонтрольВеденияУчета.ВыполнитьПроверку", "Проверка",
			Проверка, Тип("СправочникСсылка.ПравилаПроверкиУчета"));
		ВыполняемаяПроверка = Проверка;
	КонецЕсли;
	
	Если ПараметрыВыполненияПроверки <> Неопределено Тогда
		ПроверитьПараметрыВыполненияПроверки(ПараметрыВыполненияПроверки, "КонтрольВеденияУчета.ВыполнитьПроверку");
	КонецЕсли;
		
	КонтрольВеденияУчетаСлужебный.ВыполнитьПроверку(ВыполняемаяПроверка, ПараметрыВыполненияПроверки);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Выполняет указанную проверку ведения учета с заданными параметрами.
//
// Параметры:
//   Проверка                    - СправочникСсылка.ПравилаПроверкиУчета, Строка - правило проверки,
//                                 которая будет выполняться либо строковый идентификатор указанного правила.
//   ПараметрыВыполненияПроверки - Структура, Массив - произвольные дополнительные параметры проверки,
//                                 которые уточняют, что и как именно проверять. 
//                                 См. КонтрольВеденияУчета.ПараметрыВыполненияПроверки.
//     - Структура - один параметр проверки:
//       * Свойство1 - ЛюбаяСсылка, Булево, Число, Строка, Дата - первое значение параметра.
//       * Свойство2 - ЛюбаяСсылка, Булево, Число, Строка, Дата - второе значение параметра.
//       * Свойство3 - ЛюбаяСсылка, Булево, Число, Строка, Дата - третье значение параметра.
//       ...                                              
//     - Массив - несколько параметров проверки (элементы массива типа Структура, как описано выше). 
//
// Пример:
//   1. Проверка = КонтрольВеденияУчета.ПроверкаПоИдентификатору("ПроверитьСсылочнуюЦелостность");
//      КонтрольВеденияУчета.ВыполнитьПроверку(Проверка);
//   2. ПараметрыВыполненияПроверки = Новый Массив;
//      Параметр1 = КонтрольВеденияУчета.ПараметрыВыполненияПроверки("ЗакрытиеМесяца", Организация1, ЗакрываемыйМесяц);
//      ПараметрыВыполненияПроверки.Добавить(Параметр1);
//      Параметр2 = КонтрольВеденияУчета.ПараметрыВыполненияПроверки("ЗакрытиеМесяца", Организация2, ЗакрываемыйМесяц);
//      ПараметрыВыполненияПроверки.Добавить(Параметр2);
//      ВыполнитьПроверку("ПроверитьПроведениеДокументов", ПараметрыВыполненияПроверки);
//
Процедура ВыполнитьПроверку(Знач Проверка, Знач ПараметрыВыполненияПроверки = Неопределено) Экспорт
	
	Если ТипЗнч(Проверка) = Тип("Строка") Тогда
		ВыполняемаяПроверка = ПроверкаПоИдентификатору(Проверка);
		Если ВыполняемаяПроверка.Пустая() Тогда
			ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
				НСтр("ru = 'Проверка ведения учета с идентификатором ""%1"" не существует (см. КонтрольВеденияУчетаПереопределяемый.ПриОпределенииПроверок)'"),
				Проверка);
		КонецЕсли;
	Иначе
		ОбщегоНазначенияКлиентСервер.ПроверитьПараметр("КонтрольВеденияУчета.ВыполнитьПроверку", "Проверка",
			Проверка, Тип("СправочникСсылка.ПравилаПроверкиУчета"));
		ВыполняемаяПроверка = Проверка;
	КонецЕсли;
	
	Если ПараметрыВыполненияПроверки <> Неопределено Тогда
		ПроверитьПараметрыВыполненияПроверки(ПараметрыВыполненияПроверки, "КонтрольВеденияУчета.ВыполнитьПроверку");
	КонецЕсли;
		
	КонтрольВеденияУчетаСлужебный.ВыполнитьПроверку(ВыполняемаяПроверка, ПараметрыВыполненияПроверки);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////