УстановитьЗапретОбновленияДоступа (БСП)

Установить запрет обновления доступа. Включает или отключает запрет обновления доступа при запуске

// Включает или отключает запрет обновления доступа при запуске
// с помощью регламентного задания или при программном запуске.
//
// При вызове процедуры ОбновлениеДоступаНаУровнеЗаписей
// с признаком ОбновитьВсе запрет игнорируется.
// 
// При вызове процедуры ЗапуститьОбновлениеДоступаНаУровнеЗаписей
// с признаком ЭтоЗапускВручную запрет снимается автоматически.
//
Процедура УстановитьЗапретОбновленияДоступа(Использование, ОтменитьОбновление = Ложь) Экспорт
	
	БлокировкаДанных = Новый БлокировкаДанных;
	БлокировкаДанных.Добавить("Константа.ПоследнееОбновлениеДоступа");
	
	НачатьТранзакцию();
	Попытка
		БлокировкаДанных.Заблокировать();
		ЗначениеКонстанты = Константы.ПоследнееОбновлениеДоступа.Получить();
		ПоследнееОбновлениеДоступа = ПоследнееОбновлениеДоступа(ЗначениеКонстанты);
		
		Записать = Ложь;
		Если ПоследнееОбновлениеДоступа.ОбновлениеДоступаЗапрещено <> Использование Тогда
			ПоследнееОбновлениеДоступа.ОбновлениеДоступаЗапрещено = Использование;
			Записать = Истина;
		КонецЕсли;
		
		Если ОтменитьОбновление
		   И ( Не ПоследнееОбновлениеДоступа.ОбновлениеОтменено
		      Или ПоследнееОбновлениеДоступа.ТекстОшибкиЗавершения <> "") Тогда
			
			ПоследнееОбновлениеДоступа.ОбновлениеОтменено = Истина;
			ПоследнееОбновлениеДоступа.ТекстОшибкиЗавершения = "";
			Записать = Истина;
		КонецЕсли;
		
		Если Записать Тогда
			Константы.ПоследнееОбновлениеДоступа.Установить(
				Новый ХранилищеЗначения(ПоследнееОбновлениеДоступа));
		КонецЕсли;
		ЗафиксироватьТранзакцию();
	Исключение
		ОтменитьТранзакцию();
		ВызватьИсключение;
	КонецПопытки;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Включает или отключает запрет обновления доступа при запуске
// с помощью регламентного задания или при программном запуске.
//
// При вызове процедуры ОбновлениеДоступаНаУровнеЗаписей
// с признаком ОбновитьВсе запрет игнорируется.
// 
// При вызове процедуры ЗапуститьОбновлениеДоступаНаУровнеЗаписей
// с признаком ЭтоЗапускВручную запрет снимается автоматически.
//
Процедура УстановитьЗапретОбновленияДоступа(Использование, ОтменитьОбновление = Ложь) Экспорт
	
	БлокировкаДанных = Новый БлокировкаДанных;
	БлокировкаДанных.Добавить("Константа.ПоследнееОбновлениеДоступа");
	
	НачатьТранзакцию();
	Попытка
		БлокировкаДанных.Заблокировать();
		ЗначениеКонстанты = Константы.ПоследнееОбновлениеДоступа.Получить();
		ПоследнееОбновлениеДоступа = ПоследнееОбновлениеДоступа(ЗначениеКонстанты);
		
		Записать = Ложь;
		Если ПоследнееОбновлениеДоступа.ОбновлениеДоступаЗапрещено <> Использование Тогда
			ПоследнееОбновлениеДоступа.ОбновлениеДоступаЗапрещено = Использование;
			Записать = Истина;
		КонецЕсли;
		
		Если ОтменитьОбновление
		   И ( Не ПоследнееОбновлениеДоступа.ОбновлениеОтменено
		      Или ПоследнееОбновлениеДоступа.ТекстОшибкиЗавершения <> "") Тогда
			
			ПоследнееОбновлениеДоступа.ОбновлениеОтменено = Истина;
			ПоследнееОбновлениеДоступа.ТекстОшибкиЗавершения = "";
			Записать = Истина;
		КонецЕсли;
		
		Если Записать Тогда
			Константы.ПоследнееОбновлениеДоступа.Установить(
				Новый ХранилищеЗначения(ПоследнееОбновлениеДоступа));
		КонецЕсли;
		ЗафиксироватьТранзакцию();
	Исключение
		ОтменитьТранзакцию();
		ВызватьИсключение;
	КонецПопытки;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////