ПрочитатьНастройкиСкрытияСубъектов (БСП)

Автор: 1С
ОбщийМодуль.ЗащитаПерсональныхДанных
БСП

Прочитать настройки скрытия субъектов. Возвращает существующие настройки скрытия субъектов.

// Возвращает существующие настройки скрытия субъектов.
//
// Параметры:
//	Субъекты - Массив, ОпределяемыйТип.СубъектПерсональныхДанных - ссылка или массив ссылок на субъекты.
//
// Возвращаемое значение:
//     Соответствие - со свойствами:
//      * Ключ     - ОпределяемыйТип.СубъектПерсональныхДанных - субъект.
//      * Значение - Структура - структура настроек. Описание см. НастройкиСкрытияСубъектовПоУмолчанию.
//
Функция ПрочитатьНастройкиСкрытияСубъектов(Знач Субъекты) Экспорт
	
	НастройкиСубъектов = Новый Соответствие;
	Если Не ЗначениеЗаполнено(Субъекты) Тогда
		Возврат НастройкиСубъектов;
	КонецЕсли;
	
	Если ТипЗнч(Субъекты) <> Тип("Массив") Тогда
		Субъекты = ОбщегоНазначенияКлиентСервер.ЗначениеВМассиве(Субъекты);
	КонецЕсли;
	
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("Субъекты", Субъекты);
	
	Запрос.Текст = "ВЫБРАТЬ
	|	СубъектыДляСкрытияПерсональныхДанных.ДатаСкрытия КАК ДатаСкрытия,
	|	СубъектыДляСкрытияПерсональныхДанных.Состояние КАК Состояние,
	|	СубъектыДляСкрытияПерсональныхДанных.ПричинаОтменыСкрытия КАК ПричинаОтменыСкрытия,
	|	СубъектыДляСкрытияПерсональныхДанных.Субъект КАК Субъект,
	|	СубъектыДляСкрытияПерсональныхДанных.Основание КАК Основание
	|ИЗ
	|	РегистрСведений.СубъектыДляСкрытияПерсональныхДанных КАК СубъектыДляСкрытияПерсональныхДанных
	|ГДЕ
	|	СубъектыДляСкрытияПерсональныхДанных.Субъект В(&Субъекты)";
	
	Выборка = Запрос.Выполнить().Выбрать();
	НастройкиСкрытия = НастройкиСкрытияСубъектовПоУмолчанию();
	
	Для Каждого Субъект Из Субъекты Цикл
		
		НастройкиСкрытияСубъекта = ОбщегоНазначения.СкопироватьРекурсивно(НастройкиСкрытия);
		
		Выборка.Сбросить();
		Если Выборка.НайтиСледующий(Новый Структура("Субъект", Субъект)) Тогда
			ЗаполнитьЗначенияСвойств(НастройкиСкрытияСубъекта, Выборка);
		КонецЕсли;
		
		НастройкиСубъектов.Вставить(Субъект, НастройкиСкрытияСубъекта);
		
	КонецЦикла;
	
	Возврат НастройкиСубъектов;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Рекомендации

Похожие публикации

ИзменитьНастройкиСкрытияПерсональныхДанных (БСП)

ИспользоватьСкрытиеПерсональныхДанныхСубъектов (БСП)

ДнейДоСкрытияПерсональныхДанныхСубъектов (БСП)

СкрытьПерсональныеДанныеСубъектов (БСП)

СкрытиеПерсональныхДанныхСубъектов (БСП)

ОбновитьДатыСкрытияПерсональныхДанныхСубъектов (БСП)

ЭтоОбъектСоСкрытымиПерсональнымиДанными (БСП)

ЗапуститьИзменениеНастроекСкрытияПДнВФоновомЗадании (БСП)

ПередСкрытиемПерсональныхДанныхСубъектов (БСП)

TurboConf - расширение Конфигуратора 1С