ЗарегистрироватьCOMСоединитель (БСП)

Зарегистрировать com соединитель. Выполняет регистрацию компоненты "comcntr.dll" для текущей версии платформы.

// Выполняет регистрацию компоненты "comcntr.dll" для текущей версии платформы.
// В случае успешной регистрации, предлагает пользователю перезапустить клиентский сеанс 
// для того чтобы регистрация вступила в силу.
//
// Вызывается перед клиентским кодом, который использует менеджер COM-соединений (V83.COMConnector)
// и инициируется интерактивными действиями пользователя.
// 
// Параметры:
//  ВыполнитьПерезагрузкуСеанса - Булево - если Истина, то после регистрации COM соединителя
//      будет вызван диалог перезапуска сеанса.
//  Оповещение - ОписаниеОповещения - оповещение о результате регистрации.
//      - Зарегистрировано - Булево - Истина, если COM соединитель зарегистрирован без ошибок.
//      - ДополнительныеПараметры - Произвольный - значение, которое было указано 
//            при создании объекта ОписаниеОповещения.
//
// Пример:
//  ЗарегистрироватьCOMСоединитель();
//
Процедура ЗарегистрироватьCOMСоединитель(Знач ВыполнитьПерезагрузкуСеанса = Истина, 
	Знач Оповещение = Неопределено) Экспорт
	
	Контекст = Новый Структура;
	Контекст.Вставить("ВыполнитьПерезагрузкуСеанса", ВыполнитьПерезагрузкуСеанса);
	Контекст.Вставить("Оповещение", Оповещение);
	
	Если ОбщегоНазначенияСлужебныйКлиент.ЗарегистрироватьCOMСоединительДоступнаРегистрация() Тогда 
	
		ПараметрыЗапускаПрограммы = ФайловаяСистемаКлиент.ПараметрыЗапускаПрограммы();
#Если Не ВебКлиент И Не МобильныйКлиент Тогда
		ПараметрыЗапускаПрограммы.ТекущийКаталог = КаталогПрограммы();
#КонецЕсли
		ПараметрыЗапускаПрограммы.Оповещение = Новый ОписаниеОповещения(
			"ЗарегистрироватьCOMСоединительПриПроверкеРегистрации", ОбщегоНазначенияСлужебныйКлиент, Контекст);
		ПараметрыЗапускаПрограммы.ДождатьсяЗавершения = Истина;
		
		ТекстКоманды = "regsvr32.exe /n /i:user /s comcntr.dll";
		
		ФайловаяСистемаКлиент.ЗапуститьПрограмму(ТекстКоманды, ПараметрыЗапускаПрограммы);
		
	Иначе 
		
		ОбщегоНазначенияСлужебныйКлиент.ЗарегистрироватьCOMСоединительОповеститьОбОшибке(Контекст);
		
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Выполняет регистрацию компоненты "comcntr.dll" для текущей версии платформы.
// В случае успешной регистрации, предлагает пользователю перезапустить клиентский сеанс 
// для того чтобы регистрация вступила в силу.
//
// Вызывается перед клиентским кодом, который использует менеджер COM-соединений (V83.COMConnector)
// и инициируется интерактивными действиями пользователя.
// 
// Параметры:
//  ВыполнитьПерезагрузкуСеанса - Булево - если Истина, то после регистрации COM соединителя
//      будет вызван диалог перезапуска сеанса.
//  Оповещение - ОписаниеОповещения - оповещение о результате регистрации.
//      - Зарегистрировано - Булево - Истина, если COM соединитель зарегистрирован без ошибок.
//      - ДополнительныеПараметры - Произвольный - значение, которое было указано 
//            при создании объекта ОписаниеОповещения.
//
// Пример:
//  ЗарегистрироватьCOMСоединитель();
//
Процедура ЗарегистрироватьCOMСоединитель(Знач ВыполнитьПерезагрузкуСеанса = Истина, 
	Знач Оповещение = Неопределено) Экспорт
	
	Контекст = Новый Структура;
	Контекст.Вставить("ВыполнитьПерезагрузкуСеанса", ВыполнитьПерезагрузкуСеанса);
	Контекст.Вставить("Оповещение", Оповещение);
	
	Если ОбщегоНазначенияСлужебныйКлиент.ЗарегистрироватьCOMСоединительДоступнаРегистрация() Тогда 
	
		ПараметрыЗапускаПрограммы = ФайловаяСистемаКлиент.ПараметрыЗапускаПрограммы();
#Если Не ВебКлиент И Не МобильныйКлиент Тогда
		ПараметрыЗапускаПрограммы.ТекущийКаталог = КаталогПрограммы();
#КонецЕсли
		ПараметрыЗапускаПрограммы.Оповещение = Новый ОписаниеОповещения(
			"ЗарегистрироватьCOMСоединительПриПроверкеРегистрации", ОбщегоНазначенияСлужебныйКлиент, Контекст);
		ПараметрыЗапускаПрограммы.ДождатьсяЗавершения = Истина;
		
		ТекстКоманды = "regsvr32.exe /n /i:user /s comcntr.dll";
		
		ФайловаяСистемаКлиент.ЗапуститьПрограмму(ТекстКоманды, ПараметрыЗапускаПрограммы);
		
	Иначе 
		
		ОбщегоНазначенияСлужебныйКлиент.ЗарегистрироватьCOMСоединительОповеститьОбОшибке(Контекст);
		
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////