Реквизиты (БСП)

Автор: 1С
ОбщийМодуль.ЗапретРедактированияРеквизитовОбъектовКлиент
БСП

Реквизиты. Возвращает массив имен реквизитов, заданных в свойстве формы ПараметрыЗапретаРедактированияРеквизитов

// Возвращает массив имен реквизитов, заданных в свойстве формы ПараметрыЗапретаРедактированияРеквизитов
// на основе имен реквизитов, указанных в модуле менеджера объекта, исключая реквизиты,
// у которых ПравоРедактирования = Ложь.
//
// Параметры:
//  Форма         - ФормаКлиентскогоПриложения - форма объекта с обязательным стандартным реквизитом "Объект".
//  ТолькоЗаблокированные - Булево - для вспомогательных целей можно задать Ложь, чтобы
//                  получить список всех видимых реквизитов, которые могут разблокироваться.
//  ТолькоВидимые - Булево - чтобы получить и разблокировать все реквизиты объекта, нужно указать Ложь.
//
// Возвращаемое значение:
//  Массив - значения:
//   * Строка - имена реквизитов.
//
Функция Реквизиты(Знач Форма, Знач ТолькоЗаблокированные = Истина, ТолькоВидимые = Истина) Экспорт
	
	Реквизиты = Новый Массив;
	
	Для Каждого ОписаниеБлокируемогоРеквизита Из Форма.ПараметрыЗапретаРедактированияРеквизитов Цикл
		
		Если ОписаниеБлокируемогоРеквизита.ПравоРедактирования
		   И (    ОписаниеБлокируемогоРеквизита.РедактированиеРазрешено = Ложь
		      ИЛИ ТолькоЗаблокированные = Ложь) Тогда
			
			ДобавитьРеквизит = Ложь;
			Для Каждого БлокируемыйЭлементФормы Из ОписаниеБлокируемогоРеквизита.БлокируемыеЭлементы Цикл
				ЭлементФормы = Форма.Элементы.Найти(БлокируемыйЭлементФормы.Значение);
				Если ЭлементФормы <> Неопределено И (ЭлементФормы.Видимость Или НЕ ТолькоВидимые) Тогда
					ДобавитьРеквизит = Истина;
					Прервать;
				КонецЕсли;
			КонецЦикла;
			Если ДобавитьРеквизит Тогда
				Реквизиты.Добавить(ОписаниеБлокируемогоРеквизита.ИмяРеквизита);
			КонецЕсли;
		КонецЕсли;
	КонецЦикла;
	
	Возврат Реквизиты;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

РеквизитыПоСКД (БСП)

КонтролируемыеРеквизиты (БСП)

ЗаполнитьРеквизитыПоСКД (БСП)

ОбщиеРеквизиты (БСП)

НаименованиеВыводимогоРеквизита (БСП)

ИменаРеквизитовПоТипу (БСП)

ЛокализованныеЗначенияРеквизитов (БСП)

ОпределитьОшибочныеРеквизиты (БСП)

ЗаголовокОбщиеРеквизиты (БСП)

TurboConf - расширение Конфигуратора 1С