ВсеНастройкиТранспортаОбменаСВнешнимиСистемами (БСП)

Все настройки транспорта обмена внешними системами. Таблица настроек транспорта обмена для всех настроенных обменов данными с внешними системами.

// Таблица настроек транспорта обмена для всех настроенных обменов данными с внешними системами.
//
// Возвращаемое значение:
//  ТаблицаЗначений - настройки транспорта
//    * Корреспондент - ПланОбменаСсылка - узел обмена, соответствующий корреспонденту.
//    * НастройкиТранспорта - Произвольный - сохраненные настройки транспорта сообщений обмена внешней системы.
//
Функция ВсеНастройкиТранспортаОбменаСВнешнимиСистемами() Экспорт
	
	Результат = Новый ТаблицаЗначений;
	Результат.Колонки.Добавить("Корреспондент");
	Результат.Колонки.Добавить("НастройкиТранспорта");
	
	ОбщийТекстЗапроса = "";
	ПланыОбменаБСП = ОбменДаннымиПовтИсп.ПланыОбменаБСП();
	
	Для Каждого ПланОбмена Из ПланыОбменаБСП Цикл
		
		Если Не ОбменДаннымиПовтИсп.ЭтоПланОбменаXDTO(ПланОбмена) Тогда
			Продолжить;
		КонецЕсли;
		
		ТекстЗапроса = 
		"ВЫБРАТЬ
		|	Т.Ссылка КАК Корреспондент,
		|	НастройкиТранспортаОбменаДанными.ПараметрыПодключенияВнешнейСистемы КАК ПараметрыПодключенияВнешнейСистемы
		|ИЗ
		|	#ТаблицаПланаОбмена КАК Т
		|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.НастройкиТранспортаОбменаДанными КАК НастройкиТранспортаОбменаДанными
		|		ПО (НастройкиТранспортаОбменаДанными.Корреспондент = Т.Ссылка)
		|ГДЕ
		|	НЕ Т.ЭтотУзел
		|	И НастройкиТранспортаОбменаДанными.ВидТранспортаСообщенийОбменаПоУмолчанию = ЗНАЧЕНИЕ(Перечисление.ВидыТранспортаСообщенийОбмена.ВнешняяСистема)";
		ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "#ТаблицаПланаОбмена", "ПланОбмена." + ПланОбмена);
		
		Если Не ПустаяСтрока(ОбщийТекстЗапроса) Тогда
			ОбщийТекстЗапроса = ОбщийТекстЗапроса + "
			|
			|ОБЪЕДИНИТЬ ВСЕ
			|
			|";
		КонецЕсли;
		
		ОбщийТекстЗапроса = ОбщийТекстЗапроса + ТекстЗапроса;
		
	КонецЦикла;
	
	Если ПустаяСтрока(ОбщийТекстЗапроса) Тогда
		Возврат Результат;
	КонецЕсли;
	
	Запрос = Новый Запрос(ОбщийТекстЗапроса);
	
	УстановитьПривилегированныйРежим(Истина);
	ТаблицаНастройки = Запрос.Выполнить().Выгрузить();
	
	Для Каждого СтрокаНастройки Из ТаблицаНастройки Цикл
		СтрокаРезультат = Результат.Добавить();
		СтрокаРезультат.Корреспондент = СтрокаНастройки.Корреспондент;
		СтрокаРезультат.НастройкиТранспорта = СтрокаНастройки.ПараметрыПодключенияВнешнейСистемы.Получить();
	КонецЦикла;
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Таблица настроек транспорта обмена для всех настроенных обменов данными с внешними системами.
//
// Возвращаемое значение:
//  ТаблицаЗначений - настройки транспорта
//    * Корреспондент - ПланОбменаСсылка - узел обмена, соответствующий корреспонденту.
//    * НастройкиТранспорта - Произвольный - сохраненные настройки транспорта сообщений обмена внешней системы.
//
Функция ВсеНастройкиТранспортаОбменаСВнешнимиСистемами() Экспорт
	
	Результат = Новый ТаблицаЗначений;
	Результат.Колонки.Добавить("Корреспондент");
	Результат.Колонки.Добавить("НастройкиТранспорта");
	
	ОбщийТекстЗапроса = "";
	ПланыОбменаБСП = ОбменДаннымиПовтИсп.ПланыОбменаБСП();
	
	Для Каждого ПланОбмена Из ПланыОбменаБСП Цикл
		
		Если Не ОбменДаннымиПовтИсп.ЭтоПланОбменаXDTO(ПланОбмена) Тогда
			Продолжить;
		КонецЕсли;
		
		ТекстЗапроса = 
		"ВЫБРАТЬ
		|	Т.Ссылка КАК Корреспондент,
		|	НастройкиТранспортаОбменаДанными.ПараметрыПодключенияВнешнейСистемы КАК ПараметрыПодключенияВнешнейСистемы
		|ИЗ
		|	#ТаблицаПланаОбмена КАК Т
		|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.НастройкиТранспортаОбменаДанными КАК НастройкиТранспортаОбменаДанными
		|		ПО (НастройкиТранспортаОбменаДанными.Корреспондент = Т.Ссылка)
		|ГДЕ
		|	НЕ Т.ЭтотУзел
		|	И НастройкиТранспортаОбменаДанными.ВидТранспортаСообщенийОбменаПоУмолчанию = ЗНАЧЕНИЕ(Перечисление.ВидыТранспортаСообщенийОбмена.ВнешняяСистема)";
		ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "#ТаблицаПланаОбмена", "ПланОбмена." + ПланОбмена);
		
		Если Не ПустаяСтрока(ОбщийТекстЗапроса) Тогда
			ОбщийТекстЗапроса = ОбщийТекстЗапроса + "
			|
			|ОБЪЕДИНИТЬ ВСЕ
			|
			|";
		КонецЕсли;
		
		ОбщийТекстЗапроса = ОбщийТекстЗапроса + ТекстЗапроса;
		
	КонецЦикла;
	
	Если ПустаяСтрока(ОбщийТекстЗапроса) Тогда
		Возврат Результат;
	КонецЕсли;
	
	Запрос = Новый Запрос(ОбщийТекстЗапроса);
	
	УстановитьПривилегированныйРежим(Истина);
	ТаблицаНастройки = Запрос.Выполнить().Выгрузить();
	
	Для Каждого СтрокаНастройки Из ТаблицаНастройки Цикл
		СтрокаРезультат = Результат.Добавить();
		СтрокаРезультат.Корреспондент = СтрокаНастройки.Корреспондент;
		СтрокаРезультат.НастройкиТранспорта = СтрокаНастройки.ПараметрыПодключенияВнешнейСистемы.Получить();
	КонецЦикла;
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////