СведенияОбОрганизации (БСП)

Автор: 1С
ОбщийМодуль.ОрганизацииСервер
1С БСП

Сведения об организации. Возвращает структуру, содержащую сведения об организации.

// Возвращает структуру, содержащую сведения об организации.
// 
// Параметры:
//  Организация - ОпределяемыйТип.Организация - организация, сведения по которой необходимо получить.
//  Поля - Строка - имена полей, перечисленные через запятую, в формате требований к свойствам структуры.
//                  Список допустимых имен полей см. в описании возвращаемого значения (это максимально возможный список
//                  полей, конечный состав определяется в ОрганизацииПереопределяемый.*).
//                  Если указана пустая строка, то возвращаются значения всех полей.
//  Дата - Дата, Неопределено - дата, на которую требуется получить данные. Если значение не указано,
//                  то возвращается значение на текущую дату.
// Возвращаемое значение:
//   Структура - 
//            см. ОрганизацииСервер.РегистрационныеДанныеОрганизации
//            см. ОрганизацииСервер.ДополнительныеСведенияОрганизации
//            см. ОрганизацииСервер.КонтактнаяИнформацияОрганизации
//            см. ОрганизацииСервер.БанковскийСчетОрганизации
//            см. ОрганизацииСервер.РегистрационныеДанныеОбособленногоПодразделения
//            см. ОрганизацииСервер.КонтактнаяИнформацияОбособленногоПодразделения
//            см. ОрганизацииСервер.РегистрационныеДанныеИностраннойОрганизации
//            см. ОрганизацииСервер.КонтактнаяИнформацияИностраннойОрганизации
//            см. ОрганизацииСервер.РегистрационныеДанныеИндивидуальногоПредпринимателя
//            см. ОрганизацииСервер.РегистрационныеДанныеРуководителяОрганизации
//            см. ОрганизацииСервер.КонтактнаяИнформацияРуководителяОрганизации
//            см. ОрганизацииСервер.РегистрационныеДанныеГлавногоБухгалтера
//            см. ОрганизацииСервер.КонтактнаяИнформацияГлавногоБухгалтера
//            см. ОрганизацииСервер.РегистрационныеДанныеУполномоченногоПредставителя.
//
// Пример:
//       СведенияОбОрганизации = ОрганизацииСервер.СведенияОбОрганизации(Организация);
//
Функция СведенияОбОрганизации(Знач Организация, Знач Поля = "", Знач Дата = Неопределено) Экспорт
	
	ОбщиеСведения = Новый Массив;
	ОбщиеСведения.Добавить(РегистрационныеДанныеОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(ДополнительныеСведенияОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(БанковскийСчетОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(РегистрационныеДанныеОбособленногоПодразделения(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияОбособленногоПодразделения(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(РегистрационныеДанныеОтделенияИностраннойОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияОтделенияИностраннойОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(РегистрационныеДанныеИндивидуальногоПредпринимателя(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияИндивидуальногоПредпринимателя(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(РегистрационныеДанныеРуководителяОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияРуководителяОрганизации(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(РегистрационныеДанныеГлавногоБухгалтера(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияГлавногоБухгалтера(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(РегистрационныеДанныеУполномоченногоПредставителя(Организация, Поля, Дата));
	ОбщиеСведения.Добавить(КонтактнаяИнформацияУполномоченногоПредставителя(Организация, Поля, Дата));
	
	СведенияОбОрганизации = Новый Структура();
	
	Для каждого Сведения Из ОбщиеСведения Цикл
		
		Для каждого Элемент Из Сведения Цикл
			
			Если НЕ СведенияОбОрганизации.Свойство(Элемент.Ключ) Тогда
				СведенияОбОрганизации.Вставить(Элемент.Ключ, Элемент.Значение);
			Иначе
				ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
									НСтр("ru = 'Элемент с таким ключем ""%1"" уже определен.'"), Элемент.Ключ);
			КонецЕсли;
			
		КонецЦикла; 
		
	КонецЦикла;
	
	Возврат СведенияОбОрганизации;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

Сведения об организации

ПриОпределенииДополнительныхСведенийОрганизации (БСП)

ДополнительныеСведенияОрганизации (БСП)

ПриОпределенииРегистрационныхДанныхОрганизации (БСП)

ПриОпределенииКонтактнойИнформацииОрганизации (БСП)

ПриОпределенииБанковскогоСчетаОрганизации (БСП)

РегистрационныеДанныеОрганизации (БСП)

КонтактнаяИнформацияОрганизации (БСП)

БанковскийСчетОрганизации (БСП)

1С Менеджер конфигураций