ВыгрузитьДанныеВКаталог (БСП)

Автор: 1С
ОбщийМодуль.ВыгрузкаЗагрузкаДанныхСлужебный
БСП

Выгрузить данные каталог. Выгружает данные в каталог.

// Выгружает данные в каталог.
//
// Параметры:
//	КаталогВыгрузки - Строка - путь к каталогу выгрузки.
//	ПараметрыВыгрузки - Структура, содержащая параметры выгрузки данных.
//		Ключи:
//			ВыгружаемыеТипы - Массив(ОбъектМетаданных) - массив объектов метаданных, данные
//				которых требуется выгрузить в архив,
//			ВыгружатьПользователей - Булево - выгружать информацию о пользователях информационной базы,
//			ВыгружатьНастройкиПользователей - Булево, игнорируется если ВыгружатьПользователей = Ложь.
//			Также структура может содержать дополнительные ключи, которые могут быть обработаны внутри
//				произвольных обработчиков выгрузки данных.
//
Процедура ВыгрузитьДанныеВКаталог(Знач КаталогВыгрузки, Знач ПараметрыВыгрузки) Экспорт
	
	Контейнер = Обработки.ВыгрузкаЗагрузкаДанныхМенеджерКонтейнера.Создать();
	Контейнер.ИнициализироватьВыгрузку(КаталогВыгрузки, ПараметрыВыгрузки);
	
	АннотируемыеСсылочныеТипы = ВыгрузкаЗагрузкаДанныхСлужебныйСобытия.ПолучитьТипыТребующиеАннотациюСсылокПриВыгрузке();
	Сериализатор = СериализаторXDTOСАннотациейТипов(Контейнер, АннотируемыеСсылочныеТипы);
	
	Обработчики = Обработки.ВыгрузкаЗагрузкаДанныхМенеджерОбработчиковВыгрузкиДанных.Создать();
	
	Обработчики.ПередВыгрузкойДанных(Контейнер);
	
	СохранитьОписаниеВыгрузки(Контейнер);
	
	Обработки.ВыгрузкаЗагрузкаДанныхМенеджерВыгрузкиДанныхИнформационнойБазы.ВыгрузитьДанныеИнформационнойБазы(
		Контейнер, Обработчики, Сериализатор);
	
	Если ПараметрыВыгрузки.ВыгружатьПользователей Тогда
		
		ВыгрузкаЗагрузкаПользователейИнформационнойБазы.ВыгрузитьПользователейИнформационнойБазы(Контейнер);
		
		Если ПараметрыВыгрузки.ВыгружатьНастройкиПользователей Тогда
			
			Обработки.ВыгрузкаЗагрузкаДанныхМенеджерВыгрузкиНастроекПользователей.ВыгрузитьНастройкиПользователейИнформационнойБазы(
				Контейнер, Обработчики, Сериализатор);
			
		КонецЕсли;
		
	КонецЕсли;
	
	Обработчики.ПослеВыгрузкиДанных(Контейнер);
	
	Контейнер.ФинализироватьВыгрузку();
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ВыгрузитьДанныеВАрхив (БСП)

ЗагрузитьДанныеИзКаталога (БСП)

ВыгрузитьТекущуюОбластьДанныхВАрхив (БСП)

ВыгрузитьТекущуюОбластьДанныхВоВременноеХранилище (БСП)

ВыгрузитьТекущуюОбластьДанныхВФайлИРазделитьНаЧасти (БСП)

ВыгрузитьВФайл (БСП)

ВыбратьПутьККаталогуДанныхПользователя (БСП)

TurboConf - расширение Конфигуратора 1С