ОчиститьПараметрыСеанса (БСП)

Автор: 1С
ОбщийМодуль.ОбщегоНазначения
БСП

Очистить параметры сеанса. Переводит параметры сеанса в состояние "Не установлено".

// Переводит параметры сеанса в состояние "Не установлено". 
// 
// Параметры:
//  ПараметрыДляОчистки - Строка - имена параметров сеанса для очистки, разделенные ",".
//  Исключения          - Строка - имена параметров сеанса не предназначенные для очистки, разделенные ",".
//
Процедура ОчиститьПараметрыСеанса(ПараметрыДляОчистки = "", Исключения = "") Экспорт
	
	МассивИсключений = СтрРазделить(Исключения, ",");
	МассивПараметровДляОчистки = СтрРазделить(ПараметрыДляОчистки, ",", Ложь);
	
	Если МассивПараметровДляОчистки.Количество() = 0 Тогда
		Для Каждого ПараметрСеанса Из Метаданные.ПараметрыСеанса Цикл
			Если МассивИсключений.Найти(ПараметрСеанса.Имя) = Неопределено Тогда
				МассивПараметровДляОчистки.Добавить(ПараметрСеанса.Имя);
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;
	
	Индекс = МассивПараметровДляОчистки.Найти("ПараметрыКлиентаНаСервере");
	Если Индекс <> Неопределено Тогда
		МассивПараметровДляОчистки.Удалить(Индекс);
	КонецЕсли;
	
	Индекс = МассивПараметровДляОчистки.Найти("УстановленныеРасширения");
	Если Индекс <> Неопределено Тогда
		МассивПараметровДляОчистки.Удалить(Индекс);
	КонецЕсли;
	
	ПараметрыСеанса.Очистить(МассивПараметровДляОчистки);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ОчиститьВсеПараметрыСеансаКромеРазделителей (БСП)

ПриУстановкеПараметровСеанса (БСП)

УстановкаПараметровСеанса (БСП)

ПриДобавленииОбработчиковУстановкиПараметровСеанса (БСП)

ЭтоПараметрСеанса (БСП)

ПриОпределенииПараметровБлокировкиСеансов (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз