ПриПолученииДанныхНаСервере (БСП)

Автор: 1С
ОбщийМодуль.ЗащитаПерсональныхДанных
БСП

При получении данных на сервере. В форме списка заполняет колонку с картинкой, сигнализирующей об отсутствии требуемого согласия

// В форме списка заполняет колонку с картинкой, сигнализирующей об отсутствии требуемого согласия 
// на обработку персональных данных по субъектам в строках. 
// Вызывается из события ПриПолученииДанныхНаСервере формы списка.
//
// Параметры:
//   Настройки              - НастройкиКомпоновкиДанных - Содержит копию полных настроек динамического списка.
//   Строки                 - СтрокиДинамическогоСписка - Коллекция содержит данные и оформление всех строк,
//                            получаемых в списке, кроме строк группировок.
//
Процедура ПриПолученииДанныхНаСервере(Настройки, Строки) Экспорт
	
	Перем ТекущаяДата;
	
	Если Не Настройки.ДополнительныеСвойства.Свойство("ТекущаяДата", ТекущаяДата) Тогда
		Возврат;
	КонецЕсли;
	
	ДнейДоСкрытия = ДнейДоСкрытияПерсональныхДанныхСубъектов();
	
	Запрос = Новый Запрос;
	Запрос.Текст = ТекстЗапросаСубъектыДляСкрытияПерсональныхДанных(Истина) + "
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	Субъекты.Субъект КАК Субъект
	|ИЗ
	|	ВТСубъектыДляСкрытия КАК Субъекты
	|ГДЕ
	|	Субъекты.Субъект В(&Субъекты)
	|
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	СубъектыДляСкрытияПДн.Субъект
	|ИЗ
	|	РегистрСведений.СубъектыДляСкрытияПерсональныхДанных КАК СубъектыДляСкрытияПДн
	|ГДЕ
	|	СубъектыДляСкрытияПДн.Субъект В(&Субъекты)
	|	И СубъектыДляСкрытияПДн.ДатаСкрытия > &ПустаяДата
	|	И СубъектыДляСкрытияПДн.ДатаСкрытия <= &РасчетнаяДата
	|	И СубъектыДляСкрытияПДн.Состояние = ЗНАЧЕНИЕ(Перечисление.СостоянияСубъектовДляСкрытия.ГотовКСкрытию)";
	
	Запрос.УстановитьПараметр("Субъекты", Строки.ПолучитьКлючи());
	Запрос.УстановитьПараметр("ПустаяДата", '00010101');
	Запрос.УстановитьПараметр("РасчетнаяДата", ТекущаяДата + ДнейДоСкрытия * 86400);
	
	УстановитьПривилегированныйРежим(Истина);
	Выборка = Запрос.Выполнить().Выбрать();
	УстановитьПривилегированныйРежим(Ложь);
	
	Пока Выборка.Следующий() Цикл
		СтрокаСписка = Строки[Выборка.Субъект];
		СтрокаСписка.Данные["ОтсутствуетСогласие"] = 1;
	КонецЦикла;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

FTPИмяСервераИПуть (БСП)

ОшибкаПриПолученииДанных (БСП)

ОбработатьПолученныеДанныеОбласти (БСП)

ПрочитатьПолученныеДанныеОбъекта (БСП)

ПриПолученииДанныхОтПодчиненного (БСП)

ОшибкаРасхожденияВерсийПриПолученииДанных (БСП)

TurboConf - расширение Конфигуратора 1С