ХранимыеСвойстваПользователяИБ (БСП)

Хранимые свойства пользователя. Вызывается при обработке свойства СвойстваПользователяИБ пользователя в справочнике.

// Вызывается при обработке свойства СвойстваПользователяИБ пользователя в справочнике.
// 
// Параметры:
//  ОписаниеПользователя   - СправочникОбъект.Пользователи, СправочникОбъект.ВнешниеПользователи,
//                           ДанныеФормыСтруктура, содержит свойство СвойстваПользователяИБ.
//                         - СправочникСсылка.Пользователи, СправочникСсылка.ВнешниеПользователи -
//                           из объекта которой нужно прочитать свойство СвойстваПользователяИБ.
//  ВходВПрограммуРазрешен - Булево - если указано Ложь, а сохранено Истина, тогда свойства
//                           аутентификации безусловно Ложь, т.к. были сняты в конфигураторе.
//
// Возвращаемое значение:
//  Структура.
//
Функция ХранимыеСвойстваПользователяИБ(ОписаниеПользователя, ВходВПрограммуРазрешен = Ложь) Экспорт
	
	Свойства = Новый Структура;
	Свойства.Вставить("ВходВПрограммуРазрешен",    Ложь);
	Свойства.Вставить("АутентификацияСтандартная", Ложь);
	Свойства.Вставить("АутентификацияOpenID",      Ложь);
	Свойства.Вставить("АутентификацияОС",          Ложь);
	
	Если ТипЗнч(ОписаниеПользователя) = Тип("СправочникСсылка.Пользователи")
	 Или ТипЗнч(ОписаниеПользователя) = Тип("СправочникСсылка.ВнешниеПользователи") Тогда
		
		ХранилищеСвойств = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(
			ОписаниеПользователя, "СвойстваПользователяИБ");
	Иначе
		ХранилищеСвойств = ОписаниеПользователя.СвойстваПользователяИБ;
	КонецЕсли;
	
	Если ТипЗнч(ХранилищеСвойств) <> Тип("ХранилищеЗначения") Тогда
		Возврат Свойства;
	КонецЕсли;
	
	СохраненныеСвойства = ХранилищеСвойств.Получить();
	
	Если ТипЗнч(СохраненныеСвойства) <> Тип("Структура") Тогда
		Возврат Свойства;
	КонецЕсли;
	
	Для каждого КлючИЗначение Из Свойства Цикл
		Если СохраненныеСвойства.Свойство(КлючИЗначение.Ключ)
		   И ТипЗнч(СохраненныеСвойства[КлючИЗначение.Ключ]) = Тип("Булево") Тогда
			
			Свойства[КлючИЗначение.Ключ] = СохраненныеСвойства[КлючИЗначение.Ключ];
		КонецЕсли;
	КонецЦикла;
	
	Если Свойства.ВходВПрограммуРазрешен И Не ВходВПрограммуРазрешен Тогда
		Свойства.Вставить("АутентификацияСтандартная", Ложь);
		Свойства.Вставить("АутентификацияOpenID",      Ложь);
		Свойства.Вставить("АутентификацияОС",          Ложь);
	КонецЕсли;
	
	Возврат Свойства;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Вызывается при обработке свойства СвойстваПользователяИБ пользователя в справочнике.
// 
// Параметры:
//  ОписаниеПользователя   - СправочникОбъект.Пользователи, СправочникОбъект.ВнешниеПользователи,
//                           ДанныеФормыСтруктура, содержит свойство СвойстваПользователяИБ.
//                         - СправочникСсылка.Пользователи, СправочникСсылка.ВнешниеПользователи -
//                           из объекта которой нужно прочитать свойство СвойстваПользователяИБ.
//  ВходВПрограммуРазрешен - Булево - если указано Ложь, а сохранено Истина, тогда свойства
//                           аутентификации безусловно Ложь, т.к. были сняты в конфигураторе.
//
// Возвращаемое значение:
//  Структура.
//
Функция ХранимыеСвойстваПользователяИБ(ОписаниеПользователя, ВходВПрограммуРазрешен = Ложь) Экспорт
	
	Свойства = Новый Структура;
	Свойства.Вставить("ВходВПрограммуРазрешен",    Ложь);
	Свойства.Вставить("АутентификацияСтандартная", Ложь);
	Свойства.Вставить("АутентификацияOpenID",      Ложь);
	Свойства.Вставить("АутентификацияОС",          Ложь);
	
	Если ТипЗнч(ОписаниеПользователя) = Тип("СправочникСсылка.Пользователи")
	 Или ТипЗнч(ОписаниеПользователя) = Тип("СправочникСсылка.ВнешниеПользователи") Тогда
		
		ХранилищеСвойств = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(
			ОписаниеПользователя, "СвойстваПользователяИБ");
	Иначе
		ХранилищеСвойств = ОписаниеПользователя.СвойстваПользователяИБ;
	КонецЕсли;
	
	Если ТипЗнч(ХранилищеСвойств) <> Тип("ХранилищеЗначения") Тогда
		Возврат Свойства;
	КонецЕсли;
	
	СохраненныеСвойства = ХранилищеСвойств.Получить();
	
	Если ТипЗнч(СохраненныеСвойства) <> Тип("Структура") Тогда
		Возврат Свойства;
	КонецЕсли;
	
	Для каждого КлючИЗначение Из Свойства Цикл
		Если СохраненныеСвойства.Свойство(КлючИЗначение.Ключ)
		   И ТипЗнч(СохраненныеСвойства[КлючИЗначение.Ключ]) = Тип("Булево") Тогда
			
			Свойства[КлючИЗначение.Ключ] = СохраненныеСвойства[КлючИЗначение.Ключ];
		КонецЕсли;
	КонецЦикла;
	
	Если Свойства.ВходВПрограммуРазрешен И Не ВходВПрограммуРазрешен Тогда
		Свойства.Вставить("АутентификацияСтандартная", Ложь);
		Свойства.Вставить("АутентификацияOpenID",      Ложь);
		Свойства.Вставить("АутентификацияОС",          Ложь);
	КонецЕсли;
	
	Возврат Свойства;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////