СоздатьИОтправитьСообщениеSMS (БСП)

Автор: 1С
ОбщийМодуль.Взаимодействия
БСП

Создать отправить сообщение sms.

Процедура СоздатьИОтправитьСообщениеSMS(Сообщение) Экспорт

	СообщениеSMS = Документы.СообщениеSMS.СоздатьДокумент();
	
	СообщениеSMS.Дата                    = ТекущаяДатаСеанса();
	СообщениеSMS.Автор                   = Пользователи.ТекущийПользователь();

	СообщениеSMS.Ответственный           = Пользователи.ТекущийПользователь();
	СообщениеSMS.Важность                = Перечисления.ВариантыВажностиВзаимодействия.Обычная;

	СообщениеSMS.ВзаимодействиеОснование = Неопределено;
	СообщениеSMS.ТекстСообщения          = Сообщение.Текст;
	СообщениеSMS.Тема                    = ТемаПоТекстуСообщения(Сообщение.Текст);
	СообщениеSMS.ОтправлятьВТранслите    = Сообщение.ДополнительныеПараметры.ПеревестиВТранслит;
	СообщениеSMS.Комментарий             = КомментарийПоНаименованиюШаблона(Сообщение.ДополнительныеПараметры.Наименование);
	
	Для каждого АдресатSMS Из Сообщение.Получатель Цикл
		
		НоваяСтрока = СообщениеSMS.Адресаты.Добавить();
		Если ТипЗнч(АдресатSMS) = Тип("Структура") Тогда
			НоваяСтрока.Контакт                = АдресатSMS.ИсточникКонтактнойИнформации;
			НоваяСтрока.ПредставлениеКонтакта  = АдресатSMS.Представление;
			НоваяСтрока.КакСвязаться           = АдресатSMS.НомерТелефона;
			НоваяСтрока.НомерДляОтправки       = АдресатSMS.НомерТелефона;
		Иначе
			НоваяСтрока.Контакт                = "";
			НоваяСтрока.ПредставлениеКонтакта  = АдресатSMS.Представление;
			НоваяСтрока.КакСвязаться           = АдресатSMS.Значение;
			НоваяСтрока.НомерДляОтправки       = АдресатSMS.Значение;
		КонецЕсли;
		НоваяСтрока.ИдентификаторСообщения = "";
		НоваяСтрока.ТекстОшибки            = "";
		НоваяСтрока.СостояниеСообщения = Перечисления.СостоянияСообщенияSMS.Черновик;
	
	КонецЦикла;
	
	Если ОбщегоНазначения.ИнформационнаяБазаФайловая() Тогда
		ОтправкаSMSПоДокументу(СообщениеSMS);
	Иначе
		ВзаимодействияКлиентСервер.УстановитьСостояниеИсходящееДокументСообщениеSMS(СообщениеSMS);
	КонецЕсли;
	
	СообщениеSMS.Записать();
	
	Если Сообщение.ДополнительныеПараметры.Свойство("Предмет") И ЗначениеЗаполнено(Сообщение.ДополнительныеПараметры.Предмет) Тогда
		Предмет = Сообщение.ДополнительныеПараметры.Предмет;
	Иначе
		Предмет = СообщениеSMS.Ссылка;
	КонецЕсли;
	Реквизиты = СтруктураРеквизитовВзаимодействияДляЗаписи(Предмет, Истина);
	РегистрыСведений.ПредметыПапкиВзаимодействий.ЗаписатьПредметыПапкиВзаимодействий(СообщениеSMS.Ссылка, Реквизиты);
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ОтправитьСообщение (БСП)

СформироватьСообщениеИОтправить (БСП)

ОтправитьДанныеСообщенияВТехПоддержку (БСП)

СоздатьШаблон (БСП)

TurboConf - расширение Конфигуратора 1С