НачатьЗагрузку (БСП)

Автор: 1С
ОбщийМодуль.МиграцияПриложений
БСП

Начать загрузку. Инициализирует загрузку.

// Инициализирует загрузку.
//
// ПользователиОбласти - Соответствие - в качестве ключа исходная ссылка, в качестве значения логин пользователя.
//
Процедура НачатьЗагрузку(ПользователиОбласти) Экспорт
	
	ПроверитьИспользованиеРазделениеСеанса();
		
	НачатьТранзакцию();
	Попытка
		СостояниеЗагрузки = РегистрыСведений.МиграцияПриложенийСостояниеЗагрузки.СоздатьМенеджерЗаписи();
		СостояниеЗагрузки.Прочитать();
		Если СостояниеЗагрузки.Выбран() Тогда
			ВызватьИсключение НСтр("ru = 'Загрузка уже выполняется.'");
		КонецЕсли;
		
		СостояниеЗагрузки = РегистрыСведений.МиграцияПриложенийСостояниеЗагрузки.СоздатьМенеджерЗаписи();
		СостояниеЗагрузки.ДатаНачала = ТекущаяУниверсальнаяДата();
		СостояниеЗагрузки.СоответствиеСсылок = Новый ХранилищеЗначения(Новый Соответствие);
		СостояниеЗагрузки.Пользователи = Новый ХранилищеЗначения(ПользователиОбласти);
		СостояниеЗагрузки.Записать();
		
		ЗначенияПоУмолчанию = РегламентныеЗадания.СоздатьРегламентноеЗадание(Метаданные.РегламентныеЗадания.МиграцияПриложенийЗагрузка);
		
		ПараметрыЗадания = Новый Структура;
		ПараметрыЗадания.Вставить("Метаданные", Метаданные.РегламентныеЗадания.МиграцияПриложенийЗагрузка);
		ПараметрыЗадания.Вставить("Использование", Истина);
		ПараметрыЗадания.Вставить("Расписание", ЗначенияПоУмолчанию.Расписание);
		ПараметрыЗадания.Вставить("КоличествоПовторовПриАварийномЗавершении", ЗначенияПоУмолчанию.КоличествоПовторовПриАварийномЗавершении);
		ПараметрыЗадания.Вставить("ИнтервалПовтораПриАварийномЗавершении", ЗначенияПоУмолчанию.ИнтервалПовтораПриАварийномЗавершении);
		ПараметрыЗадания.Вставить("Ключ", ЗначенияПоУмолчанию.Ключ);
		
		РегламентныеЗаданияСервер.ДобавитьЗадание(ПараметрыЗадания);
		
		ЗафиксироватьТранзакцию();
	Исключение
		ОтменитьТранзакцию();
		ВызватьИсключение;
	КонецПопытки;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

НачатьСклонение (БСП)

Пример работы с OpenOffice/LibreOffice Calc

ПредметНачалоВыбора (БСП)

НачатьВыгрузку (БСП)

ПредставлениеНачалоВыбораЗавершение (БСП)

ПродолжитьОткрытиеНачало (БСП)

Загрузка XML в 1С из FTP

НачатьРегистрациюРезультатаВыполненияОперации (БСП)

ЗаписатьСобытиеНачалоОбработки (БСП)

TurboConf - расширение Конфигуратора 1С