СоздатьРегламентноеЗаданиеПроверкиПодключения (БСП)

Создать регламентное задание проверки подключения. Создает регламентное задание "ПодключениеТестовыхПериодов" и

// Создает регламентное задание "ПодключениеТестовыхПериодов" и
// записывает информацию в регистр сведений "ИдентификаторыЗапросовНаПодключение".
//
// Параметры:
//  СервисСопровождения           - Справочник.ИдентификаторыСервисовСопровождения - сервис,
//                                для которого необходимо проверить состояние запроса
//                                на подключение;
//  ИдентификаторЗапроса          - УникальныйИдентификатор - идентификатор запроса по которому будет
//                                произведена проверка;
//  ИдентификаторТестовогоПериода - Строка - уникальный идентификатор тестового периода;
//  НаименованиеТестовогоПериода  - Строка - наименование подключаемого тестового периода.
//
Процедура СоздатьРегламентноеЗаданиеПроверкиПодключения(
		СервисСопровождения,
		ИдентификаторЗапроса,
		ИдентификаторТестовогоПериода,
		НаименованиеТестовогоПериода) Экспорт
	
	Если Не РазрешеноПодключениеТестовыхПериодов() Тогда
		ВызватьИсключение НСтр("ru = 'Подключение тестового периода недоступно.'");
	КонецЕсли;
	
	УстановитьПривилегированныйРежим(Истина);
	
	ПараметрыПроцедуры = Новый Массив;
	ПараметрыПроцедуры.Добавить(СервисСопровождения);
	ПараметрыПроцедуры.Добавить(ИдентификаторЗапроса);
	ПараметрыПроцедуры.Добавить(ИдентификаторТестовогоПериода);
	
	Расписание = Новый РасписаниеРегламентногоЗадания;
	Расписание.ПериодПовтораВТечениеДня = 3600;
	Расписание.ПериодПовтораДней        = 1;
	
	НаименованиеЗадания = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
		НСтр("ru = 'Подключение тестового периода: %1'"),
		НаименованиеТестовогоПериода);
	
	ПараметрыЗадания = Новый Структура;
	ПараметрыЗадания.Вставить("Использование", Истина);
	ПараметрыЗадания.Вставить("Метаданные",    Метаданные.РегламентныеЗадания.ПодключениеТестовыхПериодов);
	ПараметрыЗадания.Вставить("Параметры",     ПараметрыПроцедуры);
	ПараметрыЗадания.Вставить("Ключ",          ИдентификаторЗапроса);
	ПараметрыЗадания.Вставить("Расписание",    Расписание);
	ПараметрыЗадания.Вставить("Наименование",  НаименованиеЗадания);
	
	НачатьТранзакцию();
	
	Попытка
		
		РегламентныеЗаданияСервер.ДобавитьЗадание(ПараметрыЗадания);
		
		ТекстЖурналРегистрации = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Создано регламентное задание для проверки запроса на подключение: %1'"),
			ИдентификаторЗапроса);
		
		ЗаписатьИнформациюВЖурналРегистрации(
			ТекстЖурналРегистрации,
			Ложь);
		
		ИдентификаторыЗапросовНабор = РегистрыСведений.ИдентификаторыЗапросовНаПодключение.СоздатьНаборЗаписей();
		ИдентификаторыЗапросовНабор.Отбор.ИдентификаторСервисаСопровождения.Установить(СервисСопровождения);
		ИдентификаторыЗапросовНабор.Отбор.Идентификатор.Установить(ИдентификаторЗапроса);
		
		Запись = ИдентификаторыЗапросовНабор.Добавить();
		Запись.ИдентификаторСервисаСопровождения = СервисСопровождения;
		Запись.Идентификатор                     = ИдентификаторЗапроса;
		Запись.Состояние                         = ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.Подключение");
		Запись.Пользователь                      = Пользователи.ТекущийПользователь();
		Запись.НаименованиеТестовогоПериода      = НаименованиеТестовогоПериода;
		Запись.ИдентификаторТестовогоПериода     = ИдентификаторТестовогоПериода;
		
		ИдентификаторыЗапросовНабор.Записать();
		
		ЗафиксироватьТранзакцию();
		
	Исключение
		
		ОтменитьТранзакцию();
		
		ТекстИсключения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Ошибка при создании регламентного задания проверки подключения тестовых периодов:
			|%1'"),
			ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
		
		ВызватьИсключение ТекстИсключения;
		
	КонецПопытки;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Создает регламентное задание "ПодключениеТестовыхПериодов" и
// записывает информацию в регистр сведений "ИдентификаторыЗапросовНаПодключение".
//
// Параметры:
//  СервисСопровождения           - Справочник.ИдентификаторыСервисовСопровождения - сервис,
//                                для которого необходимо проверить состояние запроса
//                                на подключение;
//  ИдентификаторЗапроса          - УникальныйИдентификатор - идентификатор запроса по которому будет
//                                произведена проверка;
//  ИдентификаторТестовогоПериода - Строка - уникальный идентификатор тестового периода;
//  НаименованиеТестовогоПериода  - Строка - наименование подключаемого тестового периода.
//
Процедура СоздатьРегламентноеЗаданиеПроверкиПодключения(
		СервисСопровождения,
		ИдентификаторЗапроса,
		ИдентификаторТестовогоПериода,
		НаименованиеТестовогоПериода) Экспорт
	
	Если Не РазрешеноПодключениеТестовыхПериодов() Тогда
		ВызватьИсключение НСтр("ru = 'Подключение тестового периода недоступно.'");
	КонецЕсли;
	
	УстановитьПривилегированныйРежим(Истина);
	
	ПараметрыПроцедуры = Новый Массив;
	ПараметрыПроцедуры.Добавить(СервисСопровождения);
	ПараметрыПроцедуры.Добавить(ИдентификаторЗапроса);
	ПараметрыПроцедуры.Добавить(ИдентификаторТестовогоПериода);
	
	Расписание = Новый РасписаниеРегламентногоЗадания;
	Расписание.ПериодПовтораВТечениеДня = 3600;
	Расписание.ПериодПовтораДней        = 1;
	
	НаименованиеЗадания = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
		НСтр("ru = 'Подключение тестового периода: %1'"),
		НаименованиеТестовогоПериода);
	
	ПараметрыЗадания = Новый Структура;
	ПараметрыЗадания.Вставить("Использование", Истина);
	ПараметрыЗадания.Вставить("Метаданные",    Метаданные.РегламентныеЗадания.ПодключениеТестовыхПериодов);
	ПараметрыЗадания.Вставить("Параметры",     ПараметрыПроцедуры);
	ПараметрыЗадания.Вставить("Ключ",          ИдентификаторЗапроса);
	ПараметрыЗадания.Вставить("Расписание",    Расписание);
	ПараметрыЗадания.Вставить("Наименование",  НаименованиеЗадания);
	
	НачатьТранзакцию();
	
	Попытка
		
		РегламентныеЗаданияСервер.ДобавитьЗадание(ПараметрыЗадания);
		
		ТекстЖурналРегистрации = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Создано регламентное задание для проверки запроса на подключение: %1'"),
			ИдентификаторЗапроса);
		
		ЗаписатьИнформациюВЖурналРегистрации(
			ТекстЖурналРегистрации,
			Ложь);
		
		ИдентификаторыЗапросовНабор = РегистрыСведений.ИдентификаторыЗапросовНаПодключение.СоздатьНаборЗаписей();
		ИдентификаторыЗапросовНабор.Отбор.ИдентификаторСервисаСопровождения.Установить(СервисСопровождения);
		ИдентификаторыЗапросовНабор.Отбор.Идентификатор.Установить(ИдентификаторЗапроса);
		
		Запись = ИдентификаторыЗапросовНабор.Добавить();
		Запись.ИдентификаторСервисаСопровождения = СервисСопровождения;
		Запись.Идентификатор                     = ИдентификаторЗапроса;
		Запись.Состояние                         = ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.Подключение");
		Запись.Пользователь                      = Пользователи.ТекущийПользователь();
		Запись.НаименованиеТестовогоПериода      = НаименованиеТестовогоПериода;
		Запись.ИдентификаторТестовогоПериода     = ИдентификаторТестовогоПериода;
		
		ИдентификаторыЗапросовНабор.Записать();
		
		ЗафиксироватьТранзакцию();
		
	Исключение
		
		ОтменитьТранзакцию();
		
		ТекстИсключения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Ошибка при создании регламентного задания проверки подключения тестовых периодов:
			|%1'"),
			ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
		
		ВызватьИсключение ТекстИсключения;
		
	КонецПопытки;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////