ПриОпределенииПроверок (БСП)

Автор: 1С
ОбщийМодуль.КонтрольВеденияУчетаПереопределяемый
1С БСП

При определении проверок. Предназначена для подключения собственных правил проверки ведения учета.

// Предназначена для подключения собственных правил проверки ведения учета.
//
// Параметры:
//   ГруппыПроверок - ТаблицаЗначений - Таблица, в которую добавляются группы проверок:
//      * Наименование                 - Строка - Наименование группы проверок.
//      * ИдентификаторГруппы          - Строка - Строковый идентификатор группы проверок, например: 
//                                       "СистемныеПроверки", "ЗакрытиеМесяца", "ПроверкиНДС" и т.п.
//                                       Обязателен для заполнения.
//      * Идентификатор                - Строка - Строковый идентификатор группы проверок. Обязателен для заполнения.
//                                       Для уникальности формат идентификатора следует выбирать следующим:
//                                       "<Название программного продукта>.<Идентификатор проверки>". 
//                                       Например: "СтандартныеПодсистемы.СистемныеПроверки".
//      * КонтекстПроверокВеденияУчета - ОпределяемыйТип.КонтекстПроверокВеденияУчета - значение, дополнительно
//                                       уточняющее принадлежность группы проверок ведения учета к определенной
//                                       категории.
//      * Комментарий                  - Строка - комментарий к группе проверок.
//
//   Проверки - ТаблицаЗначений - Таблица, в которую добавляются проверки:
//      * ИдентификаторГруппы          - Строка - Строковый идентификатор группы проверок, например: 
//                                                "СистемныеПроверки", "ЗакрытиеМесяца", "ПроверкиНДС" и т.п.
//                                                 Обязателен для заполнения.
//      * Наименование                 - Строка - Наименование проверки, выводимое пользователю.
//      * Причины                      - Строка - Описание возможных причин, которые приводят к возникновению проблемы.
//      * Рекомендация                 - Строка - Рекомендация по решению возникшей проблемы.
//      * Идентификатор                - Строка - Строковый идентификатор элемента. Обязателен для заполнения.
//                                                Формат идентификатора должен быть следующим:
//                                                <Название программного продукта>.<Идентификатор проверки>. Например:
//                                                СтандартныеПодсистемы.СистемныеПроверки.
//      * ДатаНачалаПроверки           - Дата - Пороговая дата, обозначающая границу проверяемых объектов
//                                              (только для объектов с датой, например, документов). Объекты, дата 
//                                              которых меньше указанной, не следует проверять. По умолчанию 
//                                              не заполнено (т.е. проверять все).
//      * ЛимитПроблем                 - Число - Количество проверяемых объектов. По умолчанию 1000. 
//                                               Если указан 0, то следует проверять все объекты.
//      * ОбработчикПроверки           - Строка - Имя экспортной процедуры-обработчика серверного общего модуля
//                                                в виде ИмяМодуля.ИмяПроцедуры.
//      * ОбработчикПереходаКИсправлению - Строка - Имя экспортной процедуры-обработчика клиентского общего модуля
//                                                  для перехода к исправлению проблемы в виде "ИмяМодуля.ИмяПроцедуры"
//                                                  или полное имя формы, которую следует открыть для исправления проблемы.
//                                                  Процедура-обработчик принимает на вход два параметра: 
//                                                    ПараметрыИсправления - Структура - со свойствами:
//                                                      ИдентификаторПроверки - Строка - строковый идентификатор проверки;
//                                                      ВидПроверки - СправочникСсылка.ВидыПроверок - вид проверки,
//                                                               дополнительно уточняющий область исправления проблемы;
//                                                    ДополнительныеПараметры - Неопределено - параметр не используется.
//                                                 При открытии формы в нее передаются такие же параметры, как свойства 
//                                                 указанной выше структуры ПараметрыИсправления.
//      * БезОбработчикаПроверки       - Булево - признак служебной проверки, которая не имеет процедуры-обработчика.
//      * ЗапрещеноИзменениеВажности   - Булево - Если Истина, то администратор не сможет перенастраивать 
//                                                важность данной проверки.
//      * КонтекстПроверокВеденияУчета - ОпределяемыйТип.КонтекстПроверокВеденияУчета - значение, дополнительно 
//                                                уточняющее принадлежность проверки ведения учета к определенной группе 
//                                                или категории.
//      * УточнениеКонтекстаПроверокВеденияУчета - ОпределяемыйТип.УточнениеКонтекстаПроверокВеденияУчета - второе значение, 
//                                                 дополнительно уточняющее принадлежность проверки ведения учета 
//                                                 к определенной группе или категории.
//      * ДополнительныеПараметры      - ХранилищеЗначений - Произвольная дополнительная информация о проверке
//                                                 для программного использования.
//      * Комментарий                  - Строка - текстовый комментарий к проверке.
//      * Отключена                    - Булево - если Истина, то проверка не будет выполняться в фоне по расписанию.
//
// Пример:
//   1) Добавление проверки
//      Проверка = Проверки.Добавить();
//      Проверка.ИдентификаторГруппы = "СистемныеПроверки";
//      Проверка.Наименование        = НСтр("ru='Демо: Проверка заполнения комментария в документах ""Демо: Поступление товаров""'");
//      Проверка.Причины             = НСтр("ru='Не введен комментарий в документе.'");
//      Проверка.Рекомендация        = НСтр("ru='Ввести комментарий в документе.'");
//      Проверка.Идентификатор       = "ПроверитьКомментарийВПоступленииТоваров";
//      Проверка.ОбработчикПроверки  = "_ДемоСтандартныеПодсистемы.ПроверитьКомментарийВПоступленииТоваров";
//      Проверка.ДатаНачалаПроверки  = Дата('20140101000000');
//      Проверка.ЛимитПроблем        = 3;
//   2) Добавление группы проверок
//      ГруппаПроверок = ГруппыПроверок.Добавить();
//      ГруппаПроверок.Наименование                 = НСтр("ru='Системные проверки'");
//      ГруппаПроверок.Идентификатор                = "СтандартныеПодсистемы.СистемныеПроверки";
//      ГруппаПроверок.КонтекстПроверокВеденияУчета = "СистемныеПроверки";
//
Процедура ПриОпределенииПроверок(ГруппыПроверок, Проверки) Экспорт
	
	// _Демо начало примера
	
	ГруппаПроверок = ГруппыПроверок.Добавить();
	ГруппаПроверок.Наименование                 = НСтр("ru='Демонстрационные проверки'");
	ГруппаПроверок.Идентификатор                = "_ДемоПроверкиВеденияУчета";
	ГруппаПроверок.КонтекстПроверокВеденияУчета = "_ДемоПроверкиВеденияУчета";
	
	Проверка = Проверки.Добавить();
	Проверка.ИдентификаторГруппы          = ГруппаПроверок.Идентификатор;
	Проверка.Наименование                 = НСтр("ru='Проверка заполнения комментария в документах ""Демо: Поступление товаров""'");
	Проверка.Причины                      = НСтр("ru='Не введен комментарий в документе.'");
	Проверка.Рекомендация                 = НСтр("ru='Ввести комментарий в документе.'");
	Проверка.Идентификатор                = "Демо.ПроверитьКомментарийВПоступленииТоваров";
	Проверка.ОбработчикПроверки           = "_ДемоСтандартныеПодсистемы.ПроверитьКомментарийВПоступленииТоваров";
	Проверка.ДатаНачалаПроверки           = Дата('20140101000000');
	Проверка.ЛимитПроблем                 = 3;
	Проверка.ЗапрещеноИзменениеВажности   = Истина;
	Проверка.КонтекстПроверокВеденияУчета = "_ДемоПроверкиВеденияУчета";
	Проверка.Комментарий                  = НСтр("ru='Демонстрационная проверка.'");
	
	Проверка = Проверки.Добавить();
	Проверка.ИдентификаторГруппы          = ГруппаПроверок.Идентификатор;
	Проверка.Наименование                 = НСтр("ru='Проверка проведения документа ""Демо: Счет фактура полученный""'");
	Проверка.Причины                      = НСтр("ru='Документ не проведен.'");
	Проверка.Рекомендация                 = НСтр("ru='Провести документ.'");
	Проверка.Идентификатор                = "Демо.ПроверитьПроведенностьСчетаФактурыПолученного";
	Проверка.ОбработчикПроверки           = "_ДемоСтандартныеПодсистемы.ПроверитьПроведенностьСчетаФактурыПолученного";
	Проверка.ОбработчикПереходаКИсправлению = "_ДемоСтандартныеПодсистемыКлиент.ПровестиСчетаФактурыПоПроблемнымКонтрагентам";
	Проверка.ЗапрещеноИзменениеВажности   = Истина;
	Проверка.КонтекстПроверокВеденияУчета = "_ДемоПроверкиВеденияУчета";
	
	// _Демо конец примера
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ПриОпределенииПроверок (БСП)

ПриОпределенииПрикладныхПроверок (БСП)

ЕстьПроблемыСистемныхПроверок (БСП)

ВидыПроверок (БСП)

ЕстьИзмененияПараметровПроверокУчета (БСП)

ПриВыполненииСтандартныхПериодическихПроверокНаКлиенте (БСП)

ПриВыполненииСтандартныхПериодическихПроверокНаСервере (БСП)

ПроверкиВеденияУчета (БСП)

TurboConf ИР адаптер 2.63