СоздатьПриложениеДляМиграции (БСП)

Создать приложение для миграции. Создает приложение для миграции в сервисе.

// Создает приложение для миграции в сервисе.
//
// Параметры:
//   ПараметрыДоступа - Структура - описание см. ВызватьМетодПрограммногоИнтерфейса().
//   Наименование - Строка - Наименование приложения.
//   ЧасовойПояс - Строка - часовой пояс приложения.
//   ПраваПользователей - ТаблицаЗначений - таблица с колонками:
//     * Логин - Строка - логин пользователя сервиса.
//     * Пользователь - СправочникСсылка.Пользователи - пользователь к которому будет привязан пользователь сервиса.
//     * Право - Строка - см. МиграцияПриложенийКлиентСервер.ИдентификаторAPIПрава().
//
// Возвращаемое значение:
//   Структура - ключи:
//     * АдресПриложения - Строка - url приложения.
//     * Логин - Строка - логин служебного пользователя.
//     * Пароль - Строка - пароль служебного пользователя.
//     * Код - Число - код области.
//
Функция СоздатьПриложениеДляМиграции(ПараметрыДоступа, Наименование, ЧасовойПояс, ПраваПользователей) Экспорт
	
	Права = Новый Массив;
	Для Каждого СтрокаТаблицы Из ПраваПользователей Цикл
		Если Не ЗначениеЗаполнено(СтрокаТаблицы.Право) Тогда
			Продолжить;
		КонецЕсли;
		Право = Новый Структура("login, role, userid");
		Право.login = СтрокаТаблицы.Логин;
		Право.role = МиграцияПриложенийКлиентСервер.ИдентификаторAPIПрава(СтрокаТаблицы.Право);
		Право.userid = Строка(СтрокаТаблицы.Пользователь.УникальныйИдентификатор());
		Права.Добавить(Право);
	КонецЦикла;
	
	ПараметрыМетода = Новый Структура;
	
	ПараметрыМетода.Вставить("auth", Новый Структура);
	ПараметрыМетода.auth.Вставить("account", ПараметрыДоступа.КодАбонента);
	
	ПараметрыМетода.Вставить("general", Новый Структура);
	ПараметрыМетода.general.Вставить("type", "ext");
	ПараметрыМетода.general.Вставить("method", "tenant/create_for_migration");
	ПараметрыМетода.general.Вставить("version", 3);
	
	ПараметрыМетода.Вставить("id", ПараметрыДоступа.КодАбонента);
	ПараметрыМетода.Вставить("application", Метаданные.Имя);
	ПараметрыМетода.Вставить("version", Метаданные.Версия);
	ПараметрыМетода.Вставить("name", Наименование);
	ПараметрыМетода.Вставить("timezone", ЧасовойПояс);
	ПараметрыМетода.Вставить("users", Права);
	
	РезультатВызова = ВызватьМетодПрограммногоИнтерфейса(ПараметрыДоступа, ПараметрыМетода);
	
	Результат = Новый Структура;
	Результат.Вставить("АдресПриложения", РезультатВызова.tenant.url);
	Результат.Вставить("Логин", РезультатВызова.tenant.login);
	Результат.Вставить("Пароль", РезультатВызова.tenant.password);
	Результат.Вставить("Код", РезультатВызова.tenant.id);
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Создает приложение для миграции в сервисе.
//
// Параметры:
//   ПараметрыДоступа - Структура - описание см. ВызватьМетодПрограммногоИнтерфейса().
//   Наименование - Строка - Наименование приложения.
//   ЧасовойПояс - Строка - часовой пояс приложения.
//   ПраваПользователей - ТаблицаЗначений - таблица с колонками:
//     * Логин - Строка - логин пользователя сервиса.
//     * Пользователь - СправочникСсылка.Пользователи - пользователь к которому будет привязан пользователь сервиса.
//     * Право - Строка - см. МиграцияПриложенийКлиентСервер.ИдентификаторAPIПрава().
//
// Возвращаемое значение:
//   Структура - ключи:
//     * АдресПриложения - Строка - url приложения.
//     * Логин - Строка - логин служебного пользователя.
//     * Пароль - Строка - пароль служебного пользователя.
//     * Код - Число - код области.
//
Функция СоздатьПриложениеДляМиграции(ПараметрыДоступа, Наименование, ЧасовойПояс, ПраваПользователей) Экспорт
	
	Права = Новый Массив;
	Для Каждого СтрокаТаблицы Из ПраваПользователей Цикл
		Если Не ЗначениеЗаполнено(СтрокаТаблицы.Право) Тогда
			Продолжить;
		КонецЕсли;
		Право = Новый Структура("login, role, userid");
		Право.login = СтрокаТаблицы.Логин;
		Право.role = МиграцияПриложенийКлиентСервер.ИдентификаторAPIПрава(СтрокаТаблицы.Право);
		Право.userid = Строка(СтрокаТаблицы.Пользователь.УникальныйИдентификатор());
		Права.Добавить(Право);
	КонецЦикла;
	
	ПараметрыМетода = Новый Структура;
	
	ПараметрыМетода.Вставить("auth", Новый Структура);
	ПараметрыМетода.auth.Вставить("account", ПараметрыДоступа.КодАбонента);
	
	ПараметрыМетода.Вставить("general", Новый Структура);
	ПараметрыМетода.general.Вставить("type", "ext");
	ПараметрыМетода.general.Вставить("method", "tenant/create_for_migration");
	ПараметрыМетода.general.Вставить("version", 3);
	
	ПараметрыМетода.Вставить("id", ПараметрыДоступа.КодАбонента);
	ПараметрыМетода.Вставить("application", Метаданные.Имя);
	ПараметрыМетода.Вставить("version", Метаданные.Версия);
	ПараметрыМетода.Вставить("name", Наименование);
	ПараметрыМетода.Вставить("timezone", ЧасовойПояс);
	ПараметрыМетода.Вставить("users", Права);
	
	РезультатВызова = ВызватьМетодПрограммногоИнтерфейса(ПараметрыДоступа, ПараметрыМетода);
	
	Результат = Новый Структура;
	Результат.Вставить("АдресПриложения", РезультатВызова.tenant.url);
	Результат.Вставить("Логин", РезультатВызова.tenant.login);
	Результат.Вставить("Пароль", РезультатВызова.tenant.password);
	Результат.Вставить("Код", РезультатВызова.tenant.id);
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////