СоздатьПриложение (БСП)

Создать приложение. Метод создает новое приложение с указанной прикладной конфигурацией.

// Метод создает новое приложение с указанной прикладной конфигурацией.
//
// Параметры:
//  ПараметрыСоздания - Структура - см. метод ПрограммныйИнтерфейсСервиса.НовыйПараметрыСозданияПриложения
//  ВызыватьИсключениеПриОшибке - Булево - признак вызова исключения при ошибке получения данных.
//  КодСостояния - Число - код состояния ответа HTTP-сервиса.
//  КодОтвета - Число - заполняется из ответа значением свойства "general.response".
//  Сообщение - Строка - заполняется из ответа значением свойства "general.message". 
// 
// Возвращаемое значение:
//  Структура - результат создания приложения:
//  * Код - Число - код созданного приложения (номер области)
//  * СостояниеПриложения - ПеречислениеСсылка.СостоянияПриложений - состояние приложения после создания.
//  * АдресПриложения - Строка - адрес созданного приложения.
//
Функция СоздатьПриложение(ПараметрыСоздания,
    ВызыватьИсключениеПриОшибке = Истина, КодСостояния = 0, КодОтвета = 0, Сообщение = "") Экспорт

	Метод = "tenant/create";
    ДанныеЗапроса = ШаблонЗапроса(Метод);
    ДанныеЗапроса.Вставить("application", ПараметрыСоздания.КодКонфигурации);
    ДанныеЗапроса.Вставить("name", ПараметрыСоздания.Наименование);
    ДанныеЗапроса.Вставить("timezone", ПараметрыСоздания.ЧасовойПояс);
    Результат = ОтправитьДанныеВМенеджерСервиса(ДанныеЗапроса);
    ДанныеОтвета = РезультатВыполнения(Результат, ВызыватьИсключениеПриОшибке, КодСостояния, КодОтвета, Сообщение);
	
	Переименования = Новый Соответствие;
	Переименования.Вставить("id", ОписаниеКолонки("Код", ОбщегоНазначения.ОписаниеТипаЧисло(7, 0, ДопустимыйЗнак.Неотрицательный)));
	Переименования.Вставить("status", ОписаниеКолонки("СостояниеПриложения", Новый ОписаниеТипов("ПеречислениеСсылка.СостоянияПриложений")));
	Переименования.Вставить("url", ОписаниеКолонки("АдресПриложения", ОбщегоНазначения.ОписаниеТипаСтрока(500)));
	
	Если КодОтвета = 10200 Или КодОтвета = 10202 Тогда
		Результат = ОбщегоНазначенияКлиентСервер.СкопироватьСтруктуру(ДанныеОтвета.tenant);
	    Поле = "status";
	    Результат[Поле] = Перечисления.СостоянияПриложений.ЗначениеПоИмени(Результат[Поле]);
		Результат = ПереименоватьСвойства(Результат, Переименования);
	Иначе
		Результат = Новый Структура;
		Результат.Вставить("Код", 0);
		Результат.Вставить("СостояниеПриложения", Перечисления.СостоянияПриложений.ПустаяСсылка());
		Результат.Вставить("АдресПриложения", "");
	КонецЕсли; 
	
	Возврат Результат;
    
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Метод создает новое приложение с указанной прикладной конфигурацией.
//
// Параметры:
//  ПараметрыСоздания - Структура - см. метод ПрограммныйИнтерфейсСервиса.НовыйПараметрыСозданияПриложения
//  ВызыватьИсключениеПриОшибке - Булево - признак вызова исключения при ошибке получения данных.
//  КодСостояния - Число - код состояния ответа HTTP-сервиса.
//  КодОтвета - Число - заполняется из ответа значением свойства "general.response".
//  Сообщение - Строка - заполняется из ответа значением свойства "general.message". 
// 
// Возвращаемое значение:
//  Структура - результат создания приложения:
//  * Код - Число - код созданного приложения (номер области)
//  * СостояниеПриложения - ПеречислениеСсылка.СостоянияПриложений - состояние приложения после создания.
//  * АдресПриложения - Строка - адрес созданного приложения.
//
Функция СоздатьПриложение(ПараметрыСоздания,
    ВызыватьИсключениеПриОшибке = Истина, КодСостояния = 0, КодОтвета = 0, Сообщение = "") Экспорт

	Метод = "tenant/create";
    ДанныеЗапроса = ШаблонЗапроса(Метод);
    ДанныеЗапроса.Вставить("application", ПараметрыСоздания.КодКонфигурации);
    ДанныеЗапроса.Вставить("name", ПараметрыСоздания.Наименование);
    ДанныеЗапроса.Вставить("timezone", ПараметрыСоздания.ЧасовойПояс);
    Результат = ОтправитьДанныеВМенеджерСервиса(ДанныеЗапроса);
    ДанныеОтвета = РезультатВыполнения(Результат, ВызыватьИсключениеПриОшибке, КодСостояния, КодОтвета, Сообщение);
	
	Переименования = Новый Соответствие;
	Переименования.Вставить("id", ОписаниеКолонки("Код", ОбщегоНазначения.ОписаниеТипаЧисло(7, 0, ДопустимыйЗнак.Неотрицательный)));
	Переименования.Вставить("status", ОписаниеКолонки("СостояниеПриложения", Новый ОписаниеТипов("ПеречислениеСсылка.СостоянияПриложений")));
	Переименования.Вставить("url", ОписаниеКолонки("АдресПриложения", ОбщегоНазначения.ОписаниеТипаСтрока(500)));
	
	Если КодОтвета = 10200 Или КодОтвета = 10202 Тогда
		Результат = ОбщегоНазначенияКлиентСервер.СкопироватьСтруктуру(ДанныеОтвета.tenant);
	    Поле = "status";
	    Результат[Поле] = Перечисления.СостоянияПриложений.ЗначениеПоИмени(Результат[Поле]);
		Результат = ПереименоватьСвойства(Результат, Переименования);
	Иначе
		Результат = Новый Структура;
		Результат.Вставить("Код", 0);
		Результат.Вставить("СостояниеПриложения", Перечисления.СостоянияПриложений.ПустаяСсылка());
		Результат.Вставить("АдресПриложения", "");
	КонецЕсли; 
	
	Возврат Результат;
    
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////