ЗагрузитьПользователейИнформационнойБазы (БСП)

Автор: 1С
ОбщийМодуль.ВыгрузкаЗагрузкаПользователейИнформационнойБазы
БСП

Загрузить пользователей информационной базы.

Процедура ЗагрузитьПользователейИнформационнойБазы(Контейнер) Экспорт
	
	ИмяФайла = Контейнер.ПолучитьФайлИзКаталога(ВыгрузкаЗагрузкаДанныхСлужебный.Users());
	
	ПотокЧтения = Новый ЧтениеXML();
	ПотокЧтения.ОткрытьФайл(ИмяФайла);
	ПотокЧтения.ПерейтиКСодержимому();
	
	Если ПотокЧтения.ТипУзла <> ТипУзлаXML.НачалоЭлемента
			Или ПотокЧтения.Имя <> "Data" Тогда
		
		ВызватьИсключение СтрШаблон(НСтр("ru = 'Ошибка чтения XML. Неверный формат файла. Ожидается начало элемента %1.'"),
			"Data"
		);
		
	КонецЕсли;
	
	Если НЕ ПотокЧтения.Прочитать() Тогда
		ВызватьИсключение НСтр("ru = 'Ошибка чтения XML. Обнаружено завершение файла.'");
	КонецЕсли;
	
	Пока ПотокЧтения.ТипУзла = ТипУзлаXML.НачалоЭлемента Цикл
		
		СериализацияПользователя = ФабрикаXDTO.ПрочитатьXML(ПотокЧтения, ФабрикаXDTO.Тип("http://www.1c.ru/1cFresh/Data/Dump/1.0.2.1", "InfoBaseUser"));
		
		ПользовательИБ = ДесериализоватьПользователяИнформационнойБазы(СериализацияПользователя);
		
		Отказ = Ложь;
		ВыгрузкаЗагрузкаДанныхСлужебныйСобытия.ВыполнитьДействияПриЗагрузкеПользователяИнформационнойБазы(
			Контейнер, СериализацияПользователя, ПользовательИБ, Отказ);
		
		Если Не Отказ Тогда
			
			ПользовательИБ.Записать();
			
			ВыгрузкаЗагрузкаДанныхСлужебныйСобытия.ВыполнитьДействияПослеЗагрузкиПользователяИнформационнойБазы(
				Контейнер, СериализацияПользователя, ПользовательИБ);
			
		КонецЕсли;
		
	КонецЦикла;
	
	ПотокЧтения.Закрыть();
	
	ВыгрузкаЗагрузкаДанныхСлужебныйСобытия.ВыполнитьДействияПослеЗагрузкиПользователейИнформационнойБазы(Контейнер);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ЗагрузитьДанныеXDTOВИнформационнуюБазу (БСП)

ВыгрузитьПользователейИнформационнойБазы (БСП)

ПриЗагрузкеПользователяИнформационнойБазы (БСП)

ПослеЗагрузкиПользователяИнформационнойБазы (БСП)

ПослеЗагрузкиПользователейИнформационнойБазы (БСП)

ПриЗаписиПользователяИнформационнойБазы (БСП)

Обновлятор-1С: групповое (пакетное) обновление и обслуживание всех баз за один раз