ПользовательскиеВариантыОтчетов (БСП)

Автор: 1С
ОбщийМодуль.ВариантыОтчетов
БСП

Пользовательские варианты отчетов. Получает варианты переданного отчета и их представления.

// Получает варианты переданного отчета и их представления.
//
// Места использования:
//   ПользователиСлужебный.ПриПолученииПользовательскихВариантовОтчетов().
//
Процедура ПользовательскиеВариантыОтчетов(ПолноеИмяОтчета, ПользовательИнформационнойБазы, ТаблицаВариантовОтчетов, СтандартнаяОбработка) Экспорт
	КлючОтчета = ПолноеИмяОтчета;
	ВсеВариантыОтчета = КлючиВариантовОтчета(КлючОтчета, ПользовательИнформационнойБазы);
	
	Для Каждого ВариантОтчета Из ВсеВариантыОтчета Цикл
		ЭлементСправочника = Справочники.ВариантыОтчетов.НайтиПоНаименованию(ВариантОтчета.Представление);
		Если ЭлементСправочника = Неопределено Тогда 
			Продолжить;
		КонецЕсли;
		
		СтандартнаяОбработка = Ложь;
		
		Если Не ЭлементСправочника.ТолькоДляАвтора Тогда 
			Продолжить;
		КонецЕсли;
		
		СтрокаВариантовОтчетов = ТаблицаВариантовОтчетов.Добавить();
		СтрокаВариантовОтчетов.КлючОбъекта = ПолноеИмяОтчета;
		СтрокаВариантовОтчетов.КлючВарианта = ВариантОтчета.Значение;
		СтрокаВариантовОтчетов.Представление = ВариантОтчета.Представление;
		СтрокаВариантовОтчетов.СтандартнаяОбработка = Ложь;
	КонецЦикла;
	
	Если Не СтандартнаяОбработка Тогда 
		Возврат;
	КонецЕсли;
	
	МетаданныеОтчета = Метаданные.НайтиПоПолномуИмени(ПолноеИмяОтчета);
	Если (МетаданныеОтчета <> Неопределено И МетаданныеОтчета.ХранилищеВариантов <> Неопределено)
		Или ТипЗнч(ХранилищеВариантовОтчетов) <> Тип("СтандартноеХранилищеНастроекМенеджер") Тогда 
		
		СтандартнаяОбработка = Ложь;
	КонецЕсли;
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

УдалитьПользовательскийВариантОтчета (БСП)

ПриУдаленииПользовательскихВариантовОтчета (БСП)

ПриПолученииПользовательскихВариантовОтчетов (БСП)

ОбновитьИндексПоискаПользовательскихВариантовОтчетов (БСП)

ЗагрузитьПользовательские (БСП)

УдалитьВариантОтчета (БСП)

ТаблицаВариантовОтчетов (БСП)

ОтключенныеВариантыОтчетов (БСП)

СброситьПользовательскиеНастройки (БСП)

TurboConf - расширение Конфигуратора 1С