ПодключитьТестовыйПериод (БСП)

Автор: 1С

ОбщийМодуль.ПодключениеСервисовСопровожденияКлиент

1С БСП

Подключить тестовый период. Открывает форму подключения тестового периода, предварительно

// Открывает форму подключения тестового периода, предварительно
// проверяя возможность подключения. Подключение может быть не доступно если:
//   - у пользователя нет прав для подключения тестового периода,
//     считается, что все сервисы не доступны;
//   - существуют необработанные запросы на подключение,
//     невозможно определить доступные тарифы;
//   - конфигурация работает в модели сервиса
//   - доступные тестовые периоды отсутствуют.
// Функцию следует использовать, если однозначно определено, что целевой сервис не подключен.
//
// Параметры:
//  Идентификатор         - Строка - идентификатор сервиса в системе Портал 1С:ИТС;
//  Форма                 - ФормаКлиентскогоПриложения - форма из которой производится подключение;
//  ОповещениеПриЗакрытии - ОписаниеОповещения - описание обработчика, который необходимо выполнить
//                          по завершению подключения. В качестве результата будет передан статус подключения:
//                          СостояниеПодключения - Перечисление.СостоянияЗаявкиПодключения - 
//                          описывает состояние подключения тестового периода. Для определения статуса
//                          необходимо использовать функции программного интерфейса:
//                            - Перечисление.СостоянияПодключенияСервисов.Подключен - подключение
//                              тестового периода выполнено без ошибок;
//                            - Перечисление.СостоянияПодключенияСервисов.ОшибкаПодключения - тестовый
//                              период не подключен;
//                            - Перечисление.СостоянияПодключенияСервисов.НеПодключен - пользователь
//                              не дождался обработки заявки на подключение;
//                            - Перечисление.СостоянияПодключенияСервисов.ПодключениеНедоступно - подключение
//                              не доступно, форма не была открыта;
//                            - Перечисление.СостоянияПодключенияСервисов.Подключение - выполняется подключение
//                              тестового периода.
//
Процедура ПодключитьТестовыйПериод(
		Идентификатор,
		Форма,
		ОповещениеПриЗакрытии = Неопределено) Экспорт
	
	Состояние(, , НСтр("ru = 'Получение информации о доступных тестовых периодах'"));
	ОписательПодключения = ПодключениеСервисовСопровожденияВызовСервера.ТестовыеПериодыСервисаСопровождения(Идентификатор);
	Состояние();
	
	Если ОписательПодключения.Ошибка Тогда
		ПараметрыФормы = ПодключениеСервисовСопровожденияКлиентСервер.НовыйПараметрыФормыОтобразитьРезультат(
			"",
			"",
			Идентификатор,
			"",
			ОписательПодключения.ИнформацияОбОшибке,
			ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.ОшибкаПодключения"));
	ИначеЕсли Не ОписательПодключения.ПодключениеДоступно Тогда
		ВыполнитьОбработкуОповещения(
			ОповещениеПриЗакрытии,
			ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.ПодключениеНедоступно"));
		Возврат;
	ИначеЕсли ОписательПодключения.ПодключениеСервиса Тогда
		ДанныеОтображения = ОписательПодключения.ДанныеОтображения;
		ПараметрыФормы    = ПодключениеСервисовСопровожденияКлиентСервер.НовыйПараметрыФормыОтобразитьРезультат(
			ДанныеОтображения.ИдентификаторТестовогоПериода,
			ДанныеОтображения.НаименованиеПодключаемого,
			Идентификатор,
			ДанныеОтображения.ИдентификаторЗапроса,
			"",
			ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.Подключение"),
			ДанныеОтображения.РежимРегламентногоЗадания);
	Иначе
		ПараметрыФормы = Новый Структура;
		ПараметрыФормы.Вставить("Идентификатор",        Идентификатор);
		ПараметрыФормы.Вставить("ОписательПодключения", ОписательПодключения);
	КонецЕсли;
	
	УникальныйИдентификатор = Неопределено;
	Если ТипЗнч(Форма) = Тип("ФормаКлиентскогоПриложения") Тогда
		УникальныйИдентификатор = Форма.УникальныйИдентификатор;
	КонецЕсли;
	
	ОткрытьФорму(
		"Обработка.ПодключениеСервисовСопровождения.Форма.ПодключениеТестовогоПериода",
		ПараметрыФормы,
		Форма,
		УникальныйИдентификатор,
		,
		,
		ОповещениеПриЗакрытии,
		РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Открывает форму подключения тестового периода, предварительно
// проверяя возможность подключения. Подключение может быть не доступно если:
//   - у пользователя нет прав для подключения тестового периода,
//     считается, что все сервисы не доступны;
//   - существуют необработанные запросы на подключение,
//     невозможно определить доступные тарифы;
//   - конфигурация работает в модели сервиса
//   - доступные тестовые периоды отсутствуют.
// Функцию следует использовать, если однозначно определено, что целевой сервис не подключен.
//
// Параметры:
//  Идентификатор         - Строка - идентификатор сервиса в системе Портал 1С:ИТС;
//  Форма                 - ФормаКлиентскогоПриложения - форма из которой производится подключение;
//  ОповещениеПриЗакрытии - ОписаниеОповещения - описание обработчика, который необходимо выполнить
//                          по завершению подключения. В качестве результата будет передан статус подключения:
//                          СостояниеПодключения - Перечисление.СостоянияЗаявкиПодключения - 
//                          описывает состояние подключения тестового периода. Для определения статуса
//                          необходимо использовать функции программного интерфейса:
//                            - Перечисление.СостоянияПодключенияСервисов.Подключен - подключение
//                              тестового периода выполнено без ошибок;
//                            - Перечисление.СостоянияПодключенияСервисов.ОшибкаПодключения - тестовый
//                              период не подключен;
//                            - Перечисление.СостоянияПодключенияСервисов.НеПодключен - пользователь
//                              не дождался обработки заявки на подключение;
//                            - Перечисление.СостоянияПодключенияСервисов.ПодключениеНедоступно - подключение
//                              не доступно, форма не была открыта;
//                            - Перечисление.СостоянияПодключенияСервисов.Подключение - выполняется подключение
//                              тестового периода.
//
Процедура ПодключитьТестовыйПериод(
		Идентификатор,
		Форма,
		ОповещениеПриЗакрытии = Неопределено) Экспорт
	
	Состояние(, , НСтр("ru = 'Получение информации о доступных тестовых периодах'"));
	ОписательПодключения = ПодключениеСервисовСопровожденияВызовСервера.ТестовыеПериодыСервисаСопровождения(Идентификатор);
	Состояние();
	
	Если ОписательПодключения.Ошибка Тогда
		ПараметрыФормы = ПодключениеСервисовСопровожденияКлиентСервер.НовыйПараметрыФормыОтобразитьРезультат(
			"",
			"",
			Идентификатор,
			"",
			ОписательПодключения.ИнформацияОбОшибке,
			ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.ОшибкаПодключения"));
	ИначеЕсли Не ОписательПодключения.ПодключениеДоступно Тогда
		ВыполнитьОбработкуОповещения(
			ОповещениеПриЗакрытии,
			ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.ПодключениеНедоступно"));
		Возврат;
	ИначеЕсли ОписательПодключения.ПодключениеСервиса Тогда
		ДанныеОтображения = ОписательПодключения.ДанныеОтображения;
		ПараметрыФормы    = ПодключениеСервисовСопровожденияКлиентСервер.НовыйПараметрыФормыОтобразитьРезультат(
			ДанныеОтображения.ИдентификаторТестовогоПериода,
			ДанныеОтображения.НаименованиеПодключаемого,
			Идентификатор,
			ДанныеОтображения.ИдентификаторЗапроса,
			"",
			ПредопределенноеЗначение("Перечисление.СостоянияПодключенияСервисов.Подключение"),
			ДанныеОтображения.РежимРегламентногоЗадания);
	Иначе
		ПараметрыФормы = Новый Структура;
		ПараметрыФормы.Вставить("Идентификатор",        Идентификатор);
		ПараметрыФормы.Вставить("ОписательПодключения", ОписательПодключения);
	КонецЕсли;
	
	УникальныйИдентификатор = Неопределено;
	Если ТипЗнч(Форма) = Тип("ФормаКлиентскогоПриложения") Тогда
		УникальныйИдентификатор = Форма.УникальныйИдентификатор;
	КонецЕсли;
	
	ОткрытьФорму(
		"Обработка.ПодключениеСервисовСопровождения.Форма.ПодключениеТестовогоПериода",
		ПараметрыФормы,
		Форма,
		УникальныйИдентификатор,
		,
		,
		ОповещениеПриЗакрытии,
		РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПодключитьТестовыйПериод (БСП)

Рекомендации

Похожие публикации