ПараметрыФормыКонтактнойИнформации (БСП)

Параметры формы контактной информации. Конструктор для структуры параметров открытия формы контактной информации.

// Конструктор для структуры параметров открытия формы контактной информации.
//
// Параметры:
//  ВидКонтактнойИнформации  - СправочникСсылка.ВидыКонтактнойИнформации - вид редактируемой контактной информации.
//                             Структура - см. УправлениеКонтактнойИнформацией.ПараметрыВидаКонтактнойИнформации
//  Значение                 - Строка - сериализованное значение полей контактной информации в формате JSON или XML.
//  Представление            - Строка - представление контактной информации.
//  Комментарий              - Строка - комментарий контактной информации.
//  ТипКонтактнойИнформации  - ПеречислениеСсылка.ТипыКонтактнойИнформации - тип контактной информации.
//                             Если указан, то в возвращаемую структуру добавляются поля соответствующие типу.
// 
// Возвращаемое значение:
//  Структура - содержит поля:
//  * ВидКонтактнойИнформации - СправочникСсылка.ВидыКонтактнойИнформации - вид редактируемой контактной информации.
//                              Структура -  см. УправлениеКонтактнойИнформацией.ПараметрыВидаКонтактнойИнформации
//  * Значение                - Строка - значение полей контактной информации в формате JSON или ХML.
//  * Представление           - Строка - представление контактной информации.
//  * ТипКонтактнойИнформации - ПеречислениеСсылка.ТипыКонтактнойИнформации - тип контактной информации, если был указан в параметрах.
//  * Страна                  - Строка - страна мира, только если указан тип контактной информации Адрес.
//  * Регион                  - Строка - значение поля региона, только если указан тип контактной информации Адрес.
//                                       Актуально для стран ЕАЭС.
//  * Индекс                  - Строка - страна мира, только если указан тип контактной информации Адрес.
//  * ТипПомещения            - Строка - тип помещения в форме ввода нового адреса, , только если указан тип контактной
//                                       информации Адрес.
//  * КодСтраны               - Строка - телефонный код страны мира, только если указан тип контактной информации Телефон.
//  * КодГорода               - Строка - телефонный код города, только если указан тип контактной информации Телефон.
//  * НомерТелефона           - Строка - телефонный номер, только если указан тип контактной информации Телефон.
//  * Добавочный              - Строка - добавочный телефонный номер, только если указан тип контактной информации Телефон.
//  * Заголовок               - Строка - заголовок формы. По умолчанию, представление вида контактной информации.
//
Функция ПараметрыФормыКонтактнойИнформации(ВидКонтактнойИнформации, Значение,
	Представление = Неопределено, Комментарий = Неопределено, ТипКонтактнойИнформации = Неопределено) Экспорт
	
	ПараметрыФормы = Новый Структура;
	ПараметрыФормы.Вставить("ВидКонтактнойИнформации", ВидКонтактнойИнформации);
	ПараметрыФормы.Вставить("Значение", Значение);
	ПараметрыФормы.Вставить("Представление", Представление);
	ПараметрыФормы.Вставить("Комментарий", Комментарий);
	Если ТипКонтактнойИнформации <> Неопределено Тогда
		ПараметрыФормы.Вставить("ТипКонтактнойИнформации", ТипКонтактнойИнформации);
		Если ТипКонтактнойИнформации = ПредопределенноеЗначение("Перечисление.ТипыКонтактнойИнформации.Адрес") Тогда
			ПараметрыФормы.Вставить("Страна");
			ПараметрыФормы.Вставить("Регион");
			ПараметрыФормы.Вставить("Индекс");
			ПараметрыФормы.Вставить("ТипПомещения", "Квартира");
		ИначеЕсли ТипКонтактнойИнформации = ПредопределенноеЗначение("Перечисление.ТипыКонтактнойИнформации.Телефон") Тогда
			ПараметрыФормы.Вставить("КодСтраны");
			ПараметрыФормы.Вставить("КодГорода");
			ПараметрыФормы.Вставить("НомерТелефона");
			ПараметрыФормы.Вставить("Добавочный");
		КонецЕсли;
	КонецЕсли;
	
	Если ТипЗнч(ВидКонтактнойИнформации) = Тип("Структура") И ВидКонтактнойИнформации.Свойство("Наименование") Тогда
		ПараметрыФормы.Вставить("Заголовок", ВидКонтактнойИнформации.Наименование);
	Иначе
		ПараметрыФормы.Вставить("Заголовок", Строка(ВидКонтактнойИнформации));
	КонецЕсли;
	
	Возврат ПараметрыФормы;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

// Конструктор для структуры параметров открытия формы контактной информации.
//
// Параметры:
//  ВидКонтактнойИнформации  - СправочникСсылка.ВидыКонтактнойИнформации - вид редактируемой контактной информации.
//                             Структура - см. УправлениеКонтактнойИнформацией.ПараметрыВидаКонтактнойИнформации
//  Значение                 - Строка - сериализованное значение полей контактной информации в формате JSON или XML.
//  Представление            - Строка - представление контактной информации.
//  Комментарий              - Строка - комментарий контактной информации.
//  ТипКонтактнойИнформации  - ПеречислениеСсылка.ТипыКонтактнойИнформации - тип контактной информации.
//                             Если указан, то в возвращаемую структуру добавляются поля соответствующие типу.
// 
// Возвращаемое значение:
//  Структура - содержит поля:
//  * ВидКонтактнойИнформации - СправочникСсылка.ВидыКонтактнойИнформации - вид редактируемой контактной информации.
//                              Структура -  см. УправлениеКонтактнойИнформацией.ПараметрыВидаКонтактнойИнформации
//  * Значение                - Строка - значение полей контактной информации в формате JSON или ХML.
//  * Представление           - Строка - представление контактной информации.
//  * ТипКонтактнойИнформации - ПеречислениеСсылка.ТипыКонтактнойИнформации - тип контактной информации, если был указан в параметрах.
//  * Страна                  - Строка - страна мира, только если указан тип контактной информации Адрес.
//  * Регион                  - Строка - значение поля региона, только если указан тип контактной информации Адрес.
//                                       Актуально для стран ЕАЭС.
//  * Индекс                  - Строка - страна мира, только если указан тип контактной информации Адрес.
//  * ТипПомещения            - Строка - тип помещения в форме ввода нового адреса, , только если указан тип контактной
//                                       информации Адрес.
//  * КодСтраны               - Строка - телефонный код страны мира, только если указан тип контактной информации Телефон.
//  * КодГорода               - Строка - телефонный код города, только если указан тип контактной информации Телефон.
//  * НомерТелефона           - Строка - телефонный номер, только если указан тип контактной информации Телефон.
//  * Добавочный              - Строка - добавочный телефонный номер, только если указан тип контактной информации Телефон.
//  * Заголовок               - Строка - заголовок формы. По умолчанию, представление вида контактной информации.
//
Функция ПараметрыФормыКонтактнойИнформации(ВидКонтактнойИнформации, Значение,
	Представление = Неопределено, Комментарий = Неопределено, ТипКонтактнойИнформации = Неопределено) Экспорт
	
	ПараметрыФормы = Новый Структура;
	ПараметрыФормы.Вставить("ВидКонтактнойИнформации", ВидКонтактнойИнформации);
	ПараметрыФормы.Вставить("Значение", Значение);
	ПараметрыФормы.Вставить("Представление", Представление);
	ПараметрыФормы.Вставить("Комментарий", Комментарий);
	Если ТипКонтактнойИнформации <> Неопределено Тогда
		ПараметрыФормы.Вставить("ТипКонтактнойИнформации", ТипКонтактнойИнформации);
		Если ТипКонтактнойИнформации = ПредопределенноеЗначение("Перечисление.ТипыКонтактнойИнформации.Адрес") Тогда
			ПараметрыФормы.Вставить("Страна");
			ПараметрыФормы.Вставить("Регион");
			ПараметрыФормы.Вставить("Индекс");
			ПараметрыФормы.Вставить("ТипПомещения", "Квартира");
		ИначеЕсли ТипКонтактнойИнформации = ПредопределенноеЗначение("Перечисление.ТипыКонтактнойИнформации.Телефон") Тогда
			ПараметрыФормы.Вставить("КодСтраны");
			ПараметрыФормы.Вставить("КодГорода");
			ПараметрыФормы.Вставить("НомерТелефона");
			ПараметрыФормы.Вставить("Добавочный");
		КонецЕсли;
	КонецЕсли;
	
	Если ТипЗнч(ВидКонтактнойИнформации) = Тип("Структура") И ВидКонтактнойИнформации.Свойство("Наименование") Тогда
		ПараметрыФормы.Вставить("Заголовок", ВидКонтактнойИнформации.Наименование);
	Иначе
		ПараметрыФормы.Вставить("Заголовок", Строка(ВидКонтактнойИнформации));
	КонецЕсли;
	
	Возврат ПараметрыФормы;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////