ДанныеОбслуживающейОрганизации (БСП)

Автор: 1С
ОбщийМодуль.МиграцияПриложений
БСП

Данные обслуживающей организации. Получает данные обслуживающей организации в сервисе.

// Получает данные обслуживающей организации в сервисе.
//
// Параметры:
//   ПараметрыДоступа - Структура - описание см. ВызватьМетодПрограммногоИнтерфейса().
//
// Возвращаемое значение:
//   Структура - ключи:
//     * Код - Число.
//     * Наименование - Строка.
//     * ЭлектроннаяПочта - Строка
//     * Телефон - Строка.
//
Функция ДанныеОбслуживающейОрганизации(ПараметрыДоступа) Экспорт
	
	ПараметрыМетода = Новый Структура;
	
	ПараметрыМетода.Вставить("auth", Новый Структура);
	ПараметрыМетода.auth.Вставить("account", ПараметрыДоступа.КодАбонента);
	
	ПараметрыМетода.Вставить("general", Новый Структура);
	ПараметрыМетода.general.Вставить("type", "ext");
	ПараметрыМетода.general.Вставить("method", "account/servant_info");
	ПараметрыМетода.general.Вставить("version", 1);
	
	ПараметрыМетода.Вставить("id", ПараметрыДоступа.КодАбонента);
	
	Результат = Новый Структура("Код, Наименование, ЭлектроннаяПочта, Телефон, ОписаниеОшибки");
	
	Попытка
		
		РезультатВызова = ВызватьМетодПрограммногоИнтерфейса(ПараметрыДоступа, ПараметрыМетода);
		
		Результат.Код = РезультатВызова.servant.id;
		Результат.Наименование = РезультатВызова.servant.name;
		Результат.ЭлектроннаяПочта = РезультатВызова.servant.email;
		Результат.Телефон = РезультатВызова.servant.phone;
	
	Исключение
		
		Результат.ОписаниеОшибки = КраткоеПредставлениеОшибки(ИнформацияОбОшибке());
		
	КонецПопытки;
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ТарифОбслуживающейОрганизаций (БСП)

ТарифыОбслуживающейОрганизации (БСП)

ОбслуживающиеОрганизацииАбонента (БСП)

СтраницаВыбораТарифаОбслуживающейОрганизации (БСП)

ТарифОбслуживающейОрганизации (БСП)

ОписаниеДанныхОрганизации (БСП)

ПриОпределенииРегистрационныхДанныхОрганизации (БСП)

РегистрационныеДанныеОрганизации (БСП)

TurboConf ИР адаптер 1.94