Публикации

БСП
Разработки

Найдено результатов: 28


ИнициализироватьWSПроксиДляУправленияОбменомДанными

Инициализирует WS-прокси для выполнения управляющих команд обмена данными,
ОбщийМодуль.ОбменДаннымиСервер
Автор: 1С
// Инициализирует WS-прокси для выполнения управляющих команд обмена данными,
// предварительно проверяет наличие узла обмена.
//
// Параметры:
//   Прокси - WSПрокси - WS-прокси для передачи управляющих команд.
//   СтруктураНастроек - Структура - структура параметров для подключения к корреспонденту и идентификации настройки обмена.
//     * ИмяПланаОбмена - Строка - имя плана обмена, используемого при синхронизации.
//     * УзелИнформационнойБазы - ПланОбменаСсылка - узел плана обмена, соответствующий корреспонденту.
//     * КлючСообщенияЖурналаРегистрации - Строка - имя события для записи ошибок в журнал регистрации.
//     * ТекущийУзелПланаОбмена - ПланОбменаСсылка - ссылка на ЭтотУзел плана обмена.
//     * ТекущийУзелПланаОбменаКод - Строка - идентификатор текущего узла плана обмена.
//     * ДействиеПриОбмене - ПеречислениеСсылка.ДействияПриОбмене - указывает на направление обмена.
//   ПараметрыПрокси - Структура
//     * ПараметрыАутентификации - Строка, Структура - содержит пароль для аутентификации на веб-сервере.
//     * СтруктураНастроекАутентификации - Структура - содержит структуру настроек для аутентификации на веб-сервере.
//     * МинимальнаяВерсия - Строка - номер минимальной версии интерфейса "ОбменДанными", требуемый для выполнения действий.
//     * ТекущаяВерсия - Строка - исходящий, фактическая версия интерфейса инициализированного WS-прокси.
//   Отказ - Булево - признак неуспешной инициализации WS-прокси.
//   СостояниеНастройки - Структура - исходящий, возвращает состояние настройки синхронизации, описанной в СтруктураНастроек.
//     * НастройкаСуществует - Булево - Истина, если настройка с указанными планом обмена и идентификатором узла существует.
//     * НастройкаСинхронизацииДанныхЗавершена - Булево - Истина, если настройка синхронизации завершена.
//     * ПоддерживаетсяСопоставлениеДанных - Булево - Истина, если корреспондент поддерживает функцию сопоставления данных.
//     * ПолученоСообщениеДляСопоставленияДанных - Булево - Истина, в корреспондент загружено сообщение для сопоставления.
//   СтрокаСообщенияОбОшибке - Строка - описание ошибки инициализации WS-прокси.
//
Процедура ИнициализироватьWSПроксиДляУправленияОбменомДанными(Прокси,
		СтруктураНастроек, ПараметрыПрокси, Отказ, СостояниеНастройки, СтрокаСообщенияОбОшибке = "") Экспорт
	
	МинимальнаяВерсия = "0.0.0.0";
	Если ПараметрыПрокси.Свойство("МинимальнаяВерсия") Тогда
		МинимальнаяВерсия = ПараметрыПрокси.МинимальнаяВерсия;
	КонецЕсли;
	
	ПараметрыАутентификации = Неопределено;
	ПараметрыПрокси.Свойство("ПараметрыАутентификации", ПараметрыАутентификации);
	
	СтруктураНастроекАутентификации = Неопределено;
	ПараметрыПрокси.Свойство("СтруктураНастроекАутентификации", СтруктураНастроекАутентификации);
	
	ПараметрыПрокси.Вставить("ТекущаяВерсия", Неопределено);
	
	ДополнительныеПараметры = Новый Структура;
	ДополнительныеПараметры.Вставить("ПараметрыАутентификации",         ПараметрыАутентификации);
	ДополнительныеПараметры.Вставить("МинимальнаяВерсия",               МинимальнаяВерсия);
	ДополнительныеПараметры.Вставить("СтруктураНастроекАутентификации", СтруктураНастроекАутентификации);
	
	Прокси = WSПроксиДляУзлаИнформационнойБазы(
		СтруктураНастроек.УзелИнформационнойБазы,
		СтрокаСообщенияОбОшибке,
		ДополнительныеПараметры);
		
	Если Прокси = Неопределено Тогда
		Отказ = Истина;
		Возврат;
	КонецЕсли;
	
	ПараметрыПрокси.ТекущаяВерсия = ДополнительныеПараметры.ТекущаяВерсия;
	
	УзелСуществует = Ложь;
	
	Если ЭтоПланОбменаXDTO(СтруктураНастроек.ИмяПланаОбмена) Тогда
		
		ПсевдонимУзла = ПсевдонимПредопределенногоУзла(СтруктураНастроек.УзелИнформационнойБазы);
		Если ЗначениеЗаполнено(ПсевдонимУзла) Тогда
			// Проверка настройки со старым идентификатором (префиксом).
			СостояниеНастройки = СостояниеНастройкиСинхронизацииВКорреспонденте(
				Прокси,
				ПараметрыПрокси,
				СтруктураНастроек.ИмяПланаОбмена,
				ПсевдонимУзла);
				
			Если Не СостояниеНастройки.НастройкаСуществует Тогда
				Если ВКорреспондентеУстаревшийВариантНастроекОбмена(
					Прокси, ПараметрыПрокси, СостояниеНастройки, СтруктураНастроек, ПсевдонимУзла, Отказ, СтрокаСообщенияОбОшибке)
					Или Отказ Тогда
					Возврат;
				КонецЕсли;
			Иначе
				СтруктураНастроек.ТекущийУзелПланаОбменаКод = ПсевдонимУзла;
				Возврат;
			КонецЕсли;
		КонецЕсли;
		
		СостояниеНастройки = СостояниеНастройкиСинхронизацииВКорреспонденте(
			Прокси,
			ПараметрыПрокси,
			СтруктураНастроек.ИмяПланаОбмена,
			СтруктураНастроек.ТекущийУзелПланаОбменаКод);
			
		Если Не СостояниеНастройки.НастройкаСуществует Тогда
			Если ВКорреспондентеУстаревшийВариантНастроекОбмена(
				Прокси, ПараметрыПрокси, СтруктураНастроек, СостояниеНастройки, СтруктураНастроек.ТекущийУзелПланаОбменаКод, Отказ, СтрокаСообщенияОбОшибке)
				Или Отказ Тогда
				Возврат;
			КонецЕсли;
		КонецЕсли;
		
	Иначе
		СостояниеНастройки = СостояниеНастройкиСинхронизацииВКорреспонденте(
			Прокси,
			ПараметрыПрокси,
			СтруктураНастроек.ИмяПланаОбмена,
			СтруктураНастроек.ТекущийУзелПланаОбменаКод);
	КонецЕсли;
	
	Если Не СостояниеНастройки.НастройкаСуществует Тогда
		СтрокаСообщенияОбОшибке = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
			НСтр("ru = 'Не найдена настройка синхронизации данных ""%1"" с идентификатором ""%2"".'"),
			СтруктураНастроек.ИмяПланаОбмена,
			СтруктураНастроек.ТекущийУзелПланаОбменаКод);
		Отказ = Истина;
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

Обмен через ВЕБ Сервисы 2 часть

Обмен через ВЕБ Сервисы , Подключение к созданной web ссылке с другой базы.
Артур 46 2 3
Процедура КнопкаЗаполнитьТаблицуИзПервойБазыНажатие(Кнопка)
      
	ВСОпределение = Новый WSОпределения("127.7.7.7/Obmen/ws/Obmen.1cws?wsdl", "admin", "pass"); 
//127.7.7.7 - ВашИПАдресГдеОпубликованWebСервис 
//admin - пользователь информационной базы с полными правами и пароль -pass
	ВСПрокси = Новый WSПрокси(ВСОпределение, "127.7.7.7", "Obmen", "ObmenSoap");
//127.7.7.7 - URl пространство имен Веб сервиса первой базы, Obmen -наименование 
// расширения ,
//ObmenSoap тоже самое Но добавляем Soap к названии ))
	
	Склад= Элементы.Склад.Значение; //Элемент формы, выбранное поле - склад
	Время=ТекущаяДата();
	
	ВСПрокси.Пользователь = "admin";
	ВСПрокси.Пароль = "pass";
	
	Данные = ВСПрокси.ОстаткиТоваровТНН(Строка(Склад),Дата(Время));  // подключаемся и получаем данные xml 
	
	попытка
	
	ЧтениеXML               = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(данные);  //Открываем файл
	Пока ЧтениеXML.Прочитать() Цикл
		Если ЧтениеXML.ТипУзла                  = ТипУзлаXML.НачалоЭлемента Тогда 
			Пока ЧтениеXML.ПрочитатьАтрибут() Цикл
				ст = Таб.Добавить();  //Табличная часть на форме 
				ст.Номенклатура = Справочники.Номенклатура.НайтиПоНаименованию(ЧтениеXML.ЗначениеАтрибута("Номенклатура"));
				ст.Склад = Справочники.Склады.НайтиПоНаименованию(ЧтениеXML.ЗначениеАтрибута("Склад"));
				ст.КоличествоНачальныйОстаток = ЧтениеXML.ЗначениеАтрибута("КоличествоНачальныйОстаток");
				ст.КоличествоПриход = ЧтениеXML.ЗначениеАтрибута("КоличествоПриход");
				ст.КоличествоРасход = ЧтениеXML.ЗначениеАтрибута("КоличествоРасход");
				ст.КоличествоКонечныйОстаток = ЧтениеXML.ЗначениеАтрибута("КоличествоКонечныйОстаток");
				прервать;	
			конеццикла;
		КонецЕсли;
	конеццикла;	
	
	исключение
	    сообщить(Данные);
	КонецПопытки;
	
	
конецпроцедуры

Обмен через ВЕБ Сервисы 1 часть

Обмен xml файлами через ВЕБ Сервисы (Запрос остаток товаров с одной базы на другую по wеб сервису,) настройка и создание web сервиса.
Артур 46 2 3
//1.Создаем web-сервис (заполняем только "Основные" и "Прочее", пока что ...)
//      - Имя любое(не критично, но желательно на англ.)
//      -URl пространство имен - вводим ip адресс для удобства (пример: 127.7.7.7)
//      -Пакеты XDTO , я еще не совсем разобрался )), поэтому выбираю стандартный 
//        (http://v8.1c.ru/8.1/xdto),  особой роли не играет в данном примере.
//        -Имя файла публикации - Любое значение с форматом *.1cws(Пример:  Obmen.1cws)
//2. Создаем Операцию с параметрами (Напоминает стандартную "Функцию" с параметрами)
//       Например -Операция "ОстаткиТоваровНТТ" 
//       тип возвращаемого значение- "Строка"- string (http://www.w3.org/2001/XMLSchema)
//3 создаем операции :Время с Типом: DataTime , Склад с Типом: string - пока хватит )
//4 создаем процедуру для операции "ОстаткиТоваровНТТ", в свойствах операции и 
//  заполним функцию ниже:
//5 в самом конце, обновляем базу и публикуем, готово!


Функция ОстаткиТоваровНТТ(Склад, Время)

	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку("UTF-8"); 
	ЗаписьXML.ЗаписатьОбъявлениеXML();  // Записываем объявление XML
	ЗаписьXML.ЗаписатьНачалоЭлемента("ОстаткиТоваров"); 

	Запрос = Новый Запрос;
	Запрос.Текст ="ВЫБРАТЬ
	              |	ТоварыНаСкладахОстаткиИОбороты.Номенклатура КАК Номенклатура,
	              |	ТоварыНаСкладахОстаткиИОбороты.Склад КАК Склад,
	              |	СУММА(ТоварыНаСкладахОстаткиИОбороты.КоличествоНачальныйОстаток) КАК КоличествоНачальныйОстаток,
	              |	СУММА(ТоварыНаСкладахОстаткиИОбороты.КоличествоПриход) КАК КоличествоПриход,
	              |	СУММА(ТоварыНаСкладахОстаткиИОбороты.КоличествоРасход) КАК КоличествоРасход,
	              |	СУММА(ТоварыНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток) КАК КоличествоКонечныйОстаток
	              |ИЗ
	              |	РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачПериод, &КонПериод, Авто, , ) КАК ТоварыНаСкладахОстаткиИОбороты
	              |ГДЕ
	              |	ТоварыНаСкладахОстаткиИОбороты.Склад = &Склад				  
		      |СГРУППИРОВАТЬ ПО
	              |	ТоварыНаСкладахОстаткиИОбороты.Номенклатура,
	              |	ТоварыНаСкладахОстаткиИОбороты.Склад,
	              |
	              |УПОРЯДОЧИТЬ ПО
	              |	Номенклатура УБЫВ"; 

	Запрос.УстановитьПараметр("НачПериод", Дата(НачалоДня(Время)));
	Запрос.УстановитьПараметр("КонПериод", Дата(КонецДня(Время)));
	Запрос.УстановитьПараметр("Склад", Справочники.Склады.НайтиПоНаименованию(Склад,Истина));  //склад заморозки Москва
	
	Если запрос.Выполнить().Пустой() тогда
		ответ = "За выбранный период остатков не найдено";
	        возврат ответ;
	КонецЕсли;
	Результат = Запрос.Выполнить().Выбрать();
	пока Результат.Следующий() цикл
		ЗаписьXML.ЗаписатьНачалоЭлемента("Результат");
		ЗаписьXML.ЗаписатьАтрибут("Склад", Строка(Результат.Склад));
	   	ЗаписьXML.ЗаписатьАтрибут("КоличествоНачальныйОстаток", Строка(Результат.КоличествоНачальныйОстаток));
		ЗаписьXML.ЗаписатьАтрибут("КоличествоПриход", Строка(Результат.КоличествоПриход));
		ЗаписьXML.ЗаписатьАтрибут("Номенклатура", Строка(Результат.Номенклатура));
		ЗаписьXML.ЗаписатьАтрибут("КоличествоРасход", Строка(Результат.КоличествоРасход));
		ЗаписьXML.ЗаписатьАтрибут("КоличествоКонечныйОстаток", Строка(Результат.КоличествоКонечныйОстаток));
		ЗаписьXML.ЗаписатьКонецЭлемента();  
	конеццикла;
	ЗаписьXML.ЗаписатьКонецЭлемента();
	данные= ЗаписьXML.Закрыть();
	
	Возврат Данные;
конецфункции
// Функция получает остатки из регистра по полученным параметрам (Время и склад),
// формирует XML запись , и отправляет обратно 

КлиентПодключенЧерезВебСервер

Возвращает Истина, если клиентское приложение подключено к базе через веб-сервер.
ОбщийМодуль.ОбщегоНазначения
Автор: 1С
// Возвращает Истина, если клиентское приложение подключено к базе через веб-сервер.
//
// Возвращаемое значение:
//  Булево - Истина, если подключен.
//
Функция КлиентПодключенЧерезВебСервер() Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	СтрокаСоединенияИнформационнойБазы = СтандартныеПодсистемыСервер.ПараметрыКлиентаНаСервере().Получить("СтрокаСоединенияИнформационнойБазы");
	
	Если СтрокаСоединенияИнформационнойБазы = Неопределено Тогда
		Возврат Ложь; // Нет клиентского приложения.
	КонецЕсли;
	
	Возврат СтрНайти(ВРег(СтрокаСоединенияИнформационнойБазы), "WS=") = 1;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

КлиентПодключенЧерезВебСервер

Возвращает Истина, если клиентское приложение подключено к базе через веб-сервер.
ОбщийМодуль.ОбщегоНазначенияКлиент
Автор: 1С
// Возвращает Истина, если клиентское приложение подключено к базе через веб-сервер.
//
// См. ОбщегоНазначения.КлиентПодключенЧерезВебСервер
//
// Возвращаемое значение:
//  Булево - Истина, если подключен.
//
Функция КлиентПодключенЧерезВебСервер() Экспорт
	
	Возврат СтрНайти(ВРег(СтрокаСоединенияИнформационнойБазы()), "WS=") = 1;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьПроксиИнформационногоЦентра

Возвращает Прокси Информационного центра Менеджера сервиса.
ОбщийМодуль.ИнформационныйЦентрСервер
Автор: 1С
// Возвращает Прокси Информационного центра Менеджера сервиса.
//
// Возвращаемое значение:
//	WSПрокси - прокси Информационного центра.
//
Функция ПолучитьПроксиИнформационногоЦентра() Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	АдресМенеджераСервиса = РаботаВМоделиСервиса.ВнутреннийАдресМенеджераСервиса();
	
	Если Не ЗначениеЗаполнено(АдресМенеджераСервиса) Тогда
		ВызватьИсключение(НСтр("ru = 'Не установлены параметры связи с менеджером сервиса.'"));
	КонецЕсли;
	
	АдресСервиса       = АдресМенеджераСервиса + "/ws/ManageInfoCenter?wsdl";
	ИмяПользователя    = РаботаВМоделиСервиса.ИмяСлужебногоПользователяМенеджераСервиса();
	ПарольПользователя = РаботаВМоделиСервиса.ПарольСлужебногоПользователяМенеджераСервиса();
	УстановитьПривилегированныйРежим(Ложь);
	
	ПараметрыПодключения = ИнтеграцияПодсистемБТС.ПараметрыПодключенияWSПрокси();
	ПараметрыПодключения.АдресWSDL = АдресСервиса;
	ПараметрыПодключения.URIПространстваИмен = "http://www.1c.ru/SaaS/1.0/WS";
	ПараметрыПодключения.ИмяСервиса = "ManageInfoCenter";
	ПараметрыПодключения.ИмяТочкиПодключения = "ManageInfoCenterSoap";
	ПараметрыПодключения.ИмяПользователя = ИмяПользователя;
	ПараметрыПодключения.Пароль = ПарольПользователя;
	ПараметрыПодключения.Таймаут = 7;
	
	Прокси = ИнтеграцияПодсистемБТС.СоздатьWSПрокси(ПараметрыПодключения);
	
	Возврат Прокси;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьПроксиИнформационногоЦентра_1_0_1_1

Возвращает Прокси Информационного центра Менеджера сервиса.
ОбщийМодуль.ИнформационныйЦентрСервер
Автор: 1С
// Возвращает Прокси Информационного центра Менеджера сервиса.
//
// Возвращаемое значение:
//	WSПрокси - прокси Информационного центра.
//
Функция ПолучитьПроксиИнформационногоЦентра_1_0_1_1() Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	АдресМенеджераСервиса = РаботаВМоделиСервиса.ВнутреннийАдресМенеджераСервиса();
	
	Если Не ЗначениеЗаполнено(АдресМенеджераСервиса) Тогда
		ВызватьИсключение(НСтр("ru = 'Не установлены параметры связи с менеджером сервиса.'"));
	КонецЕсли;
	
	АдресСервиса       = АдресМенеджераСервиса + "/ws/ManageInfoCenter_1_0_1_1?wsdl";
	ИмяПользователя    = РаботаВМоделиСервиса.ИмяСлужебногоПользователяМенеджераСервиса();
	ПарольПользователя = РаботаВМоделиСервиса.ПарольСлужебногоПользователяМенеджераСервиса();
	УстановитьПривилегированныйРежим(Ложь);
	
	ПараметрыПодключения = ИнтеграцияПодсистемБТС.ПараметрыПодключенияWSПрокси();
	ПараметрыПодключения.АдресWSDL = АдресСервиса;
	ПараметрыПодключения.URIПространстваИмен = "http://www.1c.ru/SaaS/1.0/WS";
	ПараметрыПодключения.ИмяСервиса = "ManageInfoCenter_1_0_1_1";
	ПараметрыПодключения.ИмяТочкиПодключения = "ManageInfoCenter_1_0_1_1Soap";
	ПараметрыПодключения.ИмяПользователя = ИмяПользователя;
	ПараметрыПодключения.Пароль = ПарольПользователя;
	ПараметрыПодключения.Таймаут = 7;
	
	Прокси = ИнтеграцияПодсистемБТС.СоздатьWSПрокси(ПараметрыПодключения);
	
	Возврат Прокси;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьПроксиИнформационногоЦентра_1_0_1_2

Возвращает Прокси Информационного центра Менеджера сервиса.
ОбщийМодуль.ИнформационныйЦентрСервер
Автор: 1С
// Возвращает Прокси Информационного центра Менеджера сервиса.
//
// Возвращаемое значение:
//	WSПрокси - прокси Информационного центра.
//
Функция ПолучитьПроксиИнформационногоЦентра_1_0_1_2() Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	АдресМенеджераСервиса = РаботаВМоделиСервиса.ВнутреннийАдресМенеджераСервиса();
	
	Если Не ЗначениеЗаполнено(АдресМенеджераСервиса) Тогда
		ВызватьИсключение(НСтр("ru = 'Не установлены параметры связи с менеджером сервиса.'"));
	КонецЕсли;
	
	АдресСервиса       = АдресМенеджераСервиса + "/ws/ManageInfoCenter_1_0_1_2?wsdl";
	ИмяПользователя    = РаботаВМоделиСервиса.ИмяСлужебногоПользователяМенеджераСервиса();
	ПарольПользователя = РаботаВМоделиСервиса.ПарольСлужебногоПользователяМенеджераСервиса();
	УстановитьПривилегированныйРежим(Ложь);
	
	ПараметрыПодключения = ИнтеграцияПодсистемБТС.ПараметрыПодключенияWSПрокси();
	ПараметрыПодключения.АдресWSDL = АдресСервиса;
	ПараметрыПодключения.URIПространстваИмен = "http://www.1c.ru/SaaS/1.0/WS";
	ПараметрыПодключения.ИмяСервиса = "ManageInfoCenter_1_0_1_2";
	ПараметрыПодключения.ИмяТочкиПодключения = "ManageInfoCenter_1_0_1_2Soap";
	ПараметрыПодключения.ИмяПользователя = ИмяПользователя;
	ПараметрыПодключения.Пароль = ПарольПользователя;
	ПараметрыПодключения.Таймаут = 7;
	
	Прокси = ИнтеграцияПодсистемБТС.СоздатьWSПрокси(ПараметрыПодключения);
	
	Возврат Прокси;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПроксиКонтроляРезервногоКопирования

Возвращает прокси web-сервиса контроля резервного копирования.
ОбщийМодуль.РезервноеКопированиеОбластейДанныхПовтИсп
Автор: 1С
// Возвращает прокси web-сервиса контроля резервного копирования.
// 
// Возвращаемое значение: 
//   WSПрокси - прокси менеджера сервиса.
// 
Функция ПроксиКонтроляРезервногоКопирования() Экспорт
	
	АдресМенеджераСервиса = РаботаВМоделиСервиса.ВнутреннийАдресМенеджераСервиса();
	Если Не ЗначениеЗаполнено(АдресМенеджераСервиса) Тогда
		ВызватьИсключение(НСтр("ru = 'Не установлены параметры связи с менеджером сервиса.'"));
	КонецЕсли;
	
	АдресСервиса = АдресМенеджераСервиса + "/ws/ZoneBackupControl?wsdl";
	ИмяПользователя = РаботаВМоделиСервиса.ИмяСлужебногоПользователяМенеджераСервиса();
	ПарольПользователя = РаботаВМоделиСервиса.ПарольСлужебногоПользователяМенеджераСервиса();
	
	ПараметрыПодключения = ОбщегоНазначения.ПараметрыПодключенияWSПрокси();
	ПараметрыПодключения.АдресWSDL = АдресСервиса;
	ПараметрыПодключения.URIПространстваИмен = "http://www.1c.ru/SaaS/1.0/WS";
	ПараметрыПодключения.ИмяСервиса = "ZoneBackupControl";
	ПараметрыПодключения.ИмяПользователя = ИмяПользователя; 
	ПараметрыПодключения.Пароль = ПарольПользователя;
	ПараметрыПодключения.Таймаут = 10;
	
	Прокси = ОбщегоНазначения.СоздатьWSПрокси(ПараметрыПодключения);
	
	Возврат Прокси;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ОтключитьАвтоматическуюСинхронизациюДанныхСПриложениемВИнтернете

Для внутреннего использования
ОбщийМодуль.АвтономнаяРаботаСлужебный
Автор: 1С
// Для внутреннего использования
// 
Процедура ОтключитьАвтоматическуюСинхронизациюДанныхСПриложениемВИнтернете(Источник) Экспорт
	
	Если Не ОбщегоНазначения.РазделениеВключено() Тогда
		
		ОтключитьАвтоматическуюСинхронизацию = Ложь;
		
		Для Каждого СтрокаНабора Из Источник Цикл
			
			Если СтрокаНабора.ВидТранспортаСообщенийОбменаПоУмолчанию = Перечисления.ВидыТранспортаСообщенийОбмена.WS
				И Не СтрокаНабора.WSЗапомнитьПароль Тогда
				
				ОтключитьАвтоматическуюСинхронизацию = Истина;
				Прервать;
				
			КонецЕсли;
			
		КонецЦикла;
		
		Если ОтключитьАвтоматическуюСинхронизацию Тогда
			
			УстановитьПривилегированныйРежим(Истина);
			
			РегламентныеЗаданияСервер.УстановитьИспользованиеРегламентногоЗадания(
				Метаданные.РегламентныеЗадания.СинхронизацияДанныхСПриложениемВИнтернете, Ложь);
			
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ИспользуемыеТранспортыСообщенийОбмена

Возвращает коллекцию транспортов сообщений обмена, которые могут быть использованы для заданного узла плана обмена.
ОбщийМодуль.ОбменДаннымиПовтИсп
Автор: 1С
// Возвращает коллекцию транспортов сообщений обмена, которые могут быть использованы для заданного узла плана обмена.
//
// Параметры:
//  УзелИнформационнойБазы - ПланОбменаСсылка - узел плана обмена, для которого требуется получить значение функции.
//  ВариантНастройки       - Строка           - идентификатор варианта настройки синхронизации данных.
// 
//  Возвращаемое значение:
//   Массив - Используемые транспорты сообщений обмена для узла.
//
Функция ИспользуемыеТранспортыСообщенийОбмена(УзелИнформационнойБазы, Знач ВариантНастройки = "") Экспорт
	
	ИмяПланаОбмена = ОбменДаннымиПовтИсп.ПолучитьИмяПланаОбмена(УзелИнформационнойБазы);
	
	Если Не УзелИнформационнойБазы.Пустая() Тогда
		ВариантНастройки = ОбменДаннымиСервер.СохраненныйВариантНастройкиУзлаПланаОбмена(УзелИнформационнойБазы);
	КонецЕсли;
	
	ОписаниеВариантаНастройки = ОбменДаннымиПовтИсп.ОписаниеВариантаНастройки(ИмяПланаОбмена,  
		ВариантНастройки, "", "");
	
	Результат = ОписаниеВариантаНастройки.ИспользуемыеТранспортыСообщенийОбмена;
	
	Если Результат.Количество() = 0 Тогда
		Результат = ОбменДаннымиСервер.ВсеТранспортыСообщенийОбменаКонфигурации();
	КонецЕсли;
	
	// Обмен через COM-соединение не поддерживается:
	//  - для базовых версий конфигураций;
	//  - для РИБ;
	//  - для стандартного обмена (без использования правил конвертации);
	//  - если сервер 1С запущен на ОС Linux.
	//
	Если СтандартныеПодсистемыСервер.ЭтоБазоваяВерсияКонфигурации()
		Или ОбменДаннымиПовтИсп.ЭтоПланОбменаРаспределеннойИнформационнойБазы(ИмяПланаОбмена)
		Или ОбменДаннымиПовтИсп.ЭтоУзелСтандартногоОбменаДанными(ИмяПланаОбмена)
		Или ОбщегоНазначения.ЭтоLinuxСервер() Тогда
		
		ОбщегоНазначенияКлиентСервер.УдалитьЗначениеИзМассива(Результат,
			Перечисления.ВидыТранспортаСообщенийОбмена.COM);
			
	КонецЕсли;
	
	// Обмен через WS-соединение не поддерживается:
	//  - для РИБ, не являющихся АРМ.
	//
	Если ОбменДаннымиПовтИсп.ЭтоПланОбменаРаспределеннойИнформационнойБазы(ИмяПланаОбмена)
		И Не ОбменДаннымиПовтИсп.ЭтоУзелАвтономногоРабочегоМеста(УзелИнформационнойБазы) Тогда
		
		ОбщегоНазначенияКлиентСервер.УдалитьЗначениеИзМассива(Результат,
			Перечисления.ВидыТранспортаСообщенийОбмена.WS);
		
	КонецЕсли;
	
	// Обмен через WS-соединение в пассивном режиме не поддерживается:
	//  - для обменов, не являющихся обменом через XDTO;
	//  - для файловых информационных баз.
	//
	Если Не ОбменДаннымиПовтИсп.ЭтоПланОбменаXDTO(ИмяПланаОбмена)
		Или ОбщегоНазначения.ИнформационнаяБазаФайловая() Тогда
		
		ОбщегоНазначенияКлиентСервер.УдалитьЗначениеИзМассива(Результат,
			Перечисления.ВидыТранспортаСообщенийОбмена.WSПассивныйРежим);
		
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПараметрыКлиента

Возвращает параметры клиентского приложения.
ОбщийМодуль.ИнтернетПоддержкаПользователейКлиент
Автор: 1С
// Возвращает параметры клиентского приложения.
//
// Возвращаемое значение:
//	Структура - параметры клиентского приложения.
//		* ТипПлатформы - Строка - тип платформы;
//		* ВерсияОС - Строка - версия операционной системы;
//		* ЭтоКлиентЧерезВебСервер - Булево - признак того, что тонкий клиент
//			подключен через веб-сервер.
//
Функция ПараметрыКлиента() Экспорт
	
	Результат = Новый Структура;
	СистИнфо = Новый СистемнаяИнформация;
	Результат.Вставить("ТипПлатформы",
		ИнтернетПоддержкаПользователейКлиентСервер.ИмяТипПлатформыСтр(
			СистИнфо.ТипПлатформы));
	Результат.Вставить("ВерсияОС", СистИнфо.ВерсияОС);
	#Если ВебКлиент Тогда
	Результат.Вставить("ЭтоКлиентЧерезВебСервер", Ложь);
	#Иначе
	Результат.Вставить("ЭтоКлиентЧерезВебСервер",
		(НРег(Лев(СтрокаСоединенияИнформационнойБазы(), 3)) = "ws="));
	#КонецЕсли
	
	Возврат Результат;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьWSПроксиКорреспондента

Возвращает ссылку на объект WSПрокси корреспондента, идентифицируемого узлом плана обмена.
ОбщийМодуль.ОбменДаннымиВМоделиСервисаПовтИсп
Автор: 1С
// Возвращает ссылку на объект WSПрокси корреспондента, идентифицируемого узлом плана обмена.
//
// Параметры:
// УзелИнформационнойБазы - ПланОбменаСсылка.
// СтрокаСообщенияОбОшибке - Строка - Текст сообщения об ошибке.
//
// Возвращаемое значение:
// WSПрокси.
//
Функция ПолучитьWSПроксиКорреспондента(УзелИнформационнойБазы, СтрокаСообщенияОбОшибке = "") Экспорт
	
	СтруктураНастроек = РегистрыСведений.НастройкиТранспортаОбменаОбластиДанных.НастройкиТранспортаWS(УзелИнформационнойБазы);
	СтруктураНастроек.Вставить("WSИмяСервиса", "RemoteAdministrationOfExchange");
	СтруктураНастроек.Вставить("WSURLПространстваИменСервиса", "http://www.1c.ru/SaaS/1.0/WS/RemoteAdministrationOfExchange");
	СтруктураНастроек.Вставить("WSТаймаут", 20);
	
	Возврат ОбменДаннымиСервер.ПолучитьWSПроксиПоПараметрамПодключения(СтруктураНастроек, СтрокаСообщенияОбОшибке);
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьWSПроксиКорреспондента_2_1_6_1

Возвращает ссылку на объект WSПрокси версии 2.1.6.1 корреспондента, идентифицируемого узлом плана обмена.
ОбщийМодуль.ОбменДаннымиВМоделиСервисаПовтИсп
Автор: 1С
// Возвращает ссылку на объект WSПрокси версии 2.1.6.1 корреспондента, идентифицируемого узлом плана обмена.
//
Функция ПолучитьWSПроксиКорреспондента_2_1_6_1(УзелИнформационнойБазы, СтрокаСообщенияОбОшибке = "") Экспорт
	
	СтруктураНастроек = РегистрыСведений.НастройкиТранспортаОбменаОбластиДанных.НастройкиТранспортаWS(УзелИнформационнойБазы);
	СтруктураНастроек.Вставить("WSИмяСервиса", "RemoteAdministrationOfExchange_2_1_6_1");
	СтруктураНастроек.Вставить("WSURLПространстваИменСервиса", "http://www.1c.ru/SaaS/1.0/WS/RemoteAdministrationOfExchange_2_1_6_1");
	СтруктураНастроек.Вставить("WSТаймаут", 20);
	
	Возврат ОбменДаннымиСервер.ПолучитьWSПроксиПоПараметрамПодключения(СтруктураНастроек, СтрокаСообщенияОбОшибке);
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьWSПроксиКорреспондента_2_4_5_1

Возвращает ссылку на объект WSПрокси версии 2.4.5.1 корреспондента, идентифицируемого узлом плана обмена.
ОбщийМодуль.ОбменДаннымиВМоделиСервисаПовтИсп
Автор: 1С
// Возвращает ссылку на объект WSПрокси версии 2.4.5.1 корреспондента, идентифицируемого узлом плана обмена.
//
Функция ПолучитьWSПроксиКорреспондента_2_4_5_1(УзелИнформационнойБазы, СтрокаСообщенияОбОшибке = "") Экспорт
	
	СтруктураНастроек = РегистрыСведений.НастройкиТранспортаОбменаОбластиДанных.НастройкиТранспортаWS(УзелИнформационнойБазы);
	СтруктураНастроек.Вставить("WSИмяСервиса", "RemoteAdministrationOfExchange_2_4_5_1");
	СтруктураНастроек.Вставить("WSURLПространстваИменСервиса", "http://www.1c.ru/SaaS/1.0/WS/RemoteAdministrationOfExchange_2_4_5_1");
	СтруктураНастроек.Вставить("WSТаймаут", 20);
	
	Возврат ОбменДаннымиСервер.ПолучитьWSПроксиПоПараметрамПодключения(СтруктураНастроек, СтрокаСообщенияОбОшибке);
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ВсеТранспортыСообщенийОбменаКонфигурации

Возвращает массив всех видов транспорта сообщений обмена, определенных в конфигурации.
ОбщийМодуль.ОбменДаннымиСервер
Автор: 1С
// Возвращает массив всех видов транспорта сообщений обмена, определенных в конфигурации.
//
// Возвращаемое значение:
//   Массив - Элементы массива имеют тип "ПеречислениеСсылка.ВидыТранспортаСообщенийОбмена".
//
Функция ВсеТранспортыСообщенийОбменаКонфигурации() Экспорт
	
	Результат = Новый Массив;
	Результат.Добавить(Перечисления.ВидыТранспортаСообщенийОбмена.COM);
	Результат.Добавить(Перечисления.ВидыТранспортаСообщенийОбмена.WS);
	Результат.Добавить(Перечисления.ВидыТранспортаСообщенийОбмена.FILE);
	Результат.Добавить(Перечисления.ВидыТранспортаСообщенийОбмена.FTP);
	Результат.Добавить(Перечисления.ВидыТранспортаСообщенийОбмена.EMAIL);
	Результат.Добавить(Перечисления.ВидыТранспортаСообщенийОбмена.WSПассивныйРежим);
	
	Возврат Результат;
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

КлиентПодключенЧерезВебСервер

Устарела. Следует использовать ОбщегоНазначенияКлиент.КлиентПодключенЧерезВебСервер
ОбщийМодуль.ОбщегоНазначенияКлиентСервер
Автор: 1С
// Устарела. Следует использовать ОбщегоНазначенияКлиент.КлиентПодключенЧерезВебСервер 
//  или ОбщегоНазначения.КлиентПодключенЧерезВебСервер
// Возвращает Истина, если клиентское приложение подключено к базе через веб-сервер.
// Если нет клиентского приложения, возвращается Ложь.
//
// Возвращаемое значение:
//  Булево - Истина, если подключен.
//
Функция КлиентПодключенЧерезВебСервер() Экспорт
	
#Если Сервер Или ТолстыйКлиентОбычноеПриложение Тогда
	УстановитьПривилегированныйРежим(Истина);
	
	СтрокаСоединенияИнформационнойБазы = СтандартныеПодсистемыСервер.ПараметрыКлиентаНаСервере().Получить("СтрокаСоединенияИнформационнойБазы");
	
	Если СтрокаСоединенияИнформационнойБазы = Неопределено Тогда
		Возврат Ложь; // Нет клиентского приложения.
	КонецЕсли;
#Иначе
	СтрокаСоединенияИнформационнойБазы = СтрокаСоединенияИнформационнойБазы();
#КонецЕсли
	
	Возврат СтрНайти(ВРег(СтрокаСоединенияИнформационнойБазы), "WS=") = 1;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьПроксиУправленияКонференцией

Получить прокси управления конференцией.
ОбщийМодуль.ИнформационныйЦентрСервер
Автор: 1С
// Получить прокси управления конференцией.
//
// Возвращаемое значение:
//  WSПрокси - прокси управления конференцией.
//
Функция ПолучитьПроксиУправленияКонференцией() Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	Адрес = Константы.АдресУправленияКонференцией.Получить() + "/ForumService?wsdl";
	Владелец = ИнтеграцияПодсистемБТС.ИдентификаторОбъектаМетаданных("Константа.АдресУправленияКонференцией");
	Логин = ИнтеграцияПодсистемБТС.ПрочитатьДанныеИзБезопасногоХранилища(Владелец, "Логин", Истина);
	Пароль = ИнтеграцияПодсистемБТС.ПрочитатьДанныеИзБезопасногоХранилища(Владелец, "Пароль", Истина);
	УстановитьПривилегированныйРежим(Ложь);
	
	ПараметрыПодключения = ИнтеграцияПодсистемБТС.ПараметрыПодключенияWSПрокси();
	ПараметрыПодключения.АдресWSDL = Адрес;
	ПараметрыПодключения.URIПространстваИмен = "http://ws.forum.saas.onec.ru/";
	ПараметрыПодключения.ИмяСервиса = "ForumIntegrationWSImplService";
	ПараметрыПодключения.ИмяТочкиПодключения = "ForumIntegrationWSImplPort";
	ПараметрыПодключения.ИмяПользователя = Логин;
	ПараметрыПодключения.Пароль = Пароль;
	
	Прокси = ИнтеграцияПодсистемБТС.СоздатьWSПрокси(ПараметрыПодключения);
	
	Возврат Прокси;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьWSПроксиКорреспондента_2_0_1_6

Возвращает ссылку на объект WSПрокси версии 2.0.1.6 корреспондента, идентифицируемого узлом плана обмена.
ОбщийМодуль.ОбменДаннымиВМоделиСервисаПовтИсп
Автор: 1С
// Возвращает ссылку на объект WSПрокси версии 2.0.1.6 корреспондента, идентифицируемого узлом плана обмена.
//
// Параметры:
// УзелИнформационнойБазы - ПланОбменаСсылка.
// СтрокаСообщенияОбОшибке - Строка - Текст сообщения об ошибке.
//
// Возвращаемое значение:
// WSПрокси.
//
Функция ПолучитьWSПроксиКорреспондента_2_0_1_6(УзелИнформационнойБазы, СтрокаСообщенияОбОшибке = "") Экспорт
	
	СтруктураНастроек = РегистрыСведений.НастройкиТранспортаОбменаОбластиДанных.НастройкиТранспортаWS(УзелИнформационнойБазы);
	СтруктураНастроек.Вставить("WSИмяСервиса", "RemoteAdministrationOfExchange_2_0_1_6");
	СтруктураНастроек.Вставить("WSURLПространстваИменСервиса", "http://www.1c.ru/SaaS/1.0/WS/RemoteAdministrationOfExchange_2_0_1_6");
	СтруктураНастроек.Вставить("WSТаймаут", 20);
	
	Возврат ОбменДаннымиСервер.ПолучитьWSПроксиПоПараметрамПодключения(СтруктураНастроек, СтрокаСообщенияОбОшибке);
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////

ПолучитьПроксиМенеджераСервиса

Возвращает прокси web-сервиса для синхронизации административных действий в сервисе.
ОбщийМодуль.РаботаВМоделиСервиса
Автор: 1С
// Возвращает прокси web-сервиса для синхронизации административных действий в сервисе.
// 
// Параметры:
//  ПарольПользователя - Строка - пароль для подключения.
// 
// Возвращаемое значение: 
//   WSПрокси - прокси менеджера сервиса. 
// 
Функция ПолучитьПроксиМенеджераСервиса(Знач ПарольПользователя = Неопределено) Экспорт
	
	АдресМенеджераСервиса = ВнутреннийАдресМенеджераСервиса();
	Если Не ЗначениеЗаполнено(АдресМенеджераСервиса) Тогда
		ВызватьИсключение(НСтр("ru = 'Не установлены параметры связи с менеджером сервиса.'"));
	КонецЕсли;
	
	АдресСервиса = АдресМенеджераСервиса + "/ws/ManageApplication_1_0_3_1?wsdl";
	
	Если ПарольПользователя = Неопределено Тогда
		ИмяПользователя = ИмяСлужебногоПользователяМенеджераСервиса();
		ПарольПользователя = ПарольСлужебногоПользователяМенеджераСервиса();
	Иначе
		ИмяПользователя = ИмяПользователя();
	КонецЕсли;
	
	ПараметрыПодключения = ОбщегоНазначения.ПараметрыПодключенияWSПрокси();
	ПараметрыПодключения.АдресWSDL = АдресСервиса;
	ПараметрыПодключения.URIПространстваИмен = "http://www.1c.ru/SaaS/ManageApplication/1.0.3.1";
	ПараметрыПодключения.ИмяСервиса = "ManageApplication_1_0_3_1";
	ПараметрыПодключения.ИмяПользователя = ИмяПользователя;
	ПараметрыПодключения.Пароль = ПарольПользователя;
	ПараметрыПодключения.Таймаут = 20;
	Прокси = ОбщегоНазначения.СоздатьWSПрокси(ПараметрыПодключения);
	
	Возврат Прокси;
	
КонецФункции

///////////////////////////////////////////////////////////////////////////////////////////////////////
// Copyright (c) 2019, ООО 1С-Софт
// Все права защищены. Эта программа и сопроводительные материалы предоставляются 
// в соответствии с условиями лицензии Attribution 4.0 International (CC BY 4.0)
// Текст лицензии доступен по ссылке:
// https://creativecommons.org/licenses/by/4.0/legalcode
///////////////////////////////////////////////////////////////////////////////////////////////////////