СохранитьДанныеОбновления (БСП)

Автор: 1С
ОбщийМодуль.ОбменДаннымиСервер
БСП

Сохранить данные обновления. Сохраняет содержимое файла из ЗавершитьЗаписьФайлаИПолучитьДанныеОбновления()

// Сохраняет содержимое файла из ЗавершитьЗаписьФайлаИПолучитьДанныеОбновления()
// в константу ДанныеДляОтложенногоОбновления.
//
// Параметры:
//  ДанныеОбновления - ХранилищеЗначения - содержимое файла.
//  ИмяФайлаСИзменениями - Строка - Имя файла, в котором находились данные.
//
Процедура СохранитьДанныеОбновления(ДанныеОбновления, ИмяФайлаСИзменениями) Экспорт
	
	Если ИмяФайлаСИзменениями = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	НачатьТранзакцию();
	Попытка
		Блокировка = Новый БлокировкаДанных;
		Блокировка.Добавить("Константа.ДанныеДляОтложенногоОбновления");
		Блокировка.Заблокировать();
		
		ЗначениеКонстанты = Константы.ДанныеДляОтложенногоОбновления.Получить().Получить();
		Если ТипЗнч(ЗначениеКонстанты) <> Тип("Массив") Тогда
			ЗначениеКонстанты = Новый Массив;
		КонецЕсли;
		
		ЗначениеКонстанты.Добавить(ДанныеОбновления);

		Константы.ДанныеДляОтложенногоОбновления.Установить(Новый ХранилищеЗначения(ЗначениеКонстанты));
		
		ЗафиксироватьТранзакцию();
	Исключение
		ОтменитьТранзакцию();
		ВызватьИсключение;
	КонецПопытки;
	
	ФайлСДанными = Новый Файл(ИмяФайлаСИзменениями);
	Если ФайлСДанными.Существует() Тогда
		УдалитьФайлы(ИмяФайлаСИзменениями);
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

СохранитьНастройкиОбновленияКонфигурации (БСП)

СохранитьИнформациюОДоступномОбновленииВНастройках (БСП)

СохранитьПоставляемыеДанныеВКэш (БСП)

ХранилищеНастроекДанныхФормСохранить (БСП)

СохранитьДанныеАутентификации (БСП)

СохранитьДанныеСессии (БСП)

ИнтерактивноеИзменениеВыгрузкиСохранитьНастройки (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз