ОбработчикВыбораЭлементовБазыКорреспондентаОбработкаВыбора (БСП)

Автор: 1С
ОбщийМодуль.ОбменДаннымиКлиент
БСП

Обработчик выбора элементов базы корреспондента обработка выбора. Обработчик обработки выбора элемента для формы задания настроек узла базы-корреспондента при настройке обмена через

// Обработчик обработки выбора элемента для формы задания настроек узла базы-корреспондента при настройке обмена через
// внешнее соединение.
//
// Параметры:
//	Элемент - ФормаКлиентскогоПриложения, ТаблицаФормы - Элемент для обработки выбора.
//	ВыбранноеЗначение - Произвольный - см. описание параметра ВыбранноеЗначение события ОбработкаВыбора.
//	ДанныеФормыКоллекция - ДанныеФормыКоллекция - Для режима подбора из списка.
//
Процедура ОбработчикВыбораЭлементовБазыКорреспондентаОбработкаВыбора(Знач Элемент, Знач ВыбранноеЗначение, Знач ДанныеФормыКоллекция=Неопределено) Экспорт
	
	Если ТипЗнч(ВыбранноеЗначение)<>Тип("Структура") Тогда
		Возврат;
	КонецЕсли;
	
	ИмяРеквизитаИдентификатора = ВыбранноеЗначение.ИмяРеквизита + "_Ключ";
	ИмяРеквизитаПредставления  = ВыбранноеЗначение.ИмяРеквизита;
	
	ТипЭлемента = ТипЗнч(Элемент);
	Если ТипЭлемента=Тип("ТаблицаФормы") Тогда
		
		Если ВыбранноеЗначение.РежимПодбора Тогда
			Если ДанныеФормыКоллекция<>Неопределено Тогда
				Фильтр = Новый Структура(ИмяРеквизитаИдентификатора, ВыбранноеЗначение.Идентификатор);
				СуществующиеСтроки = ДанныеФормыКоллекция.НайтиСтроки(Фильтр);
				Если СуществующиеСтроки.Количество() > 0 Тогда
					Возврат;
				КонецЕсли;
			КонецЕсли;
			
			Элемент.ДобавитьСтроку();
		КонецЕсли;
		
		ТекущиеДанные = Элемент.ТекущиеДанные;
		Если ТекущиеДанные<>Неопределено Тогда
			ТекущиеДанные[ИмяРеквизитаИдентификатора] = ВыбранноеЗначение.Идентификатор;
			ТекущиеДанные[ИмяРеквизитаПредставления]  = ВыбранноеЗначение.Представление;
		КонецЕсли;
		
	ИначеЕсли ТипЭлемента=Тип("ФормаКлиентскогоПриложения") Тогда
		Элемент[ИмяРеквизитаИдентификатора] = ВыбранноеЗначение.Идентификатор;
		Элемент[ИмяРеквизитаПредставления]  = ВыбранноеЗначение.Представление;
		
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ОбработчикВыбораЭлементовБазыКорреспондентаНачалоВыбора (БСП)

ОбработчикВыбораЭлементовБазыКорреспондентаПодбор (БСП)

ОбработкаВыбора (БСП)

ФормаОтчетаОбработкаВыбора (БСП)

ОбработкаВыбораДополненияВыгрузки (БСП)

СтранаМираОбработкаВыбора (БСП)

ФормаОбработкаВыбора (БСП)

ОбработкаВыбораТабличногоДокумента (БСП)

TurboConf - расширение Конфигуратора 1С