СтраныУчастникиЕАЭС (БСП)

Автор: 1С
ОбщийМодуль.УправлениеКонтактнойИнформацией
БСП

Страны участники. Возвращает список стран Евразийского экономического союза (ЕАЭС).

// Возвращает список стран Евразийского экономического союза (ЕАЭС).
//
// Возвращаемое значение:
//  - ТаблицаЗначений - Список стран Евразийского экономического союза (ЕАЭС).
//     * Ссылка             - СправочникСсылка.СтраныМира - Ссылка на элемент справочника страны.
//     * Наименование       - Строка - Наименование страны.
//     * Код                - Строка - Код страны.
//     * НаименованиеПолное - Строка - Полное наименование страны.
//     * КодАльфа2          - Строка - Двузначный буквенный код страны альфа-2.
//     * КодАльфа3          - Строка - Трехзначный буквенный код страны альфа-3.
Функция СтраныУчастникиЕАЭС() Экспорт
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	СтраныМира.Ссылка КАК Ссылка,
		|	СтраныМира.Наименование КАК Наименование,
		|	СтраныМира.Код КАК Код,
		|	СтраныМира.НаименованиеПолное КАК НаименованиеПолное,
		|	СтраныМира.КодАльфа2 КАК КодАльфа2,
		|	СтраныМира.КодАльфа3 КАК КодАльфа3
		|ИЗ
		|	Справочник.СтраныМира КАК СтраныМира
		|ГДЕ
		|	СтраныМира.УчастникЕАЭС = ИСТИНА";
	
	СтраныЕАЭС = Запрос.Выполнить().Выгрузить();
	
	Если Метаданные.ОбщиеМодули.Найти("РаботаСАдресами") = Неопределено Тогда
		Возврат СтраныЕАЭС;
	КонецЕсли;
	
	МодульРаботаСАдресами = ОбщегоНазначения.ОбщийМодуль("РаботаСАдресами");
	ДанныеКлассификатора = МодульРаботаСАдресами.ТаблицаКлассификатора();
	
	Для каждого Страна Из ДанныеКлассификатора Цикл
		Если Страна.УчастникЕАЭС Тогда
			Отбор = Новый Структура();
			Отбор.Вставить("Наименование", Страна.Наименование);
			Отбор.Вставить("Код", Страна.Код);
			Отбор.Вставить("НаименованиеПолное", Страна.НаименованиеПолное);
			Отбор.Вставить("КодАльфа2", Страна.КодАльфа2);
			Отбор.Вставить("КодАльфа3", Страна.КодАльфа3);
			НайденныеСтроки = СтраныЕАЭС.НайтиСтроки(Отбор);
			Если НайденныеСтроки.Количество() = 0 Тогда
				НоваяСтрока = СтраныЕАЭС.Добавить();
				ЗаполнитьЗначенияСвойств(НоваяСтрока, Отбор);
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;
	
	Возврат СтраныЕАЭС;

КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ЭтоСтранаУчастникЕАЭС (БСП)

ОсновнаяСтрана (БСП)

ЭтоОсновнаяСтрана (БСП)

ДанныеСтраныМира (БСП)

ДанныеКлассификатораСтранМираПоНаименованию (БСП)

СтранаАдресаКонтактнойИнформации (БСП)

ПолучитьУчастниковПоТаблице (БСП)

СформироватьСписокУчастников (БСП)

ЗаполнитьДанныеВыбораАвтоподбораПоСтранам (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз